Fenster Handle ermitteln ohne Application.Title

[TUX_der_Pinguin]

Moin Moin, ich bin grade dabei meiner Anwendung beizubringen nicht doppelt bzw. mehrfach zu starten.
Alles klein Problem "Mutex" erstellt und fertig, aber die Funktionalität das die 1. Instanz der Anwendung
in den Vordergrund geholt wird klappt nicht so wirklich. Da ich probleme damit habe das Fenster zu finden
ich verwende dazu FindWindowEx/FindWindow nur ist das Problem die meisten arbeiten mit Application.Title
der ist aber zu der Zeit noch unbekannt bzw. wird später zur Laufzeit dynamisch gesetzt.

Ich kann ein Fenster auch über die Klasse finden, nur heißen in einigen meiner Projekte die Hauptformulare
'frmMain' so das ich darüber nicht eindeutig ein Fenster finden kann. Gut wäre wenn ich noch weitere
informationen abfragen könnte, z.B. den Tag eines Formulars. Dann könnte ich eine schleife durchlaufen
lassen alle Fenster mit der Klasse 'TfrmMain' auflisten und dann weiter prüfen ob der Tag meiner gewünschten
Anwendung entspricht, wenn ja wird diese Anwendung in den Vordergrund geholt und angezeigt.

Hier meine Projekt (*.dpr) Datei:

Delphi-Quellcode:

program tab;

uses
  Forms,
  Windows,
  uMain in 'uMain.pas' {frmMain},
  uGlobal in 'uGlobal.pas',
  ...;

{$R *.res}
{$R icons.RES}

var
  dwMutex       : DWORD;
  hWindow       : THandle;

begin
  //Mutex erzeugen 
  dwmutex := CreateMutex(nil, True, '{Eindeutiger String z.b. GUID}');
  try
    //prüfen ob die Anwendung bereits läuft...
    if GetLastError <> ERROR_ALREADY_EXISTS then begin
      Application.Initialize;
      Application.MainFormOnTaskbar := True;
      Application.Title := '';
      Application.CreateForm(TfrmMain, frmMain);
      Application.CreateForm(TfrmSplashScreen, frmSplashScreen);
      Application.Run;
    end
    else begin
      //Hauptfenster finden
      //hWindow := FindWindow('TfrmMain', nil); // Das Hauptfenster finden
      hWindow := FindWindowEx(0, hWindow, 'TApplication', Application.Title);

      //Fenster in den Vordergrund holen
      if hWindow <> 0 then begin
        ShowWindow(hWindow, SW_NORMAL);
        SetForegroundWindow(hWindow);
      end;{if}

    end;{else}
  finally
    //Mutex freigeben
    if dwMutex <> 0 then ReleaseMutex(dwMutex);
  end;

end.

[Luckie]

Warum gibst du dem Fenster denn keinen eindeutigen Namen, damit du eine eindeutige Fensterklasse hast? Aber ohne den Titel zu kennen oder ohne eine eindeutige Klasse, wird es wohl so gut wie unmöglich. Du kannst dir zwar alle Fenster auflisten lassen, aber wie willst du sie unterscheiden? An die Objekteigenschaften der TForm Instanz wirstd u nicht drankommen, denke ich.

[Aurelius]

Wäre es nicht möglich den Klassennamen eindeutiger zu benennen, z.b. frmTabMain?

[TUX_der_Pinguin]

Naja ich hab mir das so angewöhnnt bei neuen Projekten das Hauptformular 'frmMain' zubennen.
Das Problem mit dem Titel ist halt, das ich zur Laufzeit prüfe in welchem Modus das Programm
läuft, Sagen wir mal Client oder Server dann hole ich mir noch aus einer DLL, jenach, Sprache
den entsprechenden Titel und zeige ihn an, und da ich an der Stelle noch nicht weiß in welchem
Modus und welcher Sprache die Anwendung läuft kann ich den Title nicht ermitteln.

Ein weiteres Problem wäre, wenn ich zum Beispiel möchte das die Anwendung nur im gleichen Modus
nicht mehrfach aufgerufen werden kann. Also nur einmal "Client" und einmal "Server" aber beides
"Client" u. "Server" sollte gehn, also müßte ich alle Nasenlang das MainForm umbennen und das
macht für mich weniger Sinn, ich suche nach einer sagen wir dynamischeren Lösung.

[Kalfany]

Eventuell hilft dir ja das weiter: Delphi-Treff: Mehrfachstart verhindern

Edit: Sorry, man sollte halt alles lesen :mrgreen:

[TUX_der_Pinguin]

Zitat:

Zitat von Kalfany

Eventuell hilft dir ja das weiter: Delphi-Treff: Mehrfachstart verhindern

Das Mutex Handle zuerstellen und somit einen Mehrfachstart zu verhindern war nie das Problem.

[Luckie]

Zitat:

Zitat von TUX_der_Pinguin

Naja ich hab mir das so angewöhnnt bei neuen Projekten das Hauptformular 'frmMain' zubennen.

Was spricht dagegen es mal ausserhalb der Gewohntheit eindeutig zu benennen? Zu mal es hier wohl auch nötig ist.

[TUX_der_Pinguin]

Zitat:

Zitat von Luckie

Zitat:

Zitat von TUX_der_Pinguin

Naja ich hab mir das so angewöhnnt bei neuen Projekten das Hauptformular 'frmMain' zubennen.

Was spricht dagegen es mal ausserhalb der Gewohntheit eindeutig zu benennen? Zu mal es hier wohl auch nötig ist.

Ansich hast du schon recht, nur müßte ich ständig das Teilumbennene da ich alle Nasenlang die Andwendung in einem anderen
Modus laufen lasse, alternativ hatte ich mir als Lösung überlegt ich belasse den Namen so und Prüfe ob es ein Button
oder Label, welches "unsichtbar" ist, auf dem Formular gibt welches mir die Anwendung im entsprechenden Modus identifiziert.

In der Art frmMain.lbl_Modus_1 oder frmMain.lbl_Modus_2, jetzt müßte ich nur schauen ob und wie ich herrausfinde ob es
eine solche Komponente in dem "gefundenen" Fenster gibt.

[Apollonius]

Eine andere Möglichkeit: Kein Mutex verwenden, sondern mit RegisterWindowMessage eine eindeutige Nachricht registrieren, diese dann an HWND_BROADCAST schicken. Die beiden Parameter sollten dabei das eigene Fensterhandle und eine Nachrichtenkonstante sein. Wenn du die entsprechende Nachricht empfängst, schickst du direkt die angegebene Nachricht an das angegebene Fenster und gibst als Parameter das eigene Handle an. Das erste Fenster merkt damit, ob schon eine Instanz existiert, und erhält gegebenenfalls auch gleich das Handle.

[TUX_der_Pinguin]

Hmm mit Window Message könnte ich das ganze auch mal versuchen, hab noch nicht so wirklich damit etwas gemacht.
Muß mir das Thema mal ansehen, wie man das ganze umsetzten könnte.

[patti]

Schau mal hier. Ich hatte selbst mal das Problem, dass ich nur den EXE-Namen (Dateinamen) gekannt habe, aber keinen Fenstertitel etc. bitsetter hat mir damals ziemlich geholfen.

Vielleicht ist das ja auch eine Lösung für dich

Patti

[Apollonius]

Um das ganze nochmal näher zu erläutern:

Delphi-Quellcode:

const WM_RESPONSE = WM_USER + 6; //WM_USER + beliebig

type
TfrmMain = class(TForm)
  procedure frmMainCreate(Sender: TObject);
protected
  procedure WndProc(var Message: TMessage); override;
  procedure ResponseMessage(var Message: TMessage); message WM_RESPONSE;
private
  fOtherHandle: HWnd;
end;

implementation

var MySpecialMessage: Cardinal;

procedure TfrmMain.frmMainCreate(Sender: TObject);
begin
  HandleNeeded; //wir brauchen ein Fenster-Handle
  MySpecialMessage := RegisterWindowMessage('Eindeutige String-Konstante');
  SendMessage(HWND_BROADCAST, MySpecialMessage, Integer(Handle), WM_RESPONSE);
  if fOtherHandle <> 0 then
  begin
    //es gibt eine andere Instanz, in dieser hat das Hauptfenster das Handle fOtherHandle
  end; 
end;

procedure TfrmMain.WndProc(var Message: TMessage);
begin
  if Message.Msg = MySpecialMessage then
    SendMessage(Message.WParam, Message.LParam, Handle, 0)
  else
    inherited;
end;

procedure TfrmMain.ResponseMessage(var Message: TMessage);
begin
  fOtherHandle := Message.WParam;
end;

[TUX_der_Pinguin]

Ich habe das ganze jetzt mal mit Windows Messages versucht, scheint auch alles zu klappen.

Projekt Datei:

Delphi-Quellcode:

program tab;

uses
  Forms,
  Windows,
  uMain in 'uMain.pas' {frmMain},
  uGlobal in 'uGlobal.pas',
  ...;

{$R *.res}

var
  //dwMessage : DWORD; in uGlobal.pas Deklariert.
  dwMutex       : DWORD;
  hWindow       : THandle;

begin
  //Ermitteln in welchem Modus das Programm läuft
  glPrgMode := fGetProgMode;  //glProgMode ist ein Integer-Wert

  // Eigene Message erzeugen
  dwMessage := RegisterWindowMessage('{110E0C4D-A63F-4B36-829D-3847E28636AF}');

  //Mutex erzeugen
  dwmutex := CreateMutex(nil, True,  '{B2662A89-1938-4799-9F8D-11FBD5179EA9}');
  try
    //prüfen ob die Anwendung bereits läuft...
    if GetLastError <> ERROR_ALREADY_EXISTS then begin
      Application.Initialize;
      Application.MainFormOnTaskbar := True;
      Application.Title := '';
      Application.CreateForm(TfrmMain, frmMain);
      Application.CreateForm(TfrmSplashScreen, frmSplashScreen);
      Application.OnMessage := frmMain.OnAppMsg;
      Application.Run;
    end
    else begin
      //Windows Botschaft an alle Fenster schicken...
      PostMessage(HWND_BROADCAST, dwMessage, glPrgMode, 0);
    end;{else}
  finally
    //Mutex freigeben
    if dwMutex <> 0 then ReleaseMutex(dwMutex);
  end;

end.

Und hier die Application.OnMessage Prozedur:

Delphi-Quellcode:

procedure TfrmMain.OnAppMsg(var Msg: TMsg; var Handled: Boolean);
begin
  Handled := False;

  if Msg.message = dwMessage then begin
    if Msg.wParam = glPrgMode then begin
      //ShowWindow(Application.MainFormHandle, SW_NORMAL);
      Application.Restore;
      SetForegroundWindow(Application.MainFormHandle);
    end;
    Handled := True;
  end;

end;

Jedoch habe ich an der Stelle noch das Problem, das ich mein Fenster bzw.
meine Anwendung nicht vernüftig wiederhergestellt bekomme.

[Vjay]

Dann mach dazu mal ein neues Thema auf, das Problem ist ja gelöst. Vielleicht hilft dir die Suche nach forceForegroundWindow, falls der Fokus das Problem ist.