OnMouseOver bei Array of TPanel

[erik-17]

Hallo zusammen,

ich hab mit meinem Programm während der Laufzeit mehrere Panels (Objekte, die von TPanel abgeleitet sind) erstellt. Jetzt sollen sie, wenn ich mit der Maus rübergehe zerstört werden. Bei einem einfachen Panel läuft das ja so:

Code:

procedure TForm1.Panel1MouseOver(...);
  begin
    Panel1.destroy;
  end;

Wie mach ich das, wenn ich ein Array von den Panels habe??

[stahli]

Versuche mal, ob Dir

Delphi-Quellcode:

Visible := False;

reicht. Dann kannst Du Unsichtbare Panels später freigeben und aus dem Array entfernen.
Es ist sicherer, die Panels nur von außen zu zerstören (

Delphi-Quellcode:

FreeAndNil(MyPanel);

).

Ach so: Und zu Freigeben immer Free benutzen statt Destroy.

[erik-17]

Danke für die Antwort, aber wie weiß jetzt meine Oberflächenklasse welches Panel er unsichtbar oder sonst was machen soll.
Irgendwie so:

Code:

procedure TForm1.buntpanel[a]MouseMove(...);
begin
  buntpanel[a].visible:=false;
end;

Aber das geht irgendwie nicht...

[stahli]

Ach so, Du willst es weiterhin als Ereignisbehandlung im Formular lassen...
Dann musst Du vorhaer allen Panels die gleiche Ereignisbehandlung zuweisen und Dich dann auf den Auslöser des Ereignisses beziehen:

Delphi-Quellcode:

procedure TForm1.PanelsMouseOver(Sender: TObject);
var
  MyPanel: TPanel;
begin
  if Sender is TPanel then
  begin
    MyPanel := (Sender as TPanel);
    MyPanel.Visible := False;
  end;
end;

Ob ein MyPanel.Free an der Stelle zu Problemen führen könnte kann ich jetzt nicht ausschließen. Man sollte das sicher nicht tun, da der "Rest" der Mausreaktion in dem dann zerstörten Panel noch ausgeführt wird.

[erik-17]

ich komm damit immer noch nicht so ganz klar :(
wie soll ich allen Panels die gleiche Ereignisbehandlung zuweisen, oder war das dein quellcode?

Vielleicht war auch meine erklärung zu undeutlich:
Ich habe eine neue Klasse erstellt: TBuntPanel, die von TPanel geerbt hat.
Jedes Objekt (in TForm1 als "buntpanel: array[1..10000] of TBuntPanel" bekommt beim erzeugen eine zufällige Farbe (bis hierhin läuft es wunderbar)
Jetzt soll jedes einzelne Panel, wenn man auf eins mit der Maus geht, unsichtbar werden oder irgendwie wegkommen, und auch nur das Panel, auf dem die Maus drauf war.

Vielleicht ist das jetzt etwas besser vormuliert :-D

[xZise]

Naja du hast zwei Möglichkeiten:
Entweder du fängst innerhalb der Klasse das Ereignis ab, oder du weist allen Panels das gleiche Ereignis zu, und nimmst dann stahlis Code.

Beim ersten kannst du im Create OnMouseOverEnter auf eine Methode deiner eigenen Klasse setzen, aber dann kannst du das Ereignis nicht mehr anderweitig nutzen. Eine andere Möglichkeit wäre, da die aufrufende Methode (meißt "DoMouseOverEnter()" oder so) zu überschreiben.

Ein Beispiel:

Delphi-Quellcode:

type
  TColoredPanel = class(TPanel)
  private
    procedure MouseEnterEvent(...);
  public
    constructor Create(...);
  end;

constructor TColoredPanel.Create(...);
begin
  inherited;
  OnMouseEnter := MouseEnterEvent;
end;

procedure TColoredPanel.MouseEnterEvent(...);
begin
  Visible := false;
end;

Beim Überschreiben musst du die Methode finden, die das Event aufruft. Das ist beim Panel: procedure TControl.CMMouseEnter(var Message: TMessage);. Der Rest ist also nur geraten:

Delphi-Quellcode:

type
  TColoredPanel = class(TPanel)
  private
    procedure MyMouseEnter(var Message: TMessage); message CM_MOUSEENTER;
  end;

procedure TColoredPanel.MyMouseEnter(var Message: TMessage);
begin
  // Ursprüngliche Methode aufrufen
  CMMouseEnter(Message);
  if (Message.LParam = 0) then
    Visible := false;
end;

Bei den anderen setzt du einfach das OnMouseOver, wie eine normale Variable. D.h. es ist quasi so, als würdest du das Panel manuell auf das Forumlar platzieren. Du machst das halt eben aber automatisiert.

MfG
Fabian

[sx2008]

Zitat:

Zitat von erik-17 (Beitrag 1053316)

..."buntpanel: array[1..10000] of TBuntPanel"

Bei so vielen Panels wirst du bestimmt Probleme bekommen. Jedes Panel ist ein "Window" und hat ein Window-Handle. Die Anzahl der möglichen Handles ist aber begrenzt (nämlich 10000 pro Anwendung).
Vergiss mal das Panel und erkläre was dein Programm tun soll und wie es aussehen soll.

[erik-17]

@sx2008:
Is eine Aufgabe in Informatik (Schule).
Das Programm soll Panels erzeugen (mit Timer und als neue Klasse TBuntPanel), die, wenn man auf eins geht mit der Maus, verschwinden sollen...

[rollstuhlfahrer]

dann aber bitte kein Array sondern eine ObjectList. Wenn du dann die Panel löschst, dann hast du wenigstens nicht die Verwaltungsaufgaben für dein Array auch noch zu erledigen.

Und: Ja, es geht. Man kann mehr als nur 1 Komponente die gleiche Prozedur zur Ereignisbehandlung zuweisen.

[erik-17]

Danke für eure bisherigen Antworten :-D

Es läuft jetzt mit dem Code:

Code:

procedure TBuntPanel.MouseEnter(var Message: TMessage);
begin
    Visible := false;
end;

Es werden 1000 Panels erstellt, die man dann "kaputt" machen kann. Wenn ich in der Prozedur das Panel noch freigeben möchte, wie sollte man das machen (Free; macht bei mir irgendwann eine Zugriffsverletzung) und kann man irgendwie abfragen, ob noch ein Panel auf der Oberfläche sichtbar ist, oder überhaupt existiert (letzteres nur, wenn man die auch freigibt :-D)

[DeddyH]

Wenn Du nach dem Freigeben eines Panels dieses auf nil setzt, kannst Du anschließend mit Assigned() prüfen, ob es existiert. Da IIRC Delphi 3 noch kein FreeAndNil kennt, musst Du Ersteres wohl von Hand erledigen, aber das ist ja kein großer Aufwand.

[xZise]

Doch so wie er es macht schon. Bei ihm scheint das Fenster nicht mitzubekommen, dass ein Panel verschwindet.

Wird bei dir überhaupt noch das Event gefeuert? Ansonsten könnte man da noch das Formular dran hängen. Ich weiß nicht wie weit ihr in Informatik seit, aber es gäbe auch die Möglichkeit, dass das Panel den Fenster Bescheid sagt, das es gerade unsichtbar wurde.

Unschön über zirkuläre Referenzen (Das Fenster kennt die Panels und die Panels kennen das Fenster):

Delphi-Quellcode:

type
  TColoredPanel = class(TPanel)
....


uses
  UForm1; // Jerks ... bitte nur wenn es nicht anders geht (s.u.)

procedure TColoredPanel.MouseEnter(...
begin
  Visible := false;
  Form1.NotifyVisibility(Self); // Ein Panel ist entschwunden :D
end;

Das wäre quick & dirty: Wenn das Fenster mal nicht mehr Form1 heißt musst du es auch da ändern. Außerdem was ist, wenn mal nicht das Fenster Form1 dein Panel verwendet. Deshalb kann man das einfach mit Ereignissen regeln:

Delphi-Quellcode:

type
  TColoredPanel = class; // Definieren, dass es eine Klasse TColoredPanel gibt

  TVisibilityEvent = procedure(Sender : TColoredPanel) of object; // Definiert, einen Methodenrumpf

  TColoredPanel = class(TPanel)
  private
    FEvent : TVisibilityEvent; // Hier wird gespeichert, welche Methode aufgerufen werden soll, wenn das Panel unsichtbar wird.
    procedure MouseEnter(....
  public
    property VisibilityEvent : TVisibilityEvent read FEvent write FEvent;
  end;

procedure TColoredPanel.MouseEnter(...
begin
  Visible := false;
  if Assigned(FEvent) then // Nur das Ereignis auslösen wenn es gesetzt ist
    // Die gespeicherte Funktion aufrufen
    FEvent(Self); // Ein Panel ist entschwunden :D
end;

In der Form machst du dann:

Delphi-Quellcode:

// Wo du die Panels erstellst
var
  p : TColoredPanel;
[...]
  p.VisibilityEvent := ... // Hier das Ereignis eintragen

Und im Ereignis kannst du dann herunter zählen, oder das Panel löschen, was auch immer :)

MfG
Fabian

[erik-17]

Danke für die Antworten :)

Mit den Events komme ich noch nicht so gut zurecht...
Wenn es euch nicht zu viel ist: Was soll mann bei "p.VisibilityEvent:=" einschreiben, wenn eine Variable um eins veringert werden soll.
Sorry für die vielen Fragen, aber ich würde das ganz gerne noch schaffen :D

[stahli]

In Delphi 3 wird es bestimmt schon TList geben.
Da kannst Du nach dem Erzeugen der Panels diese anhängen (anstatt eines Arrays).

Delphi-Quellcode:

PanelList: TList;

...

Delphi-Quellcode:

PanelList := TListe.Create;

...
//für jedes erzeugte Panel:

Delphi-Quellcode:

PanelList.Add(NewPanel);

...
//später kannst Du in einer Schleife rückwärts durch die Liste gehen und unsichtbare Panels löschen:

Delphi-Quellcode:

for I := PanelList.Count - 1 downto 0 do 
begin
  TmpPanel := TMyPanel(PanelList[I]);
  if not TmpPanel.Visible then
  begin
    TmpPanel.Free;
    PanelList.Delete(I);
  end;
end;

// Die Schleife kannst Du jederzeit auslösen, z.B. in einem Timer oder nachdem ein Panel unsichtbar gesetzt wurde
// abwärts musst Du zählen, da sonst die Schleife beim löschen von Items mit dem Zähler durcheinander käme
// In PanelList.Count hast Du immer die Anzahl der existierenden Panels -> 0 = alle gelöscht
...
//Zum Schluss der Ordnung halber die Liste wieder freigeben:

Delphi-Quellcode:

PanelList.Free;

[xZise]

Zitat:

Zitat von erik-17 (Beitrag 1053371)

[...]Wenn es euch nicht zu viel ist: Was soll mann bei "p.VisibilityEvent:=" einschreiben, wenn eine Variable um eins veringert werden soll.[...]

Da gibt man eine Methode an und keine Formel:

Delphi-Quellcode:

type
  TForm1 = class(TForm) // oder wie auch immer das heißt
  private
    FInVisCount: Integer; // Speichert wie viele Panels unsichtbar wurden
    procedure OnVisibility(Panel : TColoredLabel);
  //...
  end;

So irgendwo erstellst du ja deine ganzen Panels, dort trägst du jetzt für jedes Panel ein, dass die Methode "OnVisibility" da eingetragen wird:

Delphi-Quellcode:

p := TColoredPanel.Create(Self);
p.Left := ....;
[...]
p.VisibilityEvent := OnVisibility;

Und in der Methode erhöhst du Anzahl unsichtbaren Panels um eins.

Delphi-Quellcode:

procedure TForm1.OnVisibility(Panel : TColoredLabel);
begin
  Inc(FInVisCount);
end;

Damit musst du nicht ständig durch die Liste iterieren.

Das ist so ähnlich wie bei den "OnClick" von einem Button oder so: Der Button bekommt mit das er angeklickt wurde. Dann guckt er nach, ob es eine Methode gibt, die aufgerufen werden soll, wenn es angeklickt wurde und führt sie dann aus, wenn es der Fall ist.

Dabei ist "OnVisibility" die Methode die letztlich ausgeführt werden soll (die er nachguckt, ob sie gesetzt wurde). Das setzen, das diese Methode aufgerufen werden soll, das machst du beim erstellen der Liste (p.VisibilityEvent := ...) und das ganze wird in Gang gesetzt, wenn es von der Maus berührt wurde.

MfG
Fabian

PS: Kennt D3 noch keine TObjectList?

[erik-17]

Danke Leute :-D:-D:-D
Habs jetzt geschafft :thumb:
@xZise: D3 hat schon TList :)

[stahli]

Die Frage war nach TObjectList, die vereinfacht ggf. noch ein paar Dinge.
Aber TList reicht auch.