Image auf Form dynamisch mit der Maus at run time erstellen ?

[thomas2009]

Hi
wie kann ich eine Komponente z.B. eine Image at run time aber dynamisch mit gedrückter Maustaste auf Form erstellen kann ?

Ist das überhaupt möglich ?

[Luckie]

Hast du ein Glück, dass ich nicht schlafen kann. Gebraucht wird nur eine Listbox (Listbox1) und eine Schaltfläche (Button1).

Delphi-Quellcode:

procedure TForm14.CreateImage;
  procedure Swap(var X1, X2: Integer);
  var
    Temp: Integer;
  begin
    Temp := X1;
    X1 := X2;
    X2 := Temp;
  end;
var
  Image: TImage;
begin
  SetLength(ImageArray, Length(ImageArray) + 1);
  Image := TImage.Create(nil);
  Image.Name := 'Image' + IntToStr(Length(ImageArray));
  Image.Parent := Form14;
  if (BottomRight.Y < TopLeft.Y) then
    Swap(BottomRight.Y, TopLeft.Y);
  if (BottomRight.X < TopLeft.X) then
    Swap(BottomRight.X, TopLeft.X);
  Image.Left := TopLeft.X;
  Image.Top := TopLeft.Y;
  Image.Height := BottomRight.Y - TopLeft.Y;
  Image.Width := BottomRight.X - TopLeft.X;
  //Image.Stretch := True;
  //Image.Proportional := True;
  Image.Picture.LoadFromFile('C:\Dokumente und Einstellungen\Michael\Eigene Dateien\Eigene Bilder\apollo_8earthrise_1280.bmp');
  ImageArray[High(ImageArray)] := Image;
end;

procedure TForm14.DeleteImages;
var
  i: Integer;
begin
  for i := High(ImageArray) downto 0 do
  begin
    ImageArray[i].Free;
  end;
  SetLength(ImageArray, 0);
end;

procedure TForm14.ListImages;
var
  i: Integer;
begin
  ListBox1.Items.Clear;
  for i := 0 to ControlCount - 1 do
  begin
    if (Controls[i] is TImage) then
    begin
      ListBox1.Items.Add(Format('%s (%d / %d)', [TImage(Controls[i]).Name, TImage(Controls[i]).Width, TImage(Controls[i]).Height]));
    end;
  end;
end;

procedure TForm14.Reset;
begin
  IsMouseDown := False;
  TopLeft.X := 0;
  TopLeft.Y := 0;
  BottomRight.X := 0;
  BottomRight.Y := 0;
end;

procedure TForm14.DrawImageBounds(X, Y: Integer);
begin
  if not Assigned(ImageBoundsRect) then
  begin
    ImageBoundsRect := TShape.Create(Form14);
    ImageBoundsRect.Parent := Form14;
    ImageBoundsRect.Shape := stRectangle;
    ImageBoundsRect.Brush.Style := bsClear;
    ImageBoundsRect.Pen.Width := 1;
    ImageBoundsRect.Pen.Color := clBlack;
    ImageBoundsRect.Pen.Style := psDash;
  end;
  ImageBoundsRect.Left := TopLeft.X;
  ImageBoundsRect.Top := TopLeft.Y;
  ImageBoundsRect.Width := X - TopLeft.X;
  ImageBoundsRect.Height := Y - TopLeft.Y;
end;

procedure TForm14.DeleteImageBounds;
begin
  FreeAndNil(ImageBoundsRect);
end;

procedure TForm14.FormCreate(Sender: TObject);
begin
  DoubleBuffered := True;
end;

procedure TForm14.FormDestroy(Sender: TObject);
begin
  DeleteImages;
end;

procedure TForm14.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  IsMouseDown := True;
  TopLeft.X := X;
  TopLeft.Y := Y;
end;

procedure TForm14.FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
begin
  if IsMouseDown then
  begin
    BottomRight.X := X;
    BottomRight.Y := Y;
    DrawImageBounds(X, Y);
  end;
end;

procedure TForm14.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  if IsMouseDown then
  begin
    DeleteImageBounds;
    CreateImage;
    Reset;
    ListImages;
  end;
end;

procedure TForm14.Button1Click(Sender: TObject);
begin
  DeleteImages;
  ListImages;
end;

Die privaten Methoden der Form

Delphi-Quellcode:

procedure DrawImageBounds(X, Y: Integer);
procedure CreateImage;
procedure Reset;
procedure ListImages;
procedure DeleteImages;
procedure DeleteImageBounds;

Könnte man noch schön in einer Klasse packen, aber das überlasse ich dir.

[nuclearping]

Luckie, auch wenn es gut gemeint ist, aber dir ist schon klar, dass das der 3. oder 4. Thread von ihm zu dem Thema ist? Und du ihn gerade wieder darin bestätigt hast: Nur lange genug betteln und auf blöd machen, irgendwann findet sich schon einer.

[Luckie]

Deswegen habe ich ja auch mein Demoprojekt nicht angehangen.

[Luckie]

Hm, keine Rückmeldung. Kann es sein, dass er es doch verstanden hat und es funktioniert?

[Aphton]

Schade?

[thomas2009]

Noch nicht verstanden :? Es ist nur sinnvoll, wenn du das Demo zur Verfügung stellst.
Der Code ist zwar kalr aber was mich wundert z.B.

Delphi-Quellcode:

var
i:Integer;
begin
for i:=0 to ... // bekomme ich trotzdem error : undefinierter i !!!

[Luckie]

Schön. Und jetzt? Was gibt es da nicht zu verstehen? Beim Drücken der Maus werden sich die Anfangskoordinaten gemerkt, beim Loslassen wieder und dann wird damit das Image erstellt und in ein Array aufgenommen.

[thomas2009]

Es fehlt was im Code. Ich kann nicht das Project kompilieren. viele Variablen werden als undefiniert bezeichnet obwohl die Variablen schon deklariert !

Delphi-Quellcode:

var
i:Integer;
begin
for i:=0 to ... // bekomme ich trotzdem error : undefinierter i !!!

Code:

Erzeugen
  [Fehler] Unit1.pas(53): Undefinierter Bezeichner: 'ImageArray'
  [Fehler] Unit1.pas(53): Inkompatible Typen
  [Fehler] Unit1.pas(55): Inkompatible Typen
  [Fehler] Unit1.pas(57): Undefinierter Bezeichner: 'BottomRight'
  [Fehler] Unit1.pas(57): ')' erwartet, aber Bezeichner 'Y' gefunden
  [Fehler] Unit1.pas(59): ')' erwartet, aber Bezeichner 'X' gefunden
  [Fehler] Unit1.pas(75): Undefinierter Bezeichner: 'i'
  [Fehler] Unit1.pas(77): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(79): Inkompatible Typen
  [Fehler] Unit1.pas(82): Anweisung erwartet, aber 'PROCEDURE' gefunden
  [Fehler] Unit1.pas(98): Undefinierter Bezeichner: 'IsMouseDown'
  [Fehler] Unit1.pas(99): Undefinierter Bezeichner: 'TopLeft'
  [Fehler] Unit1.pas(100): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(101): Undefinierter Bezeichner: 'BottomRight'
  [Fehler] Unit1.pas(101): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(102): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(107): Undefinierter Bezeichner: 'ImageBoundsRect'
  [Fehler] Unit1.pas(107): Inkompatible Typen
  [Fehler] Unit1.pas(110): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(111): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(112): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(113): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(114): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(115): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(117): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(117): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(118): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(118): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(119): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(119): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(120): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(120): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(125): Undefinierter Bezeichner: 'ImageBoundsRect'
  [Fehler] Unit1.pas(142): Undefinierter Bezeichner: 'IsMouseDown'
  [Fehler] Unit1.pas(143): Undefinierter Bezeichner: 'TopLeft'
  [Fehler] Unit1.pas(144): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(151): Undefinierter Bezeichner: 'IsMouseDown'
  [Fehler] Unit1.pas(153): Undefinierter Bezeichner: 'BottomRight'
  [Fehler] Unit1.pas(153): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(154): Operator oder Semikolon fehlt
  [Fehler] Unit1.pas(162): Undefinierter Bezeichner: 'IsMouseDown'
  [Fehler] Unit1.pas(29): Ungenügende Forward- oder External-Deklaration: 'TForm1.DeleteImages'
  [Fataler Fehler] Project1.dpr(5): Verwendete Unit 'Unit1.pas' kann nicht compiliert werden

[Luckie]

Es ist ja auch kein ganzes Projekt. Es ist nur der relevante Code. Die Variablen musst du natürlich schon noch deklarieren und am besten als Felder der Formklasse.

[thomas2009]

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListBox1: TListBox;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
procedure DrawImageBounds(X, Y: Integer);
procedure CreateImage;
procedure Reset;
procedure ListImages;
procedure DeleteImages;
procedure DeleteImageBounds;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
procedure TForm1.CreateImage;
  procedure Swap(var X1, X2: Integer);
  var
    Temp: Integer;
  begin
    Temp := X1;
    X1 := X2;
    X2 := Temp;
  end;
var
  Image: TImage;
begin
  SetLength(ImageArray, Length(ImageArray) + 1);
  Image := TImage.Create(nil);
  Image.Name := 'Image' + IntToStr(Length(ImageArray));
  Image.Parent := Form1;
  if (BottomRight.Y < TopLeft.Y) then
    Swap(BottomRight.Y, TopLeft.Y);
  if (BottomRight.X < TopLeft.X) then
    Swap(BottomRight.X, TopLeft.X);
  Image.Left := TopLeft.X;
  Image.Top := TopLeft.Y;
  Image.Height := BottomRight.Y - TopLeft.Y;
  Image.Width := BottomRight.X - TopLeft.X;
  //Image.Stretch := True;
  //Image.Proportional := True;
  Image.Picture.LoadFromFile('test.bmp');
  ImageArray[High(ImageArray)] := Image;
end;

procedure TForm1.DeleteImages;
var
  i: Integer;
begin
  for i := High(ImageArray) downto 0 do
  begin
    ImageArray[i].Free;
  end;
  SetLength(ImageArray, 0);
end;

procedure TForm1.ListImages;
var
  i: Integer;
begin
  ListBox1.Items.Clear;
  for i := 0 to ControlCount - 1 do
  begin
    if (Controls[i] is TImage) then
    begin
      ListBox1.Items.Add(Format('%s (%d / %d)', [TImage(Controls[i]).Name, TImage(Controls[i]).Width, TImage(Controls[i]).Height]));
    end;
  end;
end;

procedure TForm1.Reset;
begin
  IsMouseDown := False;
  TopLeft.X := 0;
  TopLeft.Y := 0;
  BottomRight.X := 0;
  BottomRight.Y := 0;
end;

procedure TForm1.DrawImageBounds(X, Y: Integer);
begin
  if not Assigned(ImageBoundsRect) then
  begin
    ImageBoundsRect := TShape.Create(Form1);
    ImageBoundsRect.Parent := Form14;
    ImageBoundsRect.Shape := stRectangle;
    ImageBoundsRect.Brush.Style := bsClear;
    ImageBoundsRect.Pen.Width := 1;
    ImageBoundsRect.Pen.Color := clBlack;
    ImageBoundsRect.Pen.Style := psDash;
  end;
  ImageBoundsRect.Left := TopLeft.X;
  ImageBoundsRect.Top := TopLeft.Y;
  ImageBoundsRect.Width := X - TopLeft.X;
  ImageBoundsRect.Height := Y - TopLeft.Y;
end;

procedure TForm1.DeleteImageBounds;
begin
  FreeAndNil(ImageBoundsRect);
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
  DoubleBuffered := True;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  DeleteImages;
end;

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  IsMouseDown := True;
  TopLeft.X := X;
  TopLeft.Y := Y;
end;


procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  if IsMouseDown then
  begin
    BottomRight.X := X;
    BottomRight.Y := Y;
    DrawImageBounds(X, Y);
  end;
end;

procedure TForm1.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if IsMouseDown then
  begin
    DeleteImageBounds;
    CreateImage;
    Reset;
    ListImages;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  DeleteImages;
  ListImages;
end;

end.

[Luckie]

Und was willst du mir damit jetzt sagen?

[thomas2009]

Jetzt sage ich gute Nacht! Bis morgen. Augen gehen ständig zu:cyclops:

[Sir Rufo]

Zitat:

Zitat von Luckie (Beitrag 1090611)

Und was willst du mir damit jetzt sagen?

Er möchte Hipp-Code

Vorgekaut und leicht verdaulich :mrgreen:

[nuclearping]

Und genau deswegen bringts nichts. Jeder andere "Delphi Anfänger" hätte Luckie jetzt die Füße geküsst, aber "thomas" weiß scheinbar leider auch nichtmal, was Füße sind.

[Daniel]

Ich mache hier mal zu, denn das macht so keinen Sinn.
Dir fehlen zu viele Grundlagen, um diesen Code zu verstehen. Das ist an sich kein Problem, jeder von uns hat einmal angefangen - nur versuche bitte nicht, Dir diesen Code hier schreiben zu lassen, um ihn dann zu verwenden, ohne ihn zu verstehen.

Ein paar Grundlagen-Tutorials, z.B. von Delphi-Treff.de, sollten Deine nächste Lektüre sein, wenn Du tiefer in das Thema einsteigen möchtest.