Vokale entfernen

[Connor Temple]

Hab mal wieder ein Problem, dass diesmal tatsächlich an meinen Delphikenntnissen scheitert und nicht an meinen Mathekenntnissen *hust*

Also gut, es geht darum in einem beliebig eingebbaren Text die Vokale zu entfernen, allerdings habe ich ein Problem mit dem Delete Befehl.
Ich wollte den Text mit einer While-Do-Schleife durchgehen und dabei jeden Vokal entfernen, aber wie mache ich das?
Bei einem Delete-Befehl ist es ja so, dass man die Zahl des Zeichens mit angeben muss, aber wie macht man sowas in einem beliebig eingebbaren Text?

Hoffe ihr versteht, was ich meine und könnt mir helfen...

[mkinzler]

Man könnte es auch mit StringReplace() versuchen

[Connor Temple]

Damit weiß ich leider nicht umzugehen, ich kann nur das machen, was wir im Unterricht hatten, wir hatten Schleifen und fangen jetzt grade mit Strings an, aber mein Lehrer meinte ich solle es mit einem Delete-String machen.

[TonyR]

ja, dein Ansatz ist doch gut, zeig doch mal, was du bisher probiert hast!

[DeddyH]

Eine sehr unperformante Variante: alle Vokale in Groß- und Kleinschreibung in einem konstanten Array deklarieren. Dann dieses Array in einer Schleife durchgehen und dann in einer weiteren Schleife die Position des aktuellen Vokals ermitteln und solange löschen, bis dieser Vokal nicht mehr enthalten ist, Pos also 0 zurückgibt.

[mkinzler]

Oder mit 2 Strings: über Quellstring iterieren und nur Konsonaten/zahle usw. in Zielstring übernehmen

[himitsu]

@mkinzler: Die Aufgabe ist die Verwendung von Delete :zwinker:
(glaub ich zumindestens so verstanden zu haben)


Kennt ihr IN schon?

Delphi-Quellcode:

if s[index] in ['a', 'A', 'e', ...] then 
  Delete(s, index, 1);

// entspricht
if (s[index] = 'a') or (s[index] = 'A') or (s[index] = 'e') or ... then 
  Delete(s, index, 1);

Und nicht vergessen ... beim Löschen solltest du die Schleife rückwärts (downto) laufen lassen, da sich beim Löschen der Index verschiebt, was in einer Vorschleife nicht angepaßt wird, es sei denn man rechnet einen Offset mit ein oder verwendet eine While-Schleife.

[Connor Temple]

In haben wir leider nicht benutzt.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var Text                               :String;
    i                                  :Integer;
begin
Text := Texteingabe.Text ;
i := 1 ;
While i <= length(Text) Do
     Begin
          If Text[i] = 'a'
            Then Delete (Text, a) ;

     i := i + 1 ;
     end;
Textausgabe.Text := Text;
end;

end.

So siehts aus, mein Fehler liegt jetzt aber bei dem Delete, außerdem möchte ich das gerne für alle Vokale in Groß- und Kleinschreibung benutzen.
Aber so kommt ein Fehler, ich weiß echt nicht mehr weiter und verzweifel grad schon wieder an diesem komischen Programm, das einfach nicht versteht was ich von ihm will -.-

[Fussel9]

Hi, wir haben ähnliche programme schon einmal geschrieben vielleicht kann dir das Programm weiter hälfen (->Anhang)


€DIT:

Wenn du alle großen und kleinen Vokale und Konsonanten überprüfen willst wirst du IN benutzen müssen, sonst musst du jede Prüfung einzeln machen oder gehst mit ner or Bedingung in eine If schleife, was auch viel zu schreiben ist ^^


Beispiel:

Delphi-Quellcode:

function DeineForm.tötedievokale(deinstring: String; p:Integer) : String
var i: Integer;
    temp: String;
begin
result:='';
i:=p;
if (deinstring[i]='a') or (deinstring[i]='e') or (deinstring[i]='i')  {.... und so weiter ...} then 
begin
  temp:=copy(deinstring,1,(i-1)); //alles ohne den Vokal
  delete(deinstring,1,(i)); //alles mit dem Vokal
    if not(i = length(deinstring)) then
      begin
        i:=i+1;
        temp:=temp+self.tötedievokale(deinstring,i);
      end
    else
      begin
        temp:=deinstring;
      end;
result:=temp;
end;

[himitsu]

Zitat:

Zitat von Connor Temple (Beitrag 1066978)

So siehts aus, mein Fehler liegt jetzt aber bei dem Delete, außerdem möchte ich das gerne für alle Vokale in Groß- und Kleinschreibung benutzen.
Aber so kommt ein Fehler, ich weiß echt nicht mehr weiter und verzweifel grad schon wieder an diesem komischen Programm, das einfach nicht versteht was ich von ihm will -.-

Schön, daß man uns nie den Text der Fehlermeldung sagt.
Aber ich kann's mir zum Glück denken, da heute die Glaskugel :glaskugel: mal funktioniert.
Irgendwas vonwegen fehlendem Parameter ... niwa?
Schau mal in die OH, was sie dir zum Delete sagt.

PS:

Delphi-Quellcode:

i := i + 1;

Den Index nur herhöhen, wenn nicht gelöscht wurde (ELSE > delete oder i+1).
Den Grund nannte ich schon. (oder eben die While-Schleife am Ende des Strings loslaufen lassen und dann rückwärts zur 1 runterzählen)

[Connor Temple]

Also soll ich die "While >= length(Text)" schreiben?
Das beschriebene Index hatten wir in Verbindung mit Delete noch gar nicht.
Deswegen hab ich grad voll das Problem eure Lösungen so zu verstehen...

[Fussel9]

... welcher der folgenden Begriffe sagt die denn was:

- rekusiv
- Menge
- pos({code})
- if ...or... then

je nach dem welche du kennst kann man einen Ansatz herausarbeiten

[Aphton]

Zitat:

Zitat von Connor Temple (Beitrag 1066978)

In haben wir leider nicht benutzt.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var Text                               :String;
    i                                  :Integer;
begin
Text := Texteingabe.Text ;
i := 1 ;
While i <= length(Text) Do
     Begin
          If Text[i] = 'a'
            Then Delete (Text, a) ;

     i := i + 1 ;
     end;
Textausgabe.Text := Text;
end;

end.

So siehts aus, mein Fehler liegt jetzt aber bei dem Delete, außerdem möchte ich das gerne für alle Vokale in Groß- und Kleinschreibung benutzen.
Aber so kommt ein Fehler, ich weiß echt nicht mehr weiter und verzweifel grad schon wieder an diesem komischen Programm, das einfach nicht versteht was ich von ihm will -.-

Hab den Thread noch nicht ganz durchgelesen, aber dein Fehler ist leicht behebbar:
einfach statt Delete(Text,a) ein Delete(Text,a,1) machen.
Das heißt soviel wie: Lösche von Text, ab der Stelle a, 1 Stelle.

Edit: Warum wird hier eigentlich ständig um den heißen Brei herumgeredet?
*duck_und_weglauf

MfG

[Fussel9]

Habs, als rekursive Lösung.

d.h. das sich die procedure oder hier function in sich selbst aufruft.

das funktioniert hier z.B. so:

Ist der String leer?
-Nein
Ist der erste Buchstabe ein Vokal?
-Ja : lösche ihn und frage erneut
-Nein : merke ihn dir
_________lösche den ersten Buchstaben
_________gebe den gemerkten Buchstaben mit dem ergebniss einer erneuten prüfung aus

-Ja tue nichts


Also für das Wort 'Vokal' ergibt sich folgendes:

ist V ein Vokal?
-Nein
-result1:=V+ ist o ein Vokal?
_________-Ja
_________-result2:= ist k ein Vokal?
__________________-Nein
__________________-result3:=k+ ist a ein Vokal?
___________________________-Ja
___________________________-result4:= ist l ein Vokal?
____________________________________-Nein
____________________________________-result5:=l
_______________________________________________res ult1:=Vkl

ich glaube der Rest wird spätestens dann klar wenn du dir den Quellcode ansiehst...

:arrow:

[Connor Temple]

So, wir haben heute in der Schule die Lösung bekommen, mit Case haben wir vorher aber auch nicht gearbeitet, so sieht mein Text jetzt aus:

Delphi-Quellcode:

procedure TForm1.EntvokalisierenClick(Sender: TObject);
var Text                                    :String   ;
    i                                       :Integer  ;
begin
Text := Normaltext.Text ;

i := 1 ;

 While i <= length(Text) Do
   Begin
      Case Text[i] of
      'A','E','I','O','U','a','e','i','o','u'         :
         Begin
             Delete (Text, i, 1) ;
             i := i - 1 ;
         end;
   end;
   i := i + 1 ;

AusgabeText.Text := Text;
 end;
end;
end.

Ich musste ein bisschen selbst dazu schreiben und langsam wird es verständlicher mit Delphi umzugehen...

[DeddyH]

Das Hochzählen von i gehört aber mit in die While-Schleife, oder nicht? ;)

[mkinzler]

Und beim Löschen unbedingt die Schleife umdrehen!

[DeddyH]

Wieso? Es wird ja keine For-Schleife verwendet, da ist das in der Tat notwendig.

[user0815]

Zitat:

Das Hochzählen von i gehört aber mit in die While-Schleife, oder nicht?

Ist mit drinnen, genau wie die Ausgabe, das end gehört zum case :)

Delphi-Quellcode:

  i := 1;

  while i <= length(Text) do
  case Text[i] of
    'A','E','I','O','U','a','e','i','o','u' : Delete(Text, i, 1);
    else inc(i); // i := i + 1;
  end;

[DeddyH]

:wall: Stimmt, das liegt an der "kreativen" Einrückung.

[Fussel9]

Viele Wege führen nach Rom...

[mkinzler]

Zitat:

Zitat von DeddyH (Beitrag 1067109)

Wieso? Es wird ja keine For-Schleife verwendet, da ist das in der Tat notwendig.

Wenn du eine normale Schleife nimmst, werden doppelte Vokale auch nicht erkannt.

[DeddyH]

Ich kann Dir nicht folgen: wenn ein Vokal gefunden wird, wird er gelöscht und der Zeichenindex dekrementiert, anschließend in jedem Fall inkrementiert, so dass er auf dem nächsten Zeichen steht. Da sollten doch auch doppelte Vokale korrekt erkannt werden (gut, über das hin und her kann man sich streiten, funktionieren sollte es aber).

[mkinzler]

Ich habe den ursprünglichen Code angesehen, da fehlte das

Delphi-Quellcode:

i := i - 1;

aber eine umgekehrte Schleife würde dies auch überflüssig machen

[DeddyH]

Ich würde das ja ganz anders machen, allerdings habe ich dann kein Delete drin *g*:

Delphi-Quellcode:

function WithoutVocals(const s: string): string;
var SrcIndex, DestIndex: integer;
begin
  SetLength(Result, Length(s));
  DestIndex := 0;
  for SrcIndex := 1 to Length(s) do
    if not (Upcase(s[SrcIndex]) in ['A','E','I','O','U']) then
      begin
        inc(DestIndex);
        Result[DestIndex] := s[SrcIndex];
      end;
  SetLength(Result, DestIndex);
end;

[Connor Temple]

@DeddyH
So wie du es machst versteh ich das echt gar nicht, wir fangen ja auch grade erst mit Delphi an, da ist das okay...

[Sir Rufo]

So, dann mal passend formatiert ...

Delphi-Quellcode:

procedure TForm1.EntvokalisierenClick(Sender: TObject);
var
  Text : string;
  i : integer;
begin
  Text := NormalText.Text;

  i := 1;

  while i <= Length( Text ) do
    begin
      case Text[ i ] of
        'A','E','I','O','U',
        'a','e','i','o','u' :
          begin
            Delete ( Text, i, 1 ) ;
            i := i - 1 ;
          end;
      end;
      i := i + 1 ;

      AusgabeText.Text := Text;
    end;
end;

... und jetzt mal ein wenig optimiert ...

Delphi-Quellcode:

procedure TForm1.EntvokalisierenClick(Sender: TObject);
var
  Text : string;
  i : integer;
begin
  Text := NormalText.Text;

  i := 1;

  while i <= Length( Text ) do
    begin
      case Text[ i ] of
        'A','E','I','O','U',
        'a','e','i','o','u' :
          Delete ( Text, i, 1 ) ;
      else  // case
        i := i + 1;
      end;  // case
    end;  // while

  AusgabeText.Text := Text;
end;

... und dann noch mal so, wie es sich eigentlich gehört :mrgreen:
wegen der Trennung von Code und Oberfläche (EVA)

Delphi-Quellcode:

function Entvokalisieren( const AStr : string ) : string;
var
  i : integer;
begin
  Result := AStr;

  i := 1;

  while i <= Length( Result ) do
    begin
      case Result[ i ] of
        'A','E','I','O','U',
        'a','e','i','o','u' :
          Delete ( Result, i, 1 ) ;
      else  // case
        i := i + 1;
      end;  // case
    end;  // while

end;

procedure TForm1.EntvokalisierenClick(Sender: TObject);
begin
  AusgabeText.Text := Entvokalisieren( NormalText.Text );
end;