Rundenzähler für mehrere Läufer (Delphi 7 Prof)

[JIP0815]

Moin,

haben mir vorgenommen ein Program zu schreiben, welches jedem Läufer (Startnummer z.B.:0-100)
eine Runde addiert und zwar indem man die Zahl (Startnummer) in ein Editfeld schreibt und dann ENTER
bzw. den Button klickt.

Nun mein Problem:

Ich habe keine Erfahrung mit den Arbeiten an Tabellen über Delphi und würde euch gerne
darum bitten mir evtl nen kleines Tutorial zu schreiben, indem Delphi über nen Befehl
die Zeilen in der Spalte1 abfragt und den Wert in der Spalte2 der gesuchten Zeile um 1 verändert.

Zitat:

Sprich:
Läufer 35 überquert die Ziellinie
035 wir in das Editfeld eingegeben und ENTER wird gedrückt
Zeile35 wird gesucht
In Spalte2 der Zeile35 wird die Rundenzahl um 1 erhöht

Wie wählt man bestimmte Zeilen an und wie bearbeitet man bestimmte Spalten????

Gruß

JIP0815

[jfheins]

Geht es um Datenbanken?

Wenn ja, sollte es reichen das passende SQL Kommando abzusetzen. (update tabelle set runde=runde+1 where id=5)

[blackfin]

Ich hab dir mal ein (zugegebenermaßen sehr simples) Beispiel mit einem TListView angehängt.
Von Interesse ist für dich dabei die Prozedur InsertOrUpdateRunner().
Schau es dir einfach erstmal an, dabei lernt man am meisten, aber ohne Gewähr auf Schönheit :)
(und eine Abfrage, ob man wirklich eine Nummer eingegeben hat, ist auch noch nicht drin)
Wenn du die Liste sortiert haben willst, musst du nur beim EventView den SortType auf "stText" stellen.

[hoika]

Hallo,

Zitat:

darum bitten mir evtl nen kleines Tutorial zu schreiben, indem Delphi über nen Befehl
die Zeilen in der Spalte1 abfragt und den Wert in der Spalte2 der gesuchten Zeile um 1 verändert.

Zu Datenbanken gibt es hier genug Tutorials.

Übrigens solltest du das wirklich zuerst lesen ... ;)

Spalte = Feld
Zeile = Set

Jede "Zeile" bekommt in der Tabelle eine eindeutige Nummer (nicht die Start-Nummer !).

Code:

Id  StartNo  Runde
1   1        25
2   100      20

Dann lautet der SQL-Befehl (Tabellen-Name hier TableX)

Delphi-Quellcode:

Update TableX
Set Runde=Runde+12
Where StartNo=100

PS:
Wie kann ich eigentlich das Id Start_No Runde anständig formatieren ???


Heiko

[DeddyH]

Zitat:

Zitat von hoika (Beitrag 1036990)

PS:
Wie kann ich eigentlich das Id Start_No Runde anständig formatieren ???


Heiko

In Code-Tags einschließen?

Code:

ID   Start_No  Runde
1    100       1
2    45        2

[JIP0815]

Vielen Dank

Ich habe das mit dem InsertOrUpdate wohl vorerst verstanden und werden mein Programm
(in erweiterter Form) so gestalten wie das Programm von Blackfin (Danke nochmals).

Mit den SQL und ID etc. werd ich mich mal ein wenig umschauen.

:thumb:

JIP

P.S.: Gibt es eine Möglichkeit diese Tabelle anhand der Rundenzahlen zu sortieren?

[scrat1979]

SQL-Code:

SELECT * FROM tablename
ORDER BY Runde ASC

... aber schau Dir mal die SQL-Basics an, dann wird wirklich vielen klar!

[DeddyH]

Ööhmm... in dem Beispielprogramm wird keine DB verwendet ;)

[blackfin]

Zitat:

Ööhmm... in dem Beispielprogramm wird keine DB verwendet

Davon war im ersten Post auch gar nicht die Rede, deswegen ist mein Beispiel ohne DB mit einem simplen TListView :-)
Wenn eine Datenbank von Nöten ist, dann ist mein Beispiel natürlich nicht ganz das richtige, obwohl man ja auch die TListView-Items aus einer Datenbank laden und in diese speichern könnte.
Da bieten sich dann aber solche Sachen wie DBGrid doch mehr an :-)

Zitat:

Gibt es eine Möglichkeit diese Tabelle anhand der Rundenzahlen zu sortieren?

Die einfachste Möglichkeit in meinem Beispiel mit TListview wäre, die Runde einfach statt dem Läufer in die erste Spalte ("Caption") zu setzen, dann sortiert er bei SortType "stText" nach der Runde. Der ListView sortiert nämlich immer per standard nach der ersten Spalte.
Willst du es nach der zweiten Spalte sortieren, brauchst du das OnCompare-Event vom Listview, in dem du dir dann deine eigene Sortier-Routine zusammenbastelst.
Dazu gibts auch ein kleines Tutorial:
http://www.latiumsoftware.com/en/delphi/00011.php

[DeddyH]

Ich bezog mich auch auf den Post von Scrat: SQL nützt in Deinem Programm ja nix ;)

[JIP0815]

@Blackfin:

Danke für den Link und deinen Tipp, habe aber wahrscheinlich eine bessere Lösung gefunden:

http://www.latiumsoftware.com/en/delphi/00001.php

Ich würde gerne die Liste (TListView) als Excel-Tabelle exportieren

Kann man das wie in dem oberen Link beschrieben machen???

Könnte mir jemand kurz schreiben welche Variablen ich in der procedure ersetzten muss?!:

Delphi-Quellcode:

procedure SaveFile(const FileName: TFileName;
                   const content: string);
begin
  with TFileStream.Create(FileName, fmCreate) do
    try
      Write(Pointer(content)^, Length(content));
    finally
      Free;
    end;

SOll ich unter (T)FileName den Namen der Excel-Tabelle inkl. Pfad angeben??
Ist TFileStream := TListView???


Gruß

JIP

[blackfin]

Nee, also so einfach kannst du ein Excel-Format (XLS) nicht schreiben, das kann Delphi nicht "out of the box" :)
Willst du XLS schreiben, brauchst du entweder eine Komponente, die das kann (kostet meist was), oder du schreibst dir das selbst (sehr aufwändig und ziemlich komplex).

Alternativ-Vorschlag:
Ich würde die Reihen und Spalten des TListView mit einem TFileStream in eine CSV-Datei schreiben, die kannst du dann ganz leicht ins Excel importieren.
Dazu gehst du einfach Zeile für Zeile durch und schreibst den Inhalt der Zellen einfach raus.

Wie eine CSV-Datei aufgebaut ist, findest du hier
Wikipedia: CSV-Datei

Zitat:

Ist TFileStream := TListView???

Huh? Das verstehe ich jetzt nicht. TFileStream ist ein Datei-Stream und ein TListView ist eine sichtbare VCL-Komponente.
Die haben erstmal nichts gemeinsam....

[JIP0815]

Delphi-Quellcode:

procedure TForm1.LEditKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
if (key = 13) then
begin
 Stream:= TFileStream.Create('.\Liste.csv', fmCreate);
  try
    Stream.WriteComponent(EventView);
  finally
    Stream.Free;
    end;
    end;
end;

so erzeuge ich jetzt meine Liste....

Nun hab ich aber das Problem, dass ich nicht nur die Tabelle, sondern auch die Eigenschaften etc. dadrin stehen habe

Gibt es da noch ne elegantere und genauso einfache Lösung?



P.S.:

Zitat:

Nee, also so einfach kannst du ein Excel-Format (XLS) nicht schreiben, das kann Delphi nicht "out of the box"
Willst du XLS schreiben, brauchst du entweder eine Komponente, die das kann (kostet meist was), oder du schreibst dir das selbst (sehr aufwändig und ziemlich komplex).

Wie wärs mit der Excel-Komponente aus dem Reiter "Server"?
Leider ist mir die Geschichte mit der Excel-Anwendung im Hintergrund etwas zu kompliziert.

[Klaus01]

Guten Abend,

wenn Du "nur" die Captions der ListView abspeichern willst.
Würde ich das mit einer StringList erledigen.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  sl : TStringList;
  i: Byte;
begin
   sl := TStringList.Create;
  try
    for i:=0 to listView1.Items.Count -1 do
      sl.add(listView1.Items[i].caption);
    sl.SaveToFile('.\Liste.csv');
  finally
    sl.free;   
  end;
end;

Grüße
Klaus

[JIP0815]

Guten Morgen,


Mhh irgendwas stimmt da bei mir noch nicht.


Also soweit ich das beurteile kann ist das ganze an sich nicht schlecht, würd es den bei mir funktionieren :)

Werd noch ein bissen rumprobieren, vielleicht find ich ja noch die Lösung.

Gruß

JIP

[JIP0815]

Problem teils gelöst:

i kann nicht als Byte sondern nur als Integer gesetzt werden


Nun habe ich aber noch das Problem, das zwar die Läufernummer, aber nicht die Rundenzahl in die Datei geschrieben wird :cry:

Die Caption sollte wenn möglich als Tabelle gespeichert werden.

Nochmal Gruß


J!P

[Klaus01]

Hallo J!P,

wie ist denn Deine EventView aufgaut?

LäuferNr Rundenzahl

Grüße
Klaus

[JIP0815]

Zitat:

LäuferNr Rundenzahl

genau so :D

Gruß

J!P

[Klaus01]

Hi J!P,

hat etwas länger gedauert...

Grüße
Klaus

Delphi-Quellcode:

// befüllen des ListView
procedure TForm1.Button1Click(Sender: TObject);
var
  item:TListItem;
  i: Byte;
begin
  ListView1.Columns[0].Caption:='Läufer';
  ListView1.Columns[1].Caption:='Runde';

  for i:=0 to 5 do
    begin
      item := ListView1.Items.Add;
      item.Caption:='Alice'+IntTostr(i);;
      item.SubItems.Add(intToStr(i));
    end;
  ListView1.Items[0].SubItems[0]:='123';

end;

//auslesen des ListView
procedure TForm1.Button2Click(Sender: TObject);
var
  i,j: Byte;
  sl : TStringList;
  s : AnsiString;
begin
  sl := TStringList.Create;
  try
    for i:= 0 to ListView1.Items.count -1 do
      begin
        s:= ListView1.Items[i].Caption;
        for j:= 0 to ListView1.Items[i].SubItems.Count -1 do
          s:= s+' ; '+ ListView1.Items[i].SubItems[j];
        sl.add(s);
      end;
    //Anzeigen des ListView Inhalt in einem TMemo
    Memo1.lines.Assign(sl);
  finally
    sl.free;
  end;
end;

end.

[JIP0815]

Moment.... das ist doch nicht zum abspeichern der Tabelle, sondern zum erstellen eines TListView.

Dass habe ich ja schon.
Hier mal der komplette Code:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)

    EventView: TListView;
    Label1: TLabel;
    LEdit: TEdit;
    procedure LEditKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
    procedure InsertOrUpdateRunner(RunnerNumber: string) ;
    procedure LEditKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;
  Stream: TFileStream;
    sl : TStringList;
  i: Integer;
  o: Integer;
  Laeuferfeld: Record
    Laeufernummer,
    Runde: Integer; end;
implementation

{$R *.dfm}


procedure TForm1.InsertOrUpdateRunner(RunnerNumber: string) ;
var
  i: Integer ;
  FFound : boolean ;
  FNewround : Integer ;
begin
   FFound := false ;

   for i := 0 to (EventView.Items.Count -1) do
   begin

      if(EventView.Items[i].Caption = RunnerNumber) then
      begin
         FNewround := StrToInt(EventView.Items[i].SubItems[0]) + 1 ;
         EventView.Items[i].SubItems[0] := IntToStr(FNewround) ;
         FFound := true;
         break ;
      end;
   end;


   if (not FFound) then
   begin
      with EventView.Items.Add do
      begin
         Caption := RunnerNumber ;
         Subitems.Add('1') ; 
      end;
   end;

end;


procedure TForm1.LEditKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
begin      
  if(Key = 13) then
  begin
   InsertOrUpdateRunner(LEdit.Text);
   LEdit.Text:=' ';
end;


end;



procedure TForm1.LEditKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
if (key = 13) then
begin
   sl := TStringList.Create;
  try
    for i:=0 to EventView.Items.Count -1 do
      sl.add(EventView.Items[i].caption);
    sl.SaveToFile('.\Liste.csv');
  finally
    sl.free;
  end;
end;
end;
end.

nun habe ich aber das Problem, das der Code den du mir zuvor geschrieben hast nicht beide Spalten in die Datei schreibt.....

Gibt es da noch eine Möglickeit das zu verbessern?


Gruß

J!P

[Klaus01]

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
var
  i,j: Byte;
  sl : TStringList;
  s : AnsiString;
begin
  sl := TStringList.Create;
  try
    for i:= 0 to ListView1.Items.count -1 do
      begin
        s:= ListView1.Items[i].Caption;
        for j:= 0 to ListView1.Items[i].SubItems.Count -1 do
          s:= s+' ; '+ ListView1.Items[i].SubItems[j];
        sl.add(s);
      end;
    //Speichern des ListView Inhalt
    sl.saveToFile('.\Liste.csv');
  finally
    sl.free;
  end;
end;