Probleme mit GetFilesInDirectory Procedure

[Dash]

Zitat von Go2EITS:

Ich glaube Dein False musst Du in True umbenennen, also so:
GetFilesInDirectory('C:\', '*.*', Listbox1.Items, True, True); Grüße Go2EITS

Stimmt, ich hatte es bei mir aber schon geändert

@Christian
Ich habe nun deinen letzten Code benutzt, allerdings hört er nach der ersten Datei auf zu scannen

Gruß
Dash

[Migo]

Das Thema ist zwar schon einige Jahre alt... aber ich nutze die Rekursive Suche mit GetFilesInDirectory immer noch gerne:

Code:

procedure GetFilesInDirectory(Directory: string; const Mask: string; List: TStrings; WithSubDirs, ClearList: Boolean);

  procedure ScanDir(const Directory: string);
  var
    SR: TSearchRec;
  begin
    if FindFirst(Directory + Mask, faAnyFile and not faDirectory, SR) = 0 then try
      repeat
        List.Add(Directory + SR.Name)
      until FindNext(SR) <> 0;
    finally
      FindClose(SR);
    end;

    if WithSubDirs then begin
      if FindFirst(Directory + '*.*', faAnyFile, SR) = 0 then try
        repeat
          if ((SR.attr and faDirectory) = faDirectory) and
             (SR.Name <> '.') and (SR.Name <> '..') then
            ScanDir(Directory + SR.Name + '\');
        until FindNext(SR) <> 0;
      finally
        FindClose(SR);
      end;
    end;
  end;

begin
  List.BeginUpdate;
  try
    if ClearList then List.Clear;
    if Directory = '\' then Exit;
    if Directory[Length(Directory)] <> '\' then
      Directory := Directory + '\';
    ScanDir(Directory);
  finally
    List.EndUpdate;
  end;
end;

Nun ist aber mein ungelöstes Problem, das ich bei der Suche in C:\ProgramData folgendes als Ergebnis bekomme, wenn ich nach "lights*" suche: Siehe angehängten Screenshot.

?!? Er dürfte mir die Dateien "Light Skin..." doch gar nicht anzeigen? Was mag der Grund sein?

Gruß,
Migo

[himitsu]

Altes ANSI-Delphi? (D7 oder davor)
Und kein Kompatibilitätsmanifest vorhanden, bzw. läuft die Anwendung in einem Kompatibilitätsmodus? (WinXP oder so)

Hmmm, eigentlich sieht es nicht so aus,
aber würden die ShortNames verwendet, dann wäre es eine Erklärung.
Ohh ja, es werden ShortName und LongName vom FindFirst/FindNext berücksichtigt.

Verwende deinen Debugger und schau, was im SR alles drin steht, bzw. genauer in SR.FindData.cAlternateFileName




Ist Directory leer '' , dann raucht es dir ab

Delphi-Quellcode:

if Directory[Length(Directory)] <> '\' then
      Directory := Directory + '\';

und, selbst wenn nicht, dann sollte if Directory = '\' then Exit; bestimmt erst danach erfolgen.

EndsStr, bzw. IncludeTrailingBackslash IncludeTrailingPathDelimiter

TDirectory.GetFiles

[Migo]

Zitat von himitsu:

Ohh ja, es werden ShortName und LongName vom FindFirst/FindNext berücksichtigt.

Danke Dir für Dein Feedback.
Ja, es werden beide wohl berücksichtigt - leider fehlt mir aktuell das Wissen, meine Prozedur so umzubauen, dass nur LongNames berücksichtigt werden.

[himitsu]

Den Namen nochmals mit MatchesMask (System.Masks) prüfen.

Ob jetzt FindFirst oder via TDirectrory.GetFiles, ist dabei auch egal.

[Delphi.Narium]

TSearchRec hat auch noch das Feld FindData. Da gibt es dann SearchRec.FindData.cFileName für den langen Dateinamen und SearchRec.FindData.cAlternateFileName für den kurzen Dateinamen.

Wenn Du nun nach lights* suchst, prüfst Du in cFileName, ob's auch mit lights beginnt. Light Skin fiele dann raus.

Wenn Du willst kannst Du die Prüfung dann auch noch casesensitiv machen, damit sich lights und Lights auch noch unterscheiden lassen.

Ansonsten: Reguläre Ausdrücke oder MatchesMask (wie schon vorgeschlagen).

[Migo]

Zitat von Delphi.Narium:

Ansonsten: Reguläre Ausdrücke oder MatchesMask (wie schon vorgeschlagen).

Ganz lieben Dank Euch beiden! Ihr habt mir sehr geholfen mit Eurer Hilfestellung.

Ich konnte mir mit

Code:

if MatchesMask(SR.Name, Suchmaske) then

nun weiterhelfen und bekomme jetzt die richtigen Ergebnisse angezeigt.


Interessanterweise konnte mir die Abfrage mit

Code:

if MatchesMask(SR.FindData.cFileName, Suchmaske) then

da nicht weiterhelfen. Sie zeigte nicht das gewünschte Ergebnis an.

[Delphi.Narium]

MatchesMask will als Parameter Strings. cFileName ist aber kein String.

Funktioniert eventuell

Delphi-Quellcode:

var
  myFileName: string;

...

  myFileName := string(SR.FindData.cFileName);
  if MatchesMask(myFileName, Suchmaske) then ...

oder
if MatchesMask(string(SR.FindData.cFileName), Suchmaske) then ...