Es geht auch eleganter, wenn wir den Compiler zu Hilfe nehmen. Zu jedem deklarierten Typ werden durch den Compiler auch Typ Informationen in die EXE eingelinkt. Durch diese wird es möglich dynamisch zur Laufzeit Typen zu überprüfen oder sogar zu casten. Die Funktionen in
Unit TypInfo.pas sind da sehr hilfreich. Nachfolgender Code "castet" eine beliebigen String in ein Mengenelement aus der Menge von TName.
Delphi-Quellcode:
uses TypInfo;
type // der Namen Typ + das set
TName = (unknown, idiot, comment, name, id);
TNames = set of TName;
function StrToName(const Value: String): TName;
// wandelt einen String in ein TName um
var
I: Integer;
begin
I := GetEnumValue(TypeInfo(TName), Value);
if I = -1 then Result := unknown
else Result := TName(I)
end;
function NameToStr(Value: TName): String;
// gibt den lesbaren Bezeichner eines Mengen Elemente zurück
begin
Result := GetEnumName(TypeInfo(TName), Integer(Value));
end;
procedure Test;
var
Name: TName;
begin
Name := StrToName('comment');
Writeln( NameToStr( Name ) );
WriteLn( NameToStr( StrToName('ID') ) );
WriteLn( NameToStr( StrToName('iD') ) );
WriteLn( NameToStr( StrToName('Comment') ) );
WriteLn( NameToStr( StrToName('Test') ) );
if StrToName('id') in [id, comment] then WriteLn('id is in [id, comment]')
else WriteLn('id is not in [id, comment]');
if StrToName('Test') in [id, comment] then WriteLn('Test is in [id, comment]')
else WriteLn('Test is not in [id, comment]')
end;
Da auch Strings an StrToName() übergeben werden können die nicht in TName vorkommen habe ich das Element "unknown" deklariert. Alle Strings die nicht in TName vorkommen werden als unknown definiert.
Interessant wird es jetzt mit "idiot" denn mit Hansas Vorschlag würde eine solche Doppeldeutigkeit zu Fehlern führen. Da eben "id" auch in "idiot" vorkommt.
Gruß Hagen