Rückgabe von CommandLineToArgvW

[Luckie]

Folgender Code:

Delphi-Quellcode:

//type
  //TPWideCharArray = array[0..0] of PWideChar;
  //PPWideCharArray = ^TPWideCharArray;

  //function CommandLineToArgvW( lpCmdLine: PWideChar; var NumArgs: Integer): PPWideChar;
    //stdcall; external 'shell32.dll';

procedure GetCommandLineArgs(Args: TStrings);
var
  NumArgs: Integer;
  //TempArgs: PPWideCharArray;
  TempArgs: PPWideChar;
  i: Integer;
begin
  if CommandLineToArgvW(GetCommandLineW, NumArgs) <> nil then
  begin
    try
      try
        TempArgs := CommandLineToArgvW(GetCommandLineW, NumArgs);
        for i := 0 to NumArgs - 1 do
          Args.Add(TempArgs^[i]);
      except
        raise Exception.Create(SysErrorMessage(GetLastError));
      end;
    finally
      GlobalFree(THandle(TempArgs));
    end;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  GetCommandLineArgs(ListBox1.Items);
end;

Wenn ich PPWideChar und die Funktion nicht selber deklariere, siehe auskommentierten Code, bekomme ich nicht die Argumente, sondern nur die ersten drei Zeichen des Pfades.

Was muss ich ändern, damit ich die Datentypen und die Funktion nicht selber deklarieren muss, damit es funktioniert?

Entwicklungsumgebung ist Delphi 7, also nix Unicode.

[samso]

Delphi-Quellcode:

        
        for i := 0 to NumArgs - 1 do
        begin
          Args.Add(TempArgs^);
          Inc(TempArgs);
        end;

[Luckie]

Danke funktioniert. Aber warum? Kannst du mir das auch noch erklären?

[Dezipaitor]

Der Rückgabewert ist ein Zeiger auf den ersten WideChar Zeiger. Also bei mir funkz das mit PPWideCharArray.

[Luckie]

Hm, OK. Dann habe ich nur den Zugriff versemmelt. ;)

Ja mit PPWideCharArray funktioniert es bei mir auch, nur ich wollte ohne die zusätzliche Deklaration auskommen.

[samso]

Ich habe nochmal darüber nachgedacht und mir ist aufgefallen, das der Code, so wie er von mir vorgeschlagen wurde, gleich zwei Memoryleaks produziert. Hier nun eine korregierte Fassung. (Ich gehe davon aus, das die Windows-Funktionen keine Exception erzeugen werden).

Delphi-Quellcode:

procedure GetCommandLineArgs(Args: TStrings);
type
  TPWideCharArray = array[0..0] of PWideChar;
var
  NumArgs: Integer;
  TempArgs: PPWideChar;
  i: Integer;
begin
  TempArgs := CommandLineToArgvW(GetCommandLineW, NumArgs);
  try
    if TempArgs <> nil then
    begin
      for i := 0 to NumArgs - 1 do
        Args.Add(TPWideCharArray(TempArgs^)[i]);
    end
    else
      RaiseLastOSError;
  finally
    GlobalFree(THandle(TempArgs));
  end;
end;

[Luckie]

Das heißt, dieser Code
http://www.michael-puff.de/Programmi...eToArgvW.shtml
verursacht Speicherlücken? Wo entstehen diese denn?

[Dezipaitor]

Ich habe auch was :)

1. CommandLineToArgvW verwendet LocalAlloc und daher sollte LocalFree verwendet werden (das macht aber in 32bit nichts mehr aus, da es dasselbe ist. Aber MSDN sagt es halt so

2. try/except ist hier garnicht notwendig, ja sogar total falsch, da GetLastError verwendet wird, was falsche Werte liefert, weil keine Winapi so eine Exception wirft (könnte auch eine AV sein)

3. Das Prüfen des Rückgabewertes von CommandLineToArgvW auf nil ist ein Fehler, denn hier wird Speicher alloziert, jedoch nicht freigegeben. Weiterhin gibt es nur zwei Fälle, die ein nil produzieren

• Zweiter Parameter ist nil. (GetLastError = ERROR_INVALID_PARAMETER)
• LocalAlloc kann kein Speicher allokieren. (GetLastError = ERROR_NOT_ENOUGH_MEMORY)

Es wäre also besser, den Rückgabewert in eine Variable zu speichern und dann zu prüfen oder sie zu verwenden.

[samso]

Der Code

Delphi-Quellcode:

procedure GetCommandLineArgs(Args: TStrings);
var
  NumArgs: Integer;
  TempArgs: PPWideChar;
  i: Integer;
begin
  if CommandLineToArgvW(GetCommandLineW, NumArgs) <> nil then
  begin
    try
      try
        TempArgs := CommandLineToArgvW(GetCommandLineW, NumArgs);
        for i := 0 to NumArgs - 1 do
        begin
          Args.Add(TempArgs^);
          Inc(TempArgs);
        end;
      except
        raise Exception.Create(SysErrorMessage(GetLastError));
      end;
    finally
      GlobalFree(THandle(TempArgs));
    end;
  end;
end;

erzeugt zwei Speicherlöcher:
Erstes Speicherloch:

Delphi-Quellcode:

if CommandLineToArgvW(GetCommandLineW, NumArgs) <> nil then

denn das Ergebnis wird nicht freigegeben (wie Dezipaitor schon richtig schreibt)

Zweites Speicherloch:

Delphi-Quellcode:

GlobalFree(THandle(TempArgs));

denn TempArgs ist nicht mehr gültig (wegen Inc()).

[Luckie]

Ok, danke für die Erklärung.

[Garfield]

Zitat:

Zitat von samso (Beitrag 1050293)

Zweites Speicherloch:

Delphi-Quellcode:

GlobalFree(THandle(TempArgs));

denn TempArgs ist nicht mehr gültig (wegen Inc()).

Das sollte sich mit einem weiteren PPWideChar lösen lassen, welchem nach

Delphi-Quellcode:

TempArgs := CommandLineToArgvW(GetCommandLineW, NumArgs);

der Wert von TempArgs zugewiesen wird.

[samso]

Ja, das ist wohl war. Es gibt viele Wege zum Ziel. Es geht auch so:

Delphi-Quellcode:

procedure GetCommandLineArgs(Args: TStrings);
var
  NumArgs: Integer;
  TempArgs, p: PPWideChar;
  i: Integer;
begin
  TempArgs := CommandLineToArgvW(GetCommandLineW, NumArgs);
  try
    if TempArgs <> nil then
    begin
      p := TempArgs;
      for i := 0 to NumArgs - 1 do
      begin
        Args.Add(p^);
        Inc(p);
      end;
    end
    else
      RaiseLastOSError;
  finally
    LocalFree(THandle(TempArgs));
  end;
end;

Gegenüber der Lösung in Antwort #6 sieht das hier zwar nicht so schön aus, dafür übersteht es aber eine Bereichsprüfung.

[Garfield]

Man muss Prioritäten setzen. Schönheit oder Korrektheit. :wink:

[Dezipaitor]

Naja, das try finally ist hier garnicht notwendig und macht es imo unübersichtlich. Besser sollte es weg und das LocalFree in die if-Bed mit rein.

[Luckie]

Also so:

Delphi-Quellcode:

procedure GetCommandLineArgs(Args: TStrings);
type
  TPWideCharArray = array[0..0] of PWideChar;
var
  NumArgs: Integer;
  TempArgs: PPWideChar;
  i: Integer;
begin
  TempArgs := CommandLineToArgvW(GetCommandLineW, NumArgs);
  if TempArgs <> nil then
  begin
    for i := 0 to NumArgs - 1 do
      Args.Add(TPWideCharArray(TempArgs^)[i]);
    LocalFree(THandle(TempArgs));
  end
  else
    RaiseLastOSError;
end;

[samso]

Nunja, ich hatte auch darüber nachgedacht, ob das try finally notwendig ist. Ich hatte es drinn gelassen, weil die Add-funktion bei einer leeren Liste (args=nil oder args nicht gültig) eine Exception erzeugen würde. Falls man den Fall LocalFree(0) abfangen möchte (was ich nicht für notwendig halte), dann könnte man das ja auch noch auf anderen Wegen erreichen.

[himitsu]

Zitat:

Delphi-Quellcode:

for i := 0 to NumArgs - 1 do
  Args.Add(TempArgs^[i]);

Zitat:

Zitat von Luckie (Beitrag 1050233)

Danke funktioniert. Aber warum? Kannst du mir das auch noch erklären?

Delphi-Quellcode:

for i := 0 to NumArgs - 1 do
  Args.Add(TempArgs[i]);

Es müste auch funktionieren, wenn du das ^ weglassen würdest.

Über ^ dereferenzierst du den PPWideChar und der Index [i] wird dann als Zeichenindex im 1. PWideChar gezählt.
Ohne ^ wäre es aber der Index im PPWideChar, also im Array.

bzw. so müßte es auch gehn.

Delphi-Quellcode:

type TTempArgs: array[0..0] of PWideChar;
var TempArgs: ^TempArgs;

TempArgs := Ponter(CommandLineToArgvW(GetCommandLineW, NumArgs));
...
for i := 0 to NumArgs - 1 do
  Args.Add(TempArgs[i]);

[Luckie]

Danke für die Erklärung.