ListBox Tastatur- bzw. Worteingabe

[Christoph]

Hallo!

Ich habe eine sortierte ListBox mit einer großen Anzahl von Einträgen.
Mit AutoComplete springt der ItemIndex an den ersten Buchstaben eines Eintrages.

Da ich eine Menge Einträge unter jedem Buchstaben habe möchte ich gerne mehrere Zeichen hintereinander tippen und somit schneller zu dem gewünschten Listboxeintrag kommen.

Bsp.:
Ich suche den Eintrag 'gruendung' in der folgenden Liste:

gruen
gruendbar
gruendorf
gruendung
gruenlich
gruenstadt

Gebe ich ein 'g' ein, springt der ItemIndex auf den ersten Eintrag mit einem 'g', hier also auf 'gruen'.
Ich würde gerne 'gruendo' eingeben können mit dem Ergebnis, dass der ListboxItemIndex auf 'gruendorf' steht.

Wer kann helfen?

Danke und Gruß,
Christoph

[Legolas]

Hi Christoph,

also auf Anhieb habe ich kein Patentrezept aber es sollte doch möglich sein z.b. im KeyPress Ereignis der Listbox die Tastaturanschläge auszuwerten und dann mit den Einträgen zu vergleichen.

[Christoph]

Hallo,

leider bin ich bei diesem Problem noch nicht wirklich weiter gekommen.
Bislang kann ich immer nur ein einziges Zeichen 'abfangen'.
Hier ein Auszug aus dem Code (Codeschnipsel aus diesem Forum, gekürzt):

Delphi-Quellcode:

function TForm1.GetKey(Key: Word): String;
begin
  case Key of
    VK_NUMPAD6   : Result := 'VK_NUMPAD6';
    VK_NUMPAD7   : Result := 'VK_NUMPAD7';
    VK_NUMPAD8   : Result := 'VK_NUMPAD8';
    VK_NUMPAD9   : Result := 'VK_NUMPAD9';
    VK_MULTIPLY  : Result := 'VK_MULTIPLY';
    VK_ADD       : Result := 'VK_VKADD';
    VK_SEPARATOR : Result := 'VK_SEPARATOR';
    VK_SUBTRACT  : Result := 'VK_SUBTRACT';
    VK_DECIMAL   : Result := 'VK_DECIMAL';
    VK_divIDE    : Result := 'VK_divIDE';
  else
    Result := 'Zeichentaste: '+ Chr(Key);
  end;
end;

Delphi-Quellcode:

procedure TForm1.ListBoxKeyUp(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var Zeichen: string;
begin
  Zeichen:=GetKey(Key);
  Form1.Memo.Text:=Zeichen;
end;

Damit bekomme ich aber immer nur ein einzelnes Zeichen. Ich möchte die ersten vier bis fünf Zeichen abfangen, nacheinander in einen String schreiben und dann den so erzeugten String mit dem Eintrag in der Listbox abgleichen.

Kann jemand helfen?

Danke und Gruß,
Christoph

[Legolas]

Hi Christoph,

ich habe da mal ein bisserl rumgespielt und habe folgenden Lösungsansatz für dich und habe deinen Code entsprechend erweitert:

Code:

...
implementation

{$R *.dfm}

var Zeichen  : string;

function TForm1.GetKey(Key: Word): String;
begin
  case Key of
    VK_NUMPAD6   : Result := 'VK_NUMPAD6';
    VK_NUMPAD7   : Result := 'VK_NUMPAD7';
    VK_NUMPAD8   : Result := 'VK_NUMPAD8';
    VK_NUMPAD9   : Result := 'VK_NUMPAD9';
    VK_MULTIPLY  : Result := 'VK_MULTIPLY';
    VK_ADD       : Result := 'VK_VKADD';
    VK_SEPARATOR : Result := 'VK_SEPARATOR';
    VK_SUBTRACT  : Result := 'VK_SUBTRACT';
    VK_DECIMAL   : Result := 'VK_DECIMAL';
    VK_divIDE    : Result := 'VK_divIDE';
  else
    Result := Chr(Key);
  end;
end;

procedure TForm1.ListBox1KeyPress(Sender: TObject; var Key: Char);
var I: Integer;
begin
  Zeichen:=Zeichen+Key;
  for i:=0 to Listbox1.Items.Count do
  begin
    Memo1.Text:=Zeichen;
    if (Length(ListBox1.Items[i])=Length(Zeichen)) or (Length(ListBox1.Items[i])>Length(Zeichen)) then
    begin
      Label1.Caption:=Copy(ListBox1.Items[i],0,Length(Zeichen));
      if Copy(ListBox1.Items[i],0,Length(Zeichen))=Zeichen then
      begin
        ListBox1.ItemIndex:=i;
        exit;
      end;
    end;
  end;
end;
...

Ich hoffe da hilft dir bei deinem Problem weiter.

Bei mir tut es das was du dir vorgestellt hast, könnte aber sein das man es noch etwas eleganter progen kann. :-D

[SirThornberry]

bei der Comobox isses so das auch immer zum anfangsbuchstaben gesprungen wird. wenn ich zum beispiel ein "g" drücke wird zum item gespruchen das mit "g" anfängt. Wenn man schnell genug tippt kann man auch mehr als nur den ersten buchstaben eingeben, ist vielleicht bei der Listbox auch so

[Edit]Ich habs grad probiert und wie vermuted musst du einfach nur bissl schneller tippen. Eventuell einfach mal danach suchen wie du die tippgeschwindigkeit abändern kannst, dann erstparst du dir das ganze noch mal zu proggen[/Edit]

[Legolas]

Hallo SirThornberry,

laut OH sollte das auch funktionieren, aber bei mir funktioniert es nicht. Die Listbox markiert nur das erste Zeichen oder sollte ich nicht in der Lage sein so schnell zu tippen? :oops:

aber mal im Ernst, da mit dem abändern der Tipgeschwindigkeit ist ein interessanter Vorschlag.

schaun wir mal wo man da den Hebel ansetzten muß, oder weißt du's vieleicht???

Ansonsten ist die Lösung ja nun nicht so riesig ausgefallen, so das man es kurz eintippen kann.

[SirThornberry]

derzeit muss du innerhalb von 500 ms den nächsten buchstaben tippen. Den wert kannst du in

Delphi-Quellcode:

procedure TCustomListBox.KeyPress(var Key: Char); //unter delphi7 in der unit "stdctrls.pas"

ändern. (TListbox ist von TCustomListBox abgeleitet)
Oder du leitest eine neue Klasse von TListbox ab und überscheibst die methode...

[Legolas]

urspünglich hatte ja Christoph Probleme damit, aber das interessiert mich jetzt doch.

Ih werde es mal ausprobieren. Man lernt ja nie aus, oder? :mrgreen:

[SirThornberry]

habs grad probiert und es funktioniert supi. Hab anstelle der 500ms mal 5000 eingegeben, und siehe da, man kann halb einschlafen beim tippen. Türlich musste vorher die unit neu compiliert werden bzw hab ich die "stdctrls.pas" dem testprojekt hinzugefügt

[Legolas]

@SirThornberry:

Hast recht habs auch gerade probiert, funktioniert. Sehr gute Idee, Respekt.

Aber Christoph wird mit der Lösung nicht glücklich werden, denn ich meine das der Lösungsweg nicht mit Delphi 6 Personal funktionieren wird.

Wenn ich mich richtig erinnere fehlen dort die Quellen, oder?

[Christoph]

Hi!

Vielen Dank, dass sich doch noch mehrere zu meinem Problem geäußert haben.
@Legolas: Dein code funktioniert klasse, wenn ich ein kleines neues Progi codiere, nur leider nicht in meinem code (warum kriege ich jetzt nach zwei Pils nicht mehr heraus).

Unabhängig davon ist auch die Geschwindigkeit ein Problem. Ich habe deutlich über 2000 ListBox-Einträge.
Wie Du richtig schriebst steht in der OH, dass sich der String verlängert, wenn man AutoComplete auf True setzt - tut er aber nicht.
Und selbst wenn ich superschnell tippe komme ich nicht zum gewünschten Ergebnis.

Leider gibt es auch bei Delphi 6 Personal das von SirThornberry angeführte file nicht (#shit).

Wenn Ihr noch eine andere Idee habt ;)

Ansonsten muss ich mich halt ohne diese Funktionalität begnügen.

Danke und Gruß,
Christoph

[Legolas]

Hi Christoph,

das mit der geschwindigkeit gönnte sein (bei 2000 Einträgen). Aber ich denke du mußt deswegen nicht darauf verzichten.

Uns wird schon was einfallen wie wir dir helfen können. Ich, zumindest, wrde mal darüber nachdenken.

[Legolas]

So, die neue Komponenten funktioniert sehr gut. Es ist jetzt auch unerheblich ob 1000, 2000 oder mehr einträge sind.

Da ich aber, wie SirThornberry mir vergeschlagen hat, die

Delphi-Quellcode:

stdctrls.pas

geändert und neu kompiliert habe, ist jetzt die Frage ob ich die neu kompilierte Unit so weitergeben darf.

Vieleicht weiß jemand darüber bescheid.

[Christoph]

Hallo!

Vielen Dank an Euch beide schon jetzt für Euer Engagement ;)
@Legolas: Du hast eine neuen Komponente programmiert? Bringt mir natürlich nur was, wenn ich die auch mit Delphi 6 Personal benutzen kann. Ob man sowas überhaupt in diesem Fall benutzen darf, kann ich nicht sagen.
Was mich etwas wundert ist, dass ich anscheinend der einzige bin, der diese Funktionalität programmieren möchte. Ich habe schon eine Weile im Netz gesucht und nichts zu (genau) diesem Thema gefunden.
Nun denn. Ich hoffe, dass wir irgendwie zu einer Lösung kommen. Aber mein Programm läuft im Zweifel auch ohne. Ist halt nur (deutlich) mühsamer, den gewünschten Eintrag zu finden.

Gruß,
Christoph

[Legolas]

Hallo Christoph,

nein, eine neue komponente habe ich noch nicht programmiert (nur den Quellcode der ursprünglichen stdctrls.pas entsprechend geändert). Da du bei Delphi 6 Personal diese nicht besitzt bin ich mir nicht sicher ob ich dir die neu übersetzte Unit im ganzen schicken darf. Wenn ich eine neue Komponente schreibe die von TCustomListBox abgleitet ist, ist es keine Frage, denn das ist erlaubt.

Schauen wir mal wie wir das lösen.

Ich melde mich an dieser Stelle wieder. :mrgreen:

[SirThornberry]

habs für delphi6 mal gemacht (personal). Habs auch getestet und functioniert... Hab einfach eine neue Komponente von TListBox abgeleitet und die Methode überschrieben. Über Keypresstime kann dann die zeit in Millisekunden eingestellt werden die zwischen zwei tastendrücken vergehen kann

Delphi-Quellcode:

  TMyListBox = class(TListBox)
  private
    fFilter: String;
    fLastTime: Cardinal;
    fkeypresstime: Integer;
  protected
    procedure KeyPress(var Key: Char); override;
  public
    constructor Create(AOwner: TComponent); override;
  published
    property Keypresstime: Integer read fKeypresstime write fkeypresstime;
  end;

[...]

constructor TMyListBox.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  fkeypresstime := 10000;
  FFilter := '';
  FLastTime := GetTickCount;
end;

procedure TMyListBox.KeyPress(var Key: Char);
  procedure FindString;
  var
    Idx: Integer;
  begin
    if Style in [lbVirtual, lbVirtualOwnerDraw] then
      Idx := DoFindData(FFilter)
    else
      Idx := SendMessage(Handle, LB_FINDSTRING, -1, LongInt(PChar(FFilter)));
    if Idx <> LB_ERR then
    begin
      if MultiSelect then
      begin
        ClearSelection;
        SendMessage(Handle, LB_SELITEMRANGE, 1, MakeLParam(Idx, Idx))
      end;
      ItemIndex := Idx;
      Click;
    end;
    if not (Ord(Key) in [VK_RETURN, VK_BACK, VK_ESCAPE]) then
      Key := #0;  // Clear so that the listbox's default search mechanism is disabled
  end;

var
  Msg: TMsg;
begin
  inherited KeyPress(Key);
  if not AutoComplete then exit;
  if GetTickCount - FLastTime >= fkeypresstime then
    FFilter := '';
  FLastTime := GetTickCount;

  if Ord(Key) <> VK_BACK then
  begin
    if Key in LeadBytes then
    begin
      if PeekMessage(Msg, Handle, WM_CHAR, WM_CHAR, PM_REMOVE) then
      begin
        FFilter := FFilter + Key + Chr(Msg.wParam);
        Key := #0;
      end;
    end
    else
      FFilter := FFilter + Key;
  end
  else
  begin
    while ByteType(FFilter, Length(FFilter)) = mbTrailByte do
      Delete(FFilter, Length(FFilter), 1);
    Delete(FFilter, Length(FFilter), 1);
  end;

  if Length(FFilter) > 0 then
    FindString
  else
  begin
    ItemIndex := 0;
    Click;
  end;
end;

[Legolas]

@SirThornberry:

Ups, war auch gerade dabei, du warst schneller. :mrgreen:
So brauch Christoph wenigstens nicht darauf zu verzichten.

[SirThornberry]

@Legolas: hatte vorhin gelesen das er es irgendwie nicht auf die reihe bekommt und da habsch mir mal die 10 minuten genommen die methode zu überschreiben...

@Christoph: Mich würdes mal interessieren ob die Methode schneller ist als die selbst geproggte die schon gepostet wurde....

[Legolas]

Hi SirThornberry,

jetzt hat er wenigstens ne vernünftige Lösung. :mrgreen:

Die ist auf jedenfall schneller. Habe ja meine Source (wie du, allerdings "mur" auf 2500) auch geändert und habe das ganze mit einer Listbox mit ca 2100 Einträgen ausprobiert. Die Geschwindigkeit ist trotz meiner betagten CPU (Athlon 900) sehr gut.

Damit ist sein Problem auf jedenfall gelöst.

[Christoph]

Hallo SirThornberry und Legolas,

erstmal herzlichsten Dank für Euer wirklich vorbildliches Engagement.

Ich habe mal ein Mini-Prog mit genau dem Code geschrieben, den SirThornberry hier gepostet hat. Funktioniert einwandfrei - klasse.

Jetzt versuche ich schon meine gesamte Mittagspause diese Funktionalität in mein Programm einzubauen, was mir aber bisher leider nicht mit dem gewünschten Effekt gelingt.

Was ich nicht verstehe:
Füge ich der Listbox per

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
begin
  ListBox1.Items.Add('end');
  ListBox1.Items.Add('endac');
  ListBox1.Items.Add('endad');
  ListBox1.Items.Add('endae');
  ListBox1.Items.Add('endaf');
  ListBox1.Items.Add('endag');
end;

Einträge hinzu, tut die von SirThornberry gepostete Funktionalität.

Sie tut aber leider nicht in meinem Programm, in dem ich die Daten aus einem file lese.
Da ich im Moment keine Ahnung habe warum das so ist (und in den nächsten Tagen kaum Zeit in Ruhe zu testen) anbei hier mal meine gesamte Unit plus die Datei 'namen.txt' aus der ich die Daten auslese.

Wenn Ihr nochmal Muße habt drüberzuschauen, wäre ich Euch mehr als dankbar.

Noch zwei Anmerkungen dazu:
1.
Wo ich den Code von SirThornberry eingefügt habe, poste ich diesen z.T. nur als Auszug.

2.
Zum Code: Ich bin Jurist, und kein Programmierer ;)

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
end;

type
TMyListBox = class(TListBox)
  private
    fFilter: String;
    fLastTime: Cardinal;
    fkeypresstime: Integer;
  protected
    procedure KeyPress(var Key: Char); override;
  public
    constructor Create(AOwner: TComponent); override;
  published
    property Keypresstime: Integer read fKeypresstime write fkeypresstime;
end;

type
  CardRecord = record
    Name: string;
end;

var
  Form1: TForm1;
  Card: array[0..1800] of CardRecord;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  SortierListe: TStringList;
  a: integer;
begin
  SortierListe := TStringList.Create;
  SortierListe.LoadFromFile('namen.txt');
  SortierListe.Sorted:= True;                // Alphabetische Sortierung

  for a:= 0 to SortierListe.Count-1 do
  begin
    Card[a].Name:=SortierListe[0];
    ListBox1.Items.Add(Card[a].Name);        // Auslesen und Schreiben in Array
    SortierListe.Delete(0);                  // String löschen
  end;
  SortierListe.Free;

end;

constructor TMyListBox.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  fkeypresstime := 10000;
  FFilter := '';
  FLastTime := GetTickCount;
end;

procedure TMyListBox.KeyPress(var Key: Char);
  procedure FindString;

[...]

end;

end.

Herzlichen Dank und Gruß,
Christoph

[Christoph]

Hallo!

Es wird immer interessanter.
Habe jetzt mal alle Updates installiert, die noch gefehlt haben und siehe da: im Normalfall (also ListBox1.Items.Add('xy') wie oben beschrieben) funktioniert die Funktion Autocomplete genau so, wie es in der OH steht.
Lese ich aber die Daten wie oben per file ein, tut sie es nicht.

Warum bloß?

Gruß,
Christoph

[Christoph]

Hallo!

Habe die Lösung meines Problems gefunden.
'ListBox.Sorted' muss auf 'true' stehen. Wo da der tiefere Sinn ist, bleibt mir verschlossen. Und erstaunlicherweise sortiert 'ListBox.Sorted' anders als das 'Sorted' einer StringList.
Ich helfe mir damit, dass ich die einzulesenden Daten halt so vorsortiere, dass sie dem 'Sorted' der ListBox entsprechen.

Also:
Nochmal ganz herzlichen Dank an SirThornberry und Legolas.

Gruß,
Christoph