with sender

[jangbu]

Hallo,

habe mehrere Panels, will über eine procedure "panelclick" und die Abfrage des Senders die Eigenschaften des jeweils geclickten Panels verändern um nicht für jedes Panel eine eigene onclick prozedure erstellen zu müssen. Ich bekomme keine Fehlermeldung, wenn ich das programm debuge springt es auch in den richtigen if bzw else-zweig, jedoch ändert sich die erwartete Eigenschaft nicht. Ich wollte eigentlich, dass zur Laufzeit "with Sender" in z.B. "with Panel2" übersetzt wird! Was mach ich falsch?

Delphi-Quellcode:

procedure TForm1.Panel1Click(Sender: TObject);
begin
  panelclick(Sender)
end;

procedure TForm1.Panel2Click(Sender: TObject);
begin
  panelclick(Sender)
end;

procedure TForm1.panelclick(Sender: TObject);
begin
  with Sender do
  begin
    if BevelOuter = bvRaised then
      BevelOuter := bvLowered
    else
      BevelOuter := bvRaised;
  end;
end;

jangbu

[edit=SirThornberry]delphi-tags gesetzt - nächstes mal bitte selbst machen. Mfg, SirThornberry[/edit]

[SubData]

Versuchs mal so:

Delphi-Quellcode:

 with (Sender as TPanel) do

[sirius]

Du kannst in deinen Panels (im OI) auch anstatt des Standardereignisnamens eine eigene Methode eintragen (und dann in jedem dieselbe)

Es gibt Eigenscaften von Fenstern, die kann man nur beim erstellen des Fensters einstellen. Nachträgliche änderungen werden von Windows nicht berücksichtigt. Vielleicht gehört Bevel dazu.

[uligerhardt]

Noch besser - weg mit dem with:

Delphi-Quellcode:

procedure TForm1.panelclick(Sender: TObject);
var
  Panel: TPanel;
begin
  Panel := Sender as TPanel;
  if Panel.BevelOuter = bvRaised then
    Panel.BevelOuter := bvLowered
  else
    Panel.BevelOuter := bvRaised;
end;

Nebenbei: Dir reicht ein OnClick-Handler. Einfach Panel2 selektieren, im OI OnClick markieren, die Combo aufklappen und dort Panel1Click auswählen.

HTH,
Uli.

[RavenIV]

Zitat:

Zitat von uligerhardt

Noch besser - weg mit dem with

Sehr guter Tip.
Das WITH ist meistens unnötig und verwirrt sowohl Mensch wie auch Compiler/Debugger

Zitat:

Zitat von uligerhardt

Nebenbei: Dir reicht ein OnClick-Handler. Einfach Panel2 selektieren, im OI OnClick markieren, die Combo aufklappen und dort Panel1Click auswählen.

Ich finde es auch immer blöd, wenn bei allen Panels im OnClick "Panel1Click" steht.
Dann doch eine "PanelClick" und diese überall eintragen.

[DeddyH]

Und hier eine Variante mit Typprüfung:

Delphi-Quellcode:

procedure TForm1.panelclick(Sender: TObject);
var
  Panel: TPanel;
begin
  if Sender is TPanel then
    begin
      Panel := Sender as TPanel;
      if Panel.BevelOuter = bvRaised then
        Panel.BevelOuter := bvLowered
      else
        Panel.BevelOuter := bvRaised;
    end;
end;

[Cyf]

Habs mal kurz umgebaut. (Klar, dass Visible nie false sein wird, ist mir auch klar, aber es geht um die Theorie und das sieht man gut...)
Nurmal um den Unterschied bei der vorhanden Version klar zu machen, vielleicht hilft es ja jemanden, wenn der das mal liest:

Delphi-Quellcode:

with (Sender as TPanel) do
  begin
    if Visible = true then
      Visible := false
    else
      Visible := true;
  end;

Macht was es soll, löst z.B. ein Button aus irgendeinem Grund das ganze aus, gibts eine Exception.
[EDIT] Mit Deddy's Variante lässt sich diese verhindern, indem man vorher überprüft, ob der Typ stimmt, ob das sinnvoll ist hängt von der Situation ab, z.B. wenn man eine Prozedur mehrere Ereignisse für verschiedene Komponenten bereit hält. Jedoch verhindert das Ganze auch das man die Exception zu sehen bekommt und so eventuell nicht erfährt, dass aus irgend einem Grund falsche Komponenten der Auslöser sind.[/EDIT]

Delphi-Quellcode:

with TPanel(Sender) do
  begin
    if Visible = true then
      Visible := false
    else
      Visible := true;
  end;

Macht zunächst auch was es soll, würde aber auch für den Button funktionieren und keinen Fehler produzieren (was hier nicht gewollt ist, sonst würde man einen entsprechende Vorfahren nehmen und das auch besser mit as).

Delphi-Quellcode:

with (Sender) do
  begin
    if Visible = true then
      Visible := false
    else
      Visible := true;
  end;

Funktioniert nicht, tut aber auch etwas, bloß nicht das was man wollte. Das Form wird dies in diesem Fall auswerten und verschwinden.

Und wie genannt, ist es hier eleganter gleich das OnClick Ereignis entsprechend zu setzen (geht übrigens auch zur Laufzeit noch).

[tomsel]

Zitat:

Zitat von DeddyH

Und hier eine Variante mit Typprüfung

... und das sogar doppelt.


Ich schließe mich auch noch mit einer weiteren Variante an:

Delphi-Quellcode:

procedure TForm1.panelclick(Sender: TObject); 
begin 
  if Sender is TPanel then 
    begin 
      if TPanel(Sender).BevelOuter = bvRaised then 
        TPanel(Sender).BevelOuter := bvLowered 
      else 
        TPanel(Sender).BevelOuter := bvRaised; 
    end; 
end;

Du erhälst natürlich keine Fehlermeldung, weil TForm ebenfalls die eigenschaft BevelOuter besitzt. Du änderst also BevelOuter des Forms, und nicht des Panels (letzteres hast du ja schon gemerkt). Wie du siehst, kann dieses With eine tückische Fehlerquelle sein und ich sage ebenfalls: Weg damit, zumindest, wenn man nicht 100%ig sicher ist, was da passiert.

[jangbu]

Danke, super, passt!

jangbu

[DeddyH]

Zitat:

Zitat von tomsel

Zitat:

Zitat von DeddyH

Und hier eine Variante mit Typprüfung

... und das sogar doppelt.

Lieber doppelt als gar nicht, oder? :mrgreen:

[RavenIV]

Zitat:

Zitat von Cyf

Delphi-Quellcode:

with TPanel(Sender) do
  begin
    if Visible = true then
      Visible := false
    else
      Visible := true;
  end;

Nur so als Hinweis an die Allgemeinheit mal wieder.
Niemals eine Boolsche Variable auf True prüfen.
Dies kann auch in die Hose gehen, weil Boolean eigentlich "nur" ein Integer ist und True alles ungleich 0 ist.

Dies reicht vollständig:

Delphi-Quellcode:

if MyPanel.Visible then

[shmia]

Kürzer geht's nicht: ;-)

Delphi-Quellcode:

with TPanel(Sender) do Visible := not Visible;

[Cyf]

Ja habt ja recht, normal tuh ich das auch nicht, hatte nur grad so schön das Ding einfach aufs erstbeste umgeschreiben, ohne zu denken :wink: (in dem Fall ist die Überprüfung ohnehin hinfällig, weil man niemals auf etwas unsichtbares klicken wird)

Zitat:

Delphi-Quellcode:

with TPanel(Sender) do Visible := not Visible;

Wenn schon dann

Delphi-Quellcode:

with (Sender as TPanel) do Visible := not Visible;

außerdem ist das with dann überflüssig (und zudem soll das Wort with ja Leute beißen...)

Zitat:

weil Boolean eigentlich "nur" ein Integer ist und True alles ungleich 0 ist

Sicher? Ist es nicht eher ein Byte (ohne die Größe grad geprüft zu haben)?

[SubData]

Nein, ist definitiv ein Integer

[Cyf]

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var aBool: Boolean;
begin
  Showmessage(Inttostr(SizeOf(aBool)));
end;

Gibt bei mir 1 aus? Sollte das allerdings tatsächlich 4 Byte groß sein und das Programm lügt mich aus irgendwelchen Fragmentierungsgründen an, hab ich wieder einen Grund mehr, Einstellungen lieber in Sets zu speichern.

[SubData]

Oh, ich muss mich korrigieren.

Du hast natürlich recht.
Ein einfacher Boolean hat nur ein Byte.
Aus Kompatiblitätsgründen gibt es allerdings noch ByteBool und LongBool.

Verzeihung, mein Fehler.

[RavenIV]

Aus der Delphi7-Hilfe:

Zitat:

Es gibt vier vordefinierte Boolesche Typen: Boolean, ByteBool, WordBool und LongBool. In der Praxis wird in erster Linie der Typ Boolean verwendet. Die anderen Typen dienen der Kompatibilität zu anderen Sprachen und Betriebssystembibliotheken.

Eine Boolean-Variable belegt ebenso wie eine ByteBool-Variable ein Byte Speicherplatz. Eine WordBool-Variable belegt zwei (ein Word) und eine LongBool-Variable vier Bytes (zwei Word).

[OldGrumpy]

Also nochmal zusammengefasst:

Delphi-Quellcode:

Procedure TForm1.panelclick(Sender: TObject);
Begin
  if (Sender as TPanel).BevelOuter = bvRaised then //integraler Typencheck mit as
  Begin
    //Typencheck hier schon erfolgt, daher nicht nochmal notwendig
    //kleiner Performancevorteil, hier zwar nicht relevant, aber trotzdem :)
    TPanel(Sender).BevelOuter := bvLowered; 
  End
  Else
  Begin
    TPanel(Sender).BevelOuter := bvRaised;
  End;
End;

An passender Stelle, z.B. im FormCreate dann noch setzen:

Delphi-Quellcode:

panel1.OnClick := panelclick;
Panel2.OnClick := panelclick;
panel3.OnClick := panelclick;
[...]

//edits: aufhübschen ;)