String Konvertierung

[zeras]

Ich habe bis jetzt den Win32 Project Localizer benutzt. Da dieser aber nicht mehr weiterentwickelt wird, habe ich jetzt auf tsilang umgeschwenkt, möchte aber die vorhandenen Übersetzungen nutzen. Dazu kann ich im Project Localizer die Daten exportieren.
Diese stehen dann in verschiedenen Dateien wie folgt:
Beispiel
<entry name="AdvPreviewForm.Caption">
<value>0056006F007200730063006800610075</value>
</entry>


Das muss ja offenbar der 16 Bit Wert für jedes Zeichen des Textes sein. Mit welcher Funktion kann ich das zu einem String konvertieren? Mit den Konvertierungsfunktionen habe ich bisher noch nichts am Hut. Ansonsten muss ich das selber programmieren.

[HolgerX]

Hmm..

das sind ZeichenCodes von WideChars..

0056006F007200730063006800610075 entspricht dem String 'Vorschau'.

0056 V
006F o
0072 r
0073 s
0063 c
0068 h
0061 a
0075 u

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  i : integer;
begin
  Edit2.Text := '';
  For i := 0 to (length(Edit1.Text) div 4)-1 do begin
    Edit2.Text := Edit2.Text + WideChar(StrToInt('$' + Copy(Edit1.Text,1 + (i*4),4)));
  end;
end;

Kleiner Test mit D6...

[zeras]

Hallo HolgerX,

danke für die Funktion.
Meine Frage war, ob es da eine fertige Funktion gibt. Wenn nicht, werde ich dankbar deine Funktion einbauen.

[himitsu]

Ähhhhhhhhh .... Text und StrToInt?

Wie wäre es mit HexToBin oder einer gleichwertigen Stream-Funktion
und dann TEncoding.Unicode.Xyz, bzw. TEncoding.BigEndianUnicode ? :stupid: (Bytefolge beachten)

Wobei letzter Teil notfalls "einfach" entfallen kann, wenn man es direkt in einen UnicodeString schreibt. (hier muß man aber vermutlich noch die Bytes der Chars umdrehen, vonwegen BigEndian)

[EWeiss]

Zitat:

Zitat von himitsu (Beitrag 1394613)

Ähhhhhhhhh .... Text und StrToInt?

Wie wäre es mit HexToStr oder einer gleichwertigen Stream-Funktion
und dann TEncoding.Unicode.Xyz, bzw. TEncoding.BigEndianUnicode ? :stupid: (Bytefolge beachten)

Wobei letzter Teil notfalls "einfach" entfallen kann, wenn man es direkt in einen UnicodeString schreibt. (hier muß man aber vermutlich noch die Bytes der Chars umdrehen, vonwegen BigEndian)

Tja und das alles in D6 ? LOL
Denke das gab es da noch nicht.

gruss

[himitsu]

HexToBin gab es bestimmt schon
und den WideString auch.

http://docwiki.embarcadero.com/RADSt...rsion_routines
http://docwiki.embarcadero.com/RADSt...pes#WideString


In einem neueren Delphi würde ich gleich bei Unicode bleiben.
Wenn in einem älteren Delphi (D2007 und davor) eh nur ANSI angezeigt wird, also nicht das Delphi z.B. mit Unicode-Controls aufgerüstet wurde,
dann kann man da auch direkt WideCharToMultiByte / MultiByteToWideChar (für UnicodeBE > UnicodeLE > ANSI oder UnicodeLE > ANSI oder nur UnicodeBE > UnicodeLE) nutzen.

[HolgerX]

Hmm..

Ich sehe in der Verwendung von HexToBin zu StrToInt keinen Vorteil..

HexToBin füllt (zumindestens in D6) einen PChar und dieser ist in D6 Ansi.
Und ich mag das harte Speichergecaste nach dem Prinzip PChar(WideChar) nicht. ;)
Zusätzlich muss ich dafür sorgen, dass der Text auch nur Kleinbuchstaben enthält, was bei dem XML-Auszug nicht der Fall ist.

Mit der Methode WideChar(StrToInt( )) könnte ich auch statt des Edits (unter D6 nur ANSI) ein WideString füllen..

Wie ich ja auch schrieb

Zitat:

Zitat von HolgerX (Beitrag 1394610)

Kleiner Test mit D6...

War es nur ein Test, welcher funktionierte.. ;)

[himitsu]

Zitat:

Zitat von HolgerX (Beitrag 1394621)

Ich sehe in der Verwendung von HexToBin zu StrToInt keinen Vorteil..

HexToBin füllt (zumindestens in D6) einen PChar und dieser ist in D6 Ansi.

HexToBin macht mehrere/alle Bytes auf einmal
und IntToStr nur jeweils ein Char.

Und das ANSI/Unicode ist hier vollkommen egal, denn das PChar ist im Eingang und nicht im Ausgang, also der hexadezimale String (quelle) ist ANSI und das passt genau zu allen Text-Ladefunktionen des jeweiligen Delphi (ANSI und Unicode).
Der Ausgang ist aber Binär und da im Einganz 4 Zeichen = 2 Byte = WideChar ... passt das direkt in einen WideString/UnicodeString.

Falls Big/Little-Endian nicht passt, dann am Ende nochmal schnell SwapByte über jedes Char jagen.

[EWeiss]

Am ende führen viele Wege nach ROM..
Wie man eine Aufgabe löst kann doch egal sein solange sie zum gleichen Ergebnis führt.

just my 2 Cent.

Aber es würde mich schon interessieren wie du das umsetzen würdest..
Quelltext ?

gruss

[himitsu]

Zitat:

Aber es würde mich schon interessieren wie du das umsetzen würdest..

So schwer zwei/drei genannte Befehle in einen Code zu schreiben und die Parameter zu füllen?

Delphi-Quellcode:

var
  S: string;
  B: TBytes;
  U: UnicodeString;  //WideString
  i: Integer;
begin
  S := '0056006F007200730063006800610075';
  SetLength(B, Length(S) div 2);
  HexToBin(PChar(S), B[0], Length(B));
  S := TEncoding.BigEndianUnicode.GetString(B);
  ShowMessage(S);

  S := '0056006F007200730063006800610075';
  SetLength(U, Length(S) div 4);
  HexToBin(PChar(S), U[Low(U)], Length(U) * 2);
  for i := High(U) downto Low(U) do
    Word(U[i]) := Swap(Word(U[i]));
  ShowMessage(U);

Zitat:

Delphi-Quellcode:

  Edit2.Text := '';
  For i := 0 to (length(Edit1.Text) div 4)-1 do begin
    Edit2.Text := Edit2.Text + WideChar(StrToInt('$' + Copy(Edit1.Text,1 + (i*4),4)));

PS: Vom Speichermanagement her sind die vielen Stringoperationen ein Graus, vor allem im alten Delphi-Memory-Manager.
Massenhaft Speicher reservieren und wieder freigeben ... 4 Mal pro Char, zuzüglich nochmal der Behandlungen im EDIT.
Dank FastMM mag sich da seit Delphi 6 so Einiges gebessert haben, aber schön ist es dennoch nicht.

Gut, bei diesem einen String, innerhalb eines Button-OnClick, mag es niemand wirklich bemerken.

[EWeiss]

Zitat:

So schwer zwei/drei genannte Befehle in einen Code zu schreiben und die Parameter zu füllen?

Nein!
Aber du redest\schreibst sehr viel (mach dies , mach das) ohne dein Fundamentales wissen zu teilen\zeigen.
Das stört mich etwas ;)

So ist es zumindest ersichtlich was du im einzelnen so von dir gibst.

gruss

[Delphi.Narium]

Dem möchte ich mich sinngemäß anschließen.

@himitsu Du hast ein dermaßen fundiertes Wissen, dass man Dir bei Sachen, die für Dich Selbstverständlichkeiten sind, nicht folgen kann, weil einfach das eigene Grundwissen um Meilen hinter Deinem zurückliegt.

Das Problem ist dann nicht, ein paar Zeilen Quelltext zu schreiben, sondern das Problem ist, Deine Gedanken soweit zu verstehen, dass man überhaupt in der Lage ist, daraus eine entsprechende Logik abzuleiten.

Mir ist z. B. erst aufgrund Deines Quelltextes klar geworden, was Du meinst. Danach ist der Quelltext dann klar und beinahe banal. Aber man muss Dir erstmal bis dahin gedanklich folgen können und das fällt mir persönlich zuweilen schwer. Einfach, weil es mir an dem fundierten Wissen fehlt.

Also mach Du bitte so weiter wie bisher, es ist sehr lehrreich und bei Nachfragen von uns einfach erklären. Wer Deine Gedanken und Lösungen verfolgt, wird immer was dazu lernen. Und das ist ja gerade das, was dieses Forum hier so interessant macht.

Für mich persönlich ist es nicht so wichtig, dass einem hier geholfen wird, sondern die vielfältige Art der Antworten und unterschiedlichsten Lösungen zu einem Problem, gepaart mit vielen "Jahrhunderten" an Erfahrungen (wenn man die aller Teilnehmer mal so zusammenrechnet). Nur so kann man seinen eigenen Erfahrungsschatz mit Hilfe anderer erweitern und das sehr effektiv.

[HolgerX]

Hmm..

[QUOTE=himitsu;1394623]

Zitat:

Zitat von HolgerX (Beitrag 1394621)

Und das ANSI/Unicode ist hier vollkommen egal, denn das PChar ist im Eingang und nicht im Ausgang, also der hexadezimale String (quelle) ist ANSI und das passt genau zu allen Text-Ladefunktionen des jeweiligen Delphi (ANSI und Unicode).

Unter D6 sieht HexToBin so aus :

Delphi-Quellcode:

function HexToBin(Text, Buffer: PChar; BufSize: Integer): Integer; assembler;
const
  Convert: array['0'..'f'] of SmallInt =
    ( 0, 1, 2, 3, 4, 5, 6, 7, 8, 9,-1,-1,-1,-1,-1,-1,
     -1,10,11,12,13,14,15,-1,-1,-1,-1,-1,-1,-1,-1,-1,
     -1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,
     -1,10,11,12,13,14,15);
var
  I: Integer;
begin
  I := BufSize;
  while I > 0 do
  begin
    if not (Text[0] in ['0'..'f']) or not (Text[1] in ['0'..'f']) then Break;
    Buffer[0] := Char((Convert[Text[0]] shl 4) + Convert[Text[1]]);
    Inc(Buffer);
    Inc(Text, 2);
    Dec(I);
  end;
  Result := BufSize - I;
end;[DELPHI]

[/DELPHI]

Hier ist Buffer ein PChar und in diesen wird ein Char 'geschrieben', somit Out....

das 'S := '0056006F007200730063006800610075';' würde unter D6 nicht funktionieren, da hier nur Kleinbuchstaben zulässig sind, jedoch im Musterstring diese Großbuchstaben sind..

Wenn dies in einer späteren Delphiversion geändert worden ist, OK.. Ich hab hier im Moment nur in D6.

Unter D6 ist auch TBytes und PChar nicht kompatible..

[TiGü]

Zitat:

Zitat von HolgerX (Beitrag 1394694)

Hier ist Buffer ein PChar und in diesen wird ein Char 'geschrieben', somit Out....

das 'S := '0056006F007200730063006800610075';' würde unter D6 nicht funktionieren, da hier nur Kleinbuchstaben zulässig sind, jedoch im Musterstring diese Großbuchstaben sind..

Wenn dies in einer späteren Delphiversion geändert worden ist, OK.. Ich hab hier im Moment nur in D6.

Unter D6 ist auch TBytes und PChar nicht kompatible..

Wo ein Wille, da ist auch ein Weg.
Das funktioniert auch unter D6. Beachte den aufrufenden Code in der procedure Main.
Entspricht den angepassten Beispiel von Himi:

Delphi-Quellcode:

program Project3;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils;

// Von HolgerXs Delphi 6
function HexToBin(Text, Buffer: PChar; BufSize: Integer): Integer; assembler;
const
  Convert: array['0'..'f'] of SmallInt =
    ( 0, 1, 2, 3, 4, 5, 6, 7, 8, 9,-1,-1,-1,-1,-1,-1,
     -1,10,11,12,13,14,15,-1,-1,-1,-1,-1,-1,-1,-1,-1,
     -1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,-1,
     -1,10,11,12,13,14,15);
var
  I: Integer;
begin
  I := BufSize;
  while I > 0 do
  begin
    if not (Text[0] in ['0'..'f']) or not (Text[1] in ['0'..'f']) then Break;
    Buffer[0] := Char((Convert[Text[0]] shl 4) + Convert[Text[1]]);
    Inc(Buffer);
    Inc(Text, 2);
    Dec(I);
  end;
  Result := BufSize - I;
end;

procedure Main;
var
  S: string;
  B: string;
begin
  S := '0056006F007200730063006800610075';
  S := LowerCase(S);
  SetLength(B, Length(S) div 2);
  HexToBin(PChar(S), @B[1], Length(B));
  S := StringReplace(B, #0, '', [rfReplaceAll, rfIgnoreCase]);
  Writeln(S);
end;

begin
  try
    Main;
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

[HolgerX]

Hmm..

Hab auch noch ein bischen probiert:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  S: AnsiString;
  B: WideString;
  i : integer;
begin
  // LowerCase, da HexToBin nur mit Kleinbuchstaben arbeitet
  S := LowerCase(Edit1.Text);

  // WideString
  SetLength(B, (Length(S) div 4));  // 4 HexChars = 1 WideChar

  // Cast nach PChar, da D6 hier PChar erwartet!
  HexToBin(PChar(S), PChar(B), Length(S) div 2);

  // EndianSwap
  //  for i := High(B) downto Low(B) do // High/Low Geht unter D6 nicht mit WideString!!
  for i := Length(B) downto 1 do
    Word(B[i]) := Swap(Word(B[i]));

  Edit2.Text := B;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  S: AnsiString;
  B: Array of WideChar;
  i : integer;
begin
  // LowerCase, da HexToBin nur mit Kleinbuchstaben arbeitet
  S := LowerCase(Edit1.Text);

  // Bei Array ein Zeichen mehr wg PWideChar
  SetLength(B, (Length(S) div 4) + 1);  // 4 HexChars = 1 WideChar

  // Cast nach PChar, da D6 hier PChar erwartet!
  HexToBin(PChar(S), PChar(B), Length(S) div 2);

  // EndianSwap
  for i := High(B) downto Low(B) do
    Word(B[i]) := Swap(Word(B[i]));

  Edit2.Text := PWideChar(B);
end;

Eine Version mit WideString und eine mit einem Array WideChar.

Wie ist HexToBin eigendlich unter Unicode-Versionen von Delphi aufgebaut?

[himitsu]

Im Prinzip noch genauso.
Es gibt nur mehrere überladene Varianten (z.B. Eine mit TBytes als Input)
und das Convert-Array, sowie ein ValidCheck-SET ['0'..'9', 'a'..'f', 'A'..'F'] liegen globaler, anstatt in jeder der Funktionen.

[HolgerX]

Danke für die Info..

Gut, das schon mal der Blödsinn mit der zwangsweisen Kleinschreibung raus ist.
Bei D6 gibt es nur die eine Variante, da war es wohl nicht nötig die Arrays auszulagern.. ;)

[himitsu]

Zitat:

Zitat von EWeiss (Beitrag 1394624)

Aber es würde mich schon interessieren wie du das umsetzen würdest..
Quelltext ?

Nja, wenn ich mal schnell Code ohne Delphi zusammentippe, dann kann es passieren, dass er nicht kompiliert und schon beschwert sich jemand. :stupid:
Und die selben Befehle kann man in tausenden Varianten aufrufen -> jeder hat sein eigenes Codedesign, je nach Compiler/Delphiversion gibt es auch noch kleine Unterschiede und der Eine nutzt lieber diese Methode und ein Anderer was Anderes.

Der Hauptunterschied ist einfach, dass nicht jedes Char einzeln übersetzt und dafür jeweils mehrfach der Speichermanager behelligt wird, sondern dass alle Chars gemeinsam behandelt werden.
Selbst die kleine Schleife bezüglich der Bytedrehung (BigEndian>LittleEndian) könnte man noch durch einen Befehl ersetzen, welcher UnicodeBE nach UnicodeLE umwandelt. (z.B. MultiByteToWideChar mit Codepage 1201 zu 1200 inplace, also direkt die Ausgabe in den Eingabestring)