Application Path

[jaenicke]

Zitat von Gutelo:

Es ist Aufgabe von Embacedero sicherzustellen dass diese Funktion macht was Sie machen soll. Ehrlichgesagt sollte es simpel sein das Verzeichnis bei Ausfuehren des Programms so zu speichern dass der Wert durch andere Operationen nicht veraendert wird.

Du hast einmal das Anwendungsverzeichnis (Application.ExeName oder ParamStr(0)) und du hast einmal das aktuelle Arbeitsverzeichnis (GetCurrentDir). Das ist nun einmal nicht das gleiche.

Der Fehler liegt nicht in Delphi oder bei Embarcadero, wenn diese Funktionen falsch benutzt werden...

// EDIT:

Zitat von Der schöne Günther:

Genau das wollte ich wissen Gibt es denn bekannte Fälle?

Datenbankzugriffskomponenten, Fremddialoge, ...
Da gibt es einige Möglichkeiten.

Zitat von Der schöne Günther:

Bislang habe hole mir oft dynamisch das Arbeitsverzeichnis (ohne es je selbst zu ändern) und bastele mir damit dann eine absolute Pfadangabe zusammen.

Solange du damit auch das aktuelle Arbeitsverzeichnis ansprechen willst und nicht das Verzeichnis der Anwendung ist doch alles in Ordnung.

[Perlsau]

Da bei einigen offenbar rege Begriffsverwirrung herrscht, möchte ich das bisher Gesagte noch einmal zusammenfassen:

Das Anwendungsverzeichnis ändert sich nicht, während das Programm läuft:

Delphi-Quellcode:

Anwendungsverzeichnis := SysUtils.ExtractFilePath(System.ParamStr(0));
Anwendungsverzeichnis := SysUtils.ExtractFilePath(Forms.Application.ExeName);

Das Arbeitsverzeichnis kann sich während des Programmlaufs jedoch ändern, z.B. durch einen Aufruf von OpenDialg oder SaveDialog:

Delphi-Quellcode:

Arbeitsverzeichnis := SysUtils.GetCurrentDir;

Wenn ich im Programm ein festes Verzeichnis benötige, das sich nicht ändern soll, dann lege ich dieses Verzeichnsi beim Programmstart fest, z.B. den Ort, an dem die benötigte Firebird-Datenbank zu finden ist:

Delphi-Quellcode:

Const
  DB_Datei = 'MeineDatenbank.FDB';
Var
  DB_DateiName,
  DB_DateiPfad : String;

Diesen Speicherort ermittle ich entweder durch einen OpenDialog oder lege ihn in einer Ini-Datei fest (das kann auch ein einfaches Ascii-File mit nur einer Zeile sein). Diese Ini-Datei speichere ich nur dann im Anwendungsverzeichnis, wenn

1. sie nicht vom Programm verändert zurückgeschrieben werden soll und/oder
2. es sich um eine portable Anwendung handelt, die sich nicht in einem der Windows-Systemordner befindet.

Ansonsten speichert man Ini-Dateien (und andere, die man benötigt) im Benutzer-Verzeichns, und zwar bei:

WinXP entweder unter \AllUsers\Anwendungsdaten oder \[CurrentUser]\Anwendungsdaten
Win7 entweder unter \Users\Public\Documents\MeineAnwendungsDaten\ oder entsprechend unter \Users\[CurrentUser]\
Win 8 weiß ich nicht, hab ich nicht ...

Oder man setzt entsprechende Registry-Einträge und erfährt dann aus der Registry alle notwendigen festen Verzeichnisse.

[hathor]

WIN 8:

Delphi-Quellcode:

uses
  ActiveX, ShlObj;

function SpecialDirectory(const iID: Integer): string;
var aPath  : array[0..MAX_PATH] of Char; pilTemp: PItemIDList;
begin
   try
      if SHGetSpecialFolderLocation(0, iID, pilTemp)=S_OK then begin
         if SHGetPathFromIDList(pilTemp, aPath) then begin
            Result := string(aPath);
         end else Result := ''; CoTaskMemFree(pilTemp);
      end else Result := '';
   except Result := '';
   end;
end;

function GetConfigPath: String;
var AppDir: String;
begin
  AppDir := SpecialDirectory(CSIDL_APPDATA)+'\ProgName';
  if DirectoryExists(AppDir) = false then mkdir(AppDir);
    result := AppDir+'\';
end;

//ergibt: C:\Users\HATHOR\AppData\Roaming\ProgName\

Hinweis:
Über den WIN8-Explorer kommt man nur hin, wenn man
C:\Users\HATHOR\AppData\Roaming\ProgName\
direkt in die Adresszeile eingibt.

Alternativ: Im Explorer - Ansicht - Häkchen bei Ausgeblendete Elemente

[Furtbichler]

Und davor (rausgeschnibbelt aus einer größeren Unit)

Delphi-Quellcode:

unit SettingsPaths;

interface
Function LocalUserFilesPath: String;
Function LocalAppDataPath(AppName: String): String;
Function AppDataPath(AppName: String): String;
implementation
Uses sysutils,windows,ShlObj, ActiveX;
Function GetSpecialFolderLocation(csidl: integer): String;
Var
  pMalloc: IMalloc;
  pidl: PItemIDList;
  path: Array[0..MAX_PATH] Of Char;
Begin
  Result := '?';
  If SHGetMalloc(pMalloc) = S_OK Then Begin
    SHGetSpecialFolderLocation(0, csidl, pidl);
    SHGetPathFromIDList(pidl, path);
    Result := IncludeTrailingPathDelimiter(Path);
    pMalloc.Free(pidl);
  End;
End;

Function LocalUserFilesPath: String;
Begin
  Result := IncludeTrailingPathDelimiter(GetSpecialFolderLocation(CSIDL_PERSONAL));
End;

Function LocalAppDataPath(AppName: String): String;
Begin
  Result := IncludeTrailingPathDelimiter(GetSpecialFolderLocation(CSIDL_LOCAL_APPDATA));
  Result := IncludeTrailingPathDelimiter(Result + AppName);
  ForceDirectories(Result)
End;

Function AppDataPath(AppName: String): String;
Begin
  Result := IncludeTrailingPathDelimiter(GetSpecialFolderLocation(CSIDL_APPDATA));
  Result := IncludeTrailingPathDelimiter(Result + AppName);
  ForceDirectories(Result)
End;
end.

So, und wer jetzt seine INI ins Programmverzeichnis schmeißt, wird geteert und gefeedert (mit Doppel-E!).

[DeddyH]

SHGetSpecialFolderLocation

Zitat:

[SHGetSpecialFolderLocation is not supported and may be altered or unavailable in the future. Instead, use SHGetFolderLocation.]

Das führt dann zu SHGetFolderLocation

Zitat:

Deprecated. Retrieves the path of a folder as an ITEMIDLIST structure.

Alternativ kann man dann auf SHGetFolderPath zurückgreifen, aber

Zitat:

Deprecated. Gets the path of a folder identified by a CSIDL value.

Was einen dann letztendlich zu SHGetKnownFolderPath führt.
Einziger Haken:

Zitat:

Minimum supported client
Windows Vista [desktop apps only]

Daher greife ich persönlich derzeit auf SHGetFolderPath zurück, dazu braucht man nur die Unit SHFolder, und einfacher zu handhaben (und nicht ganz so veraltet wie die erstgenannten) ist sie auch noch.

[Furtbichler]

Oh, nie drauf geachtet.

[Gutelo]

Zitat:

Anwendungsverzeichnis := SysUtils.ExtractFilePath(System.ParamStr(0));
Anwendungsverzeichnis := SysUtils.ExtractFilePath(Forms.Application.ExeName );

@Perlsau: und genau die Werte dieser Anwendungsverzeichnisse aendern sich wenn das Programm in bestimmten Verzeichnissen liegt. Und das ist wohl ein Delphi-Problem.

[himitsu]

Zitat von Gutelo:

@Perlsau: und genau die Werte dieser Anwendungsverzeichnisse aendern sich wenn das Programm in bestimmten Verzeichnissen liegt. Und das ist wohl ein Delphi-Problem.

Ich würde wetten, daß das auch bei Lazarus, .net, C#, C++, ... passiert.

[hathor]

Ergebnis des untenstehenden Codes:
C:\Users\HATHOR\AppData\Roaming\MyProg

Delphi-Quellcode:

function GetMyPath: string;
var LStr: array[0 .. MAX_PATH] of Char; 
s, AppDir : String;
begin
Result:='';
  Application.Name:='MyProg';
  s:= PathDelim + Application.Name;
  SetLastError(ERROR_SUCCESS);
  if SHGetFolderPath(0, CSIDL_APPDATA, 0, 0, @LStr) = S_OK then
      AppDir:= LStr +s;
    Result := AppDir;
  if not DirectoryExists(AppDir) then mkdir(AppDir);
end;

[DeddyH]

Was ändert sich, und was soll daran ein Delphi-Problem sein? ParamStr(0) bzw. Application.Exename enthalten den vollen Pfad zum Programm, und zwar da, wo es tatsächlich liegt. Dass dieses Verzeichnis ggf. anders heißt als vom Windows-Explorer dargestellt, liegt nicht an Delphi, sondern an der Virtualisierung bestimmter Ordner seitens Microsoft.