Form einer Parabel folgen lassen

[Helmi]

Hallo,

mittels folgenden Code positionier ich eine Form über eine Strecke in 10 Schritten:

Delphi-Quellcode:

procedure TSplashScreenForm.Timer_BewegungTimer(Sender: TObject);
begin
  //
  If count < 10 then
    begin
      //SplashScreen in die linkere obere Ecke bewegen, mit 10 Schritten
      Left  := Left_alt - round(count / 10.0 * Left_alt);
      Top   := Top_alt - round(count / 10.0 * Top_alt);

      inc(count);
    end
  else
    begin
      //Timer beenden
      Timer_Bewegung.Enabled  := false;

      //Variable setzen, dass SplashScreen in Position ist
      F_SS_in_Position        := true;
    end;
end;

Nun würd ich gerne die Form über eine Parabel in 10 Schritten positionieren lassen.
Sprich, die Bewegung soll nicht einer Strecke folgen, sondern einer Parabel.

Nun ist Mathematik schon länger her. Die Formel für eine Parabel lautet y = x².
Nur wie kann ich das auf den Code anwenden?

[nachti1505]

Delphi-Quellcode:

count := -5;
OriginalLeft := Left;
OriginalTop := Top;

while count < 5 do begin
  Left := OriginalLeft + Count;
  Top := OriginalTop + (Count * Count);
  inc(Count);
end;

Ungefähr so...

[Helmi]

Danke!

[Helmi]

eine Frage hätt ich noch:

Wie kann ich von einer gegebenen Position zu einer neuen Position die Form über eine Parabel bewegen lassen?

[Khabarakh]

Es sei (x1|y1) der Start-, (x2|y2) der Endpunkt der Bewegung.
Im Endpunkt muss gelten: y2-y1 = a (x2-x1)² -> a = (y2-y1) / (x2-x1)²
Wenn du Left wie in deinem ersten Beitrag gleichmäßig (linear) von x1 bis x2 laufen lässt, ergibt sich für jeden Schritt:

Delphi-Quellcode:

Top := y1 + a * Sqr(Left - x1)

[Helmi]

oh - wunderbar - Danke!

Jetzt muss ich nur noch etwas an den Werten feilen - aber es schaut schon mal ganz gut aus...

[Edit]
Irgendwie komm ich aber nicht auf den Endpunkt

[Khabarakh]

Zitat:

Zitat von Helmi

Irgendwie komm ich aber nicht auf den Endpunkt

Wenn Left x2 wird, wird auch Top y2, soviel steht in meiner Formel fest ;) . Ansonsten bräuchten wir mal etwas Code.

[Helmi]

hier mal der Code:

Delphi-Quellcode:

procedure TSplashScreenForm.FormActivate(Sender: TObject);
begin
  //Variablen vordefinieren
  Left_alt          := Left;
  Top_alt           := Top;
  count             := 1;
end;


procedure TSplashScreenForm.Timer_BewegungTimer(Sender: TObject);

begin
  //
  If count < const_max_count then
    begin
      //Bewegung des SplashScreens abhängig von der ausgewählten Version
      //      Left  := Left_alt - count;
      //      Top   := Top_alt - (count * count);


      //Top = y1 + ((y2-y1) / (x2-x1)²) * Sqr(Left - x1)



      Left  := Left_alt - round(count / 10.0 * Left_alt);
//      Top   := Top_alt - y;

       Top := Left_alt + round( ((  (const_Endpos_X - Left_alt) / ((const_Endpos_Y - Top_alt) * (const_Endpos_Y - Top_alt))  ) * Sqr(Left - Left_alt)) );

      end;

      inc(count);
    end
  else
    begin
      //Timer beenden
      Timer_Bewegung.Enabled  := false;

      //Variable setzen, dass SplashScreen in Position ist
      F_SS_in_Position        := true;
    end;
end;

[Khabarakh]

Da hast du aber einiges in meiner Formel verdreht ;) .
Ich habe mal Struktur und Formatierung verändert, so funktioniert es bei mir:

Delphi-Quellcode:

const
  DestX = 100;
  DestY = 100;

[...]

procedure TSplashScreenForm.FormActivate(Sender: TObject);
begin
  //Variablen vordefinieren
  Left_alt          := Left;
  Top_alt           := Top;
  count             := 1;
  a := (DestY - Top_alt) / Sqr(DestX - Left_alt);
end;

procedure TSplashScreenForm.Timer_BewegungTimer(Sender: TObject);
begin
  If Left <> DestX then
  begin
    Left := Left_alt + Round(Count / 10.0 * (DestX - Left_alt));
    Top := Top_alt + Round(a * Sqr(Left - Left_alt));

    inc(count);
  end
  else
    TimerBewegung.Enabled  := false;
end;

[Helmi]

Danke für den Code.
Nur leider bewegt sich die Form fast linear in die Endpositionen

Eigentlich sollte ja die Form erst in einem Bogen nach unten gehen und dann eben in die Endpositionen

[Khabarakh]

Gut, dass man das auch mal erfährt ;) ...
Bei meiner Formel startet die Form im Parabelscheitel. Wenn das nicht so sein soll, musst du schon festlegen, wie weit sie sich erst nach unten bewegen soll.

[Helmi]

Zitat:

Zitat von Khabarakh

Gut, dass man das auch mal erfährt ;) ...
Bei meiner Formel startet die Form im Parabelscheitel. Wenn das nicht so sein soll, musst du schon festlegen, wie weit sie sich erst nach unten bewegen soll.

Ja sorry - hätt ich villeicht dazu sagen sollen :-)

Ich dachte eher so: Der Mittelpunkt zwischen Start-Position und Endposition ist der Parabelscheitel.
Dir Form bewegt sich erst in den Scheitel und kommt dann zur Endposition

[Khabarakh]

Zitat:

Zitat von Helmi

Ich dachte eher so: Der Mittelpunkt zwischen Start-Position und Endposition ist der Parabelscheitel.

Du meinst den X-Wert des Scheitels? Der läge aber nur genau in der Mitte, wenn Anfang und Ende den gleichen Y-Wert besitzen, tun sie das?
Ansonsten bräcuhte ich wie gesagt nur eine Angabe, wie tief der Scheitel liegen soll, der X-Wert ergibt sich dann von selbst.
Im Anhang mal, wie ich es verstanden habe. Parameter sind rot: Anfang, Ende, Scheitel-Y

[Helmi]

Wäre ein angebbarer Y-Scheitelwert kompliziert?

Die Form sollte halt nicht aus dem Screen rausbewegt werden.
Also immer sichtbar - und nicht am Screen-Bottom anstoßen

[Khabarakh]

Zitat:

Zitat von Helmi

Wäre ein angebbarer Y-Scheitelwert kompliziert?

Läuft auf eine quadratische Gleichung hinaus, nehmen wir vielleicht doch was Einfacheres :stupid: .
Wie wäre es mit einer quadratischen Bezier-Kurve? Dort hast du neben Start- und Endpunkt noch einen dritten Punkt, dem sich die Kurve annähert. Simpel, aber trotzdem hübsch :mrgreen: .

Delphi-Quellcode:

procedure TSplashScreenForm.Timer_BewegungTimer(Sender: TObject);
var
  t: Real;
begin
  If Count < 10 then
  begin
    t := Count / 10;
    Left := Round(Sqr(1-t) * P0.X + 2 * t * (1-t) * P1.X + Sqr(t) * P2.X);
    Top := ...

[Helmi]

Hey - Danke!

Das Ding schaut ja echt heiss aus :-)

[Edit]
Hier mal mein Code:

Delphi-Quellcode:

  private
    { Private-Deklarationen }
    P0   : TPoint;
    P1   : TPoint;
    P2   : TPoint;

    count: Integer;

{ ... }

procedure TSplashScreenForm.FormActivate(Sender: TObject);
begin
  //Positionen für die Bézierkurve angeben
  P0.X := Left;                  //Startposition X
  P0.Y := Top;                   //Startposition Y
  P2.X := 50;                    //Endposition X
  P2.Y := 50;                    //Endposition Y
  P1.X := (P0.X - P2.X) div 2;   //Kontrollpunkt X
  P1.Y := (P0.Y - P2.Y) div 2;   //Kontrollpunkt Y

  //prüfen welche Position von P0 oder P2 größer ist, und dann diese Position
  //auf P1 draufrechnen
  If P0.Y > P2.Y then
    P1.Y := P1.Y + P0.Y
  else
    P1.Y := P1.Y + P2.Y;

  //Variablen vordefinieren
  count := 1;
end;

procedure TSplashScreenForm.Timer_BewegungTimer(Sender: TObject);
var
  t: Real;

begin
  If Count <= 10 then
    begin
      //Bézierkurve berechnen
      //Formel: C(t) = (1 - t)² * P0 + 2 * t * (1 - t) * P1 + t² * P2
      //http://de.wikipedia.org/wiki/B%C3%A9zierkurve#Quadratische_B.C3.A9zierkurven_.28n.3D2.29

      t     := Count / 10;

      Left  := Round(Sqr(1 - t) * P0.X + 2 * t * (1 - t) * P1.X + Sqr(t) * P2.X);
      Top   := Round(Sqr(1 - t) * P0.Y + 2 * t * (1 - t) * P1.Y + Sqr(t) * P2.Y);

      //Variable um eins erhöhen
      inc(count);
    end
  else
    begin
      //Timer beenden
      Timer_Bewegung.Enabled  := false;
    end;
end;