ShellExecute mit Leerzeichen

[H.Bothur]

Moin,

eigentlich ist mir ja klar wie es gehen sollte:

Ich habe einen Film unter

e:\Video\2 Serien\Friesland-03-Klootschiessen.mp4

der soll mit folgendem Sourcecode gestartet werden. Natürlich habe ich im Debugger mir den Inhalt von Filename angesehen, da steht der Name auch korrekt in Anführungszeichen. Macht PChar noch irgendwas aus den Tüttelchen ?

Der Film wird nicht abgespielt und es kommt als Fehlermeldung:

EOSError
Systemfehler. Code: 2
Das System kann die angegebene Datei nicht finden.



Gruss
Hans

Delphi-Quellcode:

procedure FilmAbspielen;
var
  Node: PVirtualNode;
  Data: PTreeData;
  FileName: String;
begin
  Node := SerienDB.VST.FocusedNode;
  if not Assigned(Node) then Exit;
  Data := SerienDB.VST.GetNodeData(Node);
  FileName := #34 +SerienDB.LbEVerzeichnis.Text +'\' +Data.FCaption +#34;
  if Data.FColumn5 = 'F' then
  begin
    ShellExecute(0, 'open', PChar(FileName), NIL, NIL, SW_SHOW);
    RaiseLastOSError;
  end;
end;

[Achim Kalwa]

Zitat:

Zitat von H.Bothur (Beitrag 1527906)

Moin,

eigentlich ist mir ja klar wie es gehen sollte:

Ich habe einen Film unter

e:\Video\2 Serien\Friesland-03-Klootschiessen.mp4

der soll mit folgendem Sourcecode gestartet werden. Natürlich habe ich im Debugger mir den Inhalt von Filename angesehen, da steht der Name auch korrekt in Anführungszeichen. Macht PChar noch irgendwas aus den Tüttelchen ?

Was passiert denn? Fehlermeldung?

[H.Bothur]

Zitat:

Zitat von Achim Kalwa (Beitrag 1527909)

Was passiert denn? Fehlermeldung?

Sorry - natürlich ...


der Film wird nicht abgespielt und es kommt als Fehlermeldung:

EOSError
Systemfehler. Code: 2
Das System kann die angegebene Datei nicht finden.

Gruss
Hans

[Stolle58]

Code:

Filename := SystUtils.QuotedStr(Filename)

[Achim Kalwa]

Zitat:

Zitat von H.Bothur (Beitrag 1527911)

der Film wird nicht abgespielt und es kommt als Fehlermeldung:

EOSError
Systemfehler. Code: 2
Das System kann die angegebene Datei nicht finden.

Falls einer der Teil-Strings bereits ein Anführungszeichen oder den Backslash enthält, könnte es zu einem Problem kommen. Versuche mal

Delphi-Quellcode:

  FileName := TPath.Combine(OrdnerName, DateiName); // uses System.IOUtils;
  if Pos(' ', FileName) > 0 then
    FileName := AnsiQuotedString(FileName, #34);
  ShellExecute(...

[peterbelow]

Zitat:

Zitat von H.Bothur (Beitrag 1527911)

Zitat:

Zitat von Achim Kalwa (Beitrag 1527909)

Was passiert denn? Fehlermeldung?

Sorry - natürlich ...


der Film wird nicht abgespielt und es kommt als Fehlermeldung:

EOSError
Systemfehler. Code: 2
Das System kann die angegebene Datei nicht finden.

Gruss
Hans

Der ganze Ansatz ist falsch. Einen Dateinamen in " einzuschließen erfordern nur die Kommandozeilen-Tools, für ShellExecute ist das nicht erlaubt.

[H.Bothur]

[QUOTE=Achim Kalwa;1527915]

Zitat:

Zitat von H.Bothur (Beitrag 1527911)

Falls einer der Teil-Strings bereits ein Anführungszeichen oder den Backslash enthält, könnte es zu einem Problem kommen. Versuche mal

Delphi-Quellcode:

  FileName := TPath.Combine(OrdnerName, DateiName); // uses System.IOUtils;
  if Pos(' ', FileName) > 0 then
    FileName := AnsiQuotedString(FileName, #34);
  ShellExecute(...

Ergibt in FileName das gleiche Ergebnis - und leider auch den gleichen Fehler :-(

Hans

[H.Bothur]

[QUOTE=peterbelow;1527917]

Zitat:

Zitat von H.Bothur (Beitrag 1527911)

Der ganze Ansatz ist falsch. Einen Dateinamen in " einzuschließen erfordern nur die Kommandozeilen-Tools, für ShellExecute ist das nicht erlaubt.

Aber ohne die " kommt auch dieser Fehler - was wäre denn besser ?

Hans

[Achim Kalwa]

Zitat:

Zitat von H.Bothur (Beitrag 1527919)

Ergibt in FileName das gleiche Ergebnis - und leider auch den gleichen Fehler :-(

Ob die Datei wirklich da ist und für das ausgeführte Programm erreichbar ist hast Du sicherlich schon überprüft (IDE läuft als Admin; E: ist ein Netzwerklaufwerk gemappt vom User usw.)

Kopiere doch mal beim Debuggen den Inhalt von FileName in die Zwischenablage, und verfüttere das an Windows Start -> Ausführen. Wenn da ebenfalls ein Fehler auftritt, dann gibt es die Datei wirklich nicht.

Ansonsten hilft jetzt nur noch die Glaskugel ;-)

[dstein]

evtl. hilft zusätzlich:

begin
if fileexist(FileName) then
begin
ShellExecute(0, 'open', PChar(FileName), NIL, NIL, SW_SHOW);
RaiseLastOSError;
end
else
... "irgend eine Antwort"..
end;

[H.Bothur]

Das verstehe ich jetzt nicht: Ausführen sagt das des die Datei nicht finden kann ...

ich hatte gedacht (OK, das wird das Problem sein) das, wenn ich den Namen einer mp4-Datei übergebe, automatische der entsprechend verknüpfte MP4-Player - bei mir VLC - gestartet wird.
Das stimmt aber anscheinend gar nicht. Auf der anderen Seite will ich aber nicht den Player hart mit in shellexecute reinkopieren - kann ja sein das der Player sich mal ändert.

Was mache ich denn nun falsch ?

Gruss
Hans

[himitsu]

ShellExecute

Parameter lpFile und lpDirectory sind die Datei bzw. das Verzeichnis.
Dort mit " würde bedeuten, dass diese " als Bestandteil des Namen betrachtet werden, was sie aber nicht sein dürfen.

Aber eine Datei als Parameter (lpParameters) an diese Anwendung (lpFile) übergeben ... dort muß natürlich mit " gearbeitet werden.
Dort können es mehrere Parameter sein und die " sagen dort, daß Jenes zu "einem" Parameter gehört.

[Delphi.Narium]

Wenn VLC der Standardplayer ist, dann ruf doch zum Test mit ShellExecute mal VLC auf und übergibt den Namen der abzuspielenden Datei als Parameter.

Delphi-Quellcode:

var
  ShellExError : Integer;
begin
  if FileExists(FileName) then begin
    ShellExError := ShellExecute(Application.Handle,Nil,PChar('VLC.exe'),PChar(FileName),Nil,SW_SHOW);
    if ShellExError < 32 then begin
      // Hier ist ein Fehler aufgetreten. Sinnvolle Fehlermeldung machen.
      // Siehe: https://learn.microsoft.com/de-de/windows/win32/api/shellapi/nf-shellapi-shellexecutea
    end;
  end else begin
    MessageDLG('Datei wurde nicht gefunden:' + sLineBreak + FileName, mtError, [mbOk], 0);
  end; 
end;

Ist VLC im Suchpfad von Windows? Wenn nein, im Aufruf von ShellExecute diesen mit angeben.

Bleibt das Problem dann immernoch bestehen?

Bezieht sich der Fehler 2 eigentlich auf das Nichtfinden der MP4-Datei oder eventuell auf das Nichtfinden des Players?

[H.Bothur]

Zitat:

Zitat von Delphi.Narium (Beitrag 1527938)

Wenn VLC der Standardplayer ist, dann ruf doch zum Test mit ShellExecute mal VLC auf und übergibt den Namen der abzuspielenden Datei als Parameter.

Ist VLC im Suchpfad von Windows? Wenn nein, im Aufruf von ShellExecute diesen mit angeben.

Bleibt das Problem dann immernoch bestehen?

Bezieht sich der Fehler 2 eigentlich auf das Nichtfinden der MP4-Datei oder eventuell auf das Nichtfinden des Players?

Guter Ansatz, also ....

nur vlc startet problemlos den Player

vlc e:\temp\friesland-haifischbecken.mp4 startet den Player mit dem Film / ist ja auch kein Leerzeichen

vlc e:\Video\2 Serien\Friesland-03-Klootschiessen.mp4 startet den Player, aber
Fehlermeldung "kann die Medienadresse 'file:///e:/video/2' nicht öffnen" - da stört also das Leerzeichen und es wird am Leerzeichen abgeschnitten

vlc "e:\Video\2 Serien\Friesland-03-Klootschiessen.mp4" startet den Player, aber
Fehlermeldung 'kann die Medienadresse 'file:///e:/video/2%20Serien\Friesland-03-Klootschiessen.mp4' - da wird das Leerzeichen in %20 umkodiert

wenn ich im Windows Explorer einen Doppelklick auf die Datei mache dann geht das aber - aber wieso bei Shellexecute bzw. ausführen (was ja das gleiche sein wird) dann nicht ?

Gruss
Hans

[himitsu]

NOCHMAL:

Beim Programm KEINE " (ebenso beim Arbeitsverzeichnis ... hier das letzte NIL)
aber in den Parametern MUSS es :!:

Delphi-Quellcode:

ShellExecute(Application.Handle, nil, PChar('VLC.exe'), PChar('"' + FileName + '"'), nil, SW_SHOW);

[H.Bothur]

Sorry - ich hatte deinen ersten Post nicht verstanden, ich habe es jetzt so gemacht

Delphi-Quellcode:

    ShellExecute(Application.Handle, nil, PChar('vlc.exe'), PChar('"' +FileName + '"'), NIL, SW_SHOW);

vaber es klappt trotzdem nicht:

Fehlermeldung von Delphi:
EOSError - ein Aufruf einer Betriebssystemfunktion ist fehlgeschlagen


Fehlermeldung von VLC:
"kann die Medienadresse 'file:///e:/video/2' nicht öffnen" - da stört also das Leerzeichen und es wird am Leerzeichen abgeschnitten.

Hans

[himitsu]

hmmmmmmmm :gruebel:


Notfalls kannst du es ja mal mit der File-URL als Parameter versuchen.

Zitat:

file:///e:/video/2...

Also ReplaceStr von \ zu /
ebenso Replace von Leerzeichen zu %20 (oder eine URL-Encoding-Funktion benutzen)
und file:/// davor


Oder einfach mal

Delphi-Quellcode:

PChar(ReplaceStr(FileName, ' ', '%20'))

versuchen :duck:

[jaenicke]

Wie wäre es mit CreateProcess? Das behandelt die Parameter etwas anders.

Wenn die VLC Fehlermeldung da ist, VLC also noch läuft, kannst du im Taskmanager auch einfach mal schauen, welche Parameter übergeben wurden.

[H.Bothur]

Ich bin jetzt leider bis Sonntag unterwegs … Ich melde mich.

Danke.

Hans

[Rolf Frei]

Also folgender Code läuft bei mir einwandfrei und VLC wird gestartet und das Video abgespielt. Da werden keine Gänsefüsschen, etc. benötigt, wenn das im richtigen Parameter übergeben wird.

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var
  FileName: String;
  r: NativeUInt;
begin
  FileName := 'I:\Game Clips\Elite Dangerous Core-2015_10_10-23_16_19.mp4';
  r := ShellExecute(0, 'open', PChar(FileName), NIL, NIL, SW_SHOW);
  if r < 32 then
    RaiseLastOSError;
end;

[DieDolly]

Ich habe für sowas über die Jahre eine Unit zusammengebastelt. Da ist alles drin was ich brauche

Delphi-Quellcode:

Aufruf
TShellExecEx.ShellExecEx(Application.Handle, 'open', PChar(Datei), nil, nil, SW_NORMAL);

Delphi-Quellcode:

unit ShellExecEx;

interface

uses
 Winapi.Windows, Winapi.ShellAPI, Winapi.ShlObj, Winapi.TlHelp32, Vcl.Forms, System.SysUtils;

type
 TShellExecEx = record
 private
  class procedure seDelay(Milliseconds: Integer); static;
  class function FileExists(const aFileName: string): Boolean; static;
  class function IsDirectory(const aFileName: string): Boolean; static;
 public
  class function OpenFolderAndSelectFile(const FileName: string): Boolean; static;
  class function ShellExecEx(lphWnd: HWND; lpVerb, lpFile, lpParameters, lpDirectory: PChar; nShowCommand: Integer; bWaitForCompletion: Boolean = False;
   bProcessMessages: Boolean = False; bUseExeIsRunningCheck: Boolean = False): Boolean; static;
 end;

implementation

class procedure TShellExecEx.seDelay(Milliseconds: Integer);
const
 WM_QUIT = 18;
var
 Tick: DWord;
 Event: THandle;
 Msg: TMsg;
begin
 Event := CreateEvent(nil, False, False, nil);

 try
  Tick := GetTickCount + DWord(Milliseconds);

  while (Milliseconds > 0) and (MsgWaitForMultipleObjects(1, Event, False, Milliseconds, QS_ALLINPUT) <> WAIT_TIMEOUT) do
   begin
    if PeekMessage(Msg, 0, 0, 0, PM_REMOVE) then
     begin
      if Msg.message = WM_QUIT then
       begin
        PostQuitMessage(Msg.wParam);
        Break;
       end;

      TranslateMessage(Msg);
      DispatchMessage(Msg);
     end;

    Milliseconds := Tick - GetTickCount;
   end;
 finally
  CloseHandle(Event);
 end;
end;

class function TShellExecEx.FileExists(const aFileName: string): Boolean;
var
 i: Cardinal;
begin
 Result := False;
 i := GetFileAttributes(PChar(aFileName));
 if i <> INVALID_FILE_ATTRIBUTES then
  begin
   Result := True;
  end;
end;

class function TShellExecEx.IsDirectory(const aFileName: string): Boolean;
var
 R: DWord;
begin
 R := GetFileAttributes(PChar(aFileName));
 Result := (R <> DWord(-1)) and ((R and FILE_ATTRIBUTE_DIRECTORY) <> 0);
end;

class function TShellExecEx.OpenFolderAndSelectFile(const FileName: string): Boolean;
var
 IIDL: PItemIDList;
begin
 Result := False;
 IIDL := ILCreateFromPath(PChar(FileName));
 if IIDL <> nil then
  try
   Result := SHOpenFolderAndSelectItems(IIDL, 0, nil, 0) = S_OK;
  finally
   ILFree(IIDL);
  end;
end;

function IsExeRunning(const AExeName: string): Boolean;
var
 h: THandle;
 p: TProcessEntry32;
 bRes: Boolean;
begin
 p.dwSize := SizeOf(p);
 h := CreateToolHelp32Snapshot(TH32CS_SnapProcess, 0);

 try
  Process32First(h, p);

  repeat
   bRes := AnsiUpperCase(AExeName) = AnsiUpperCase(p.szExeFile);
  until bRes or (not Process32Next(h, p));
 finally
  CloseHandle(h);
 end;

 Result := bRes;
end;

class function TShellExecEx.ShellExecEx(lphWnd: HWND; lpVerb, lpFile, lpParameters, lpDirectory: PChar; nShowCommand: Integer; bWaitForCompletion: Boolean = False;
 bProcessMessages: Boolean = False; bUseExeIsRunningCheck: Boolean = False): Boolean;
var
 ShExecInfoW: ShellExecuteInfoW;
 lpExitCode: Cardinal;
 bIsHTTP, bIsCMD, bResShellExecEx: Boolean;
begin
 bIsHTTP := string(lpFile).StartsWith('http://') or string(lpFile).StartsWith('https://');
 if bIsHTTP then
  begin
   Result := ShellExecute(0, 'open', PChar(lpFile), nil, nil, SW_SHOWNORMAL) >= 32;
   Exit
  end;

 bIsCMD := AnsiSameText(lpFile, 'cmd') or AnsiSameText(lpFile, 'cmd.exe');
 if (not bIsCMD) and (not bIsHTTP) and (not TShellExecEx.IsDirectory(lpFile)) and (not TShellExecEx.FileExists(lpFile)) then
  begin
   Result := False;
   Exit;
  end;

 if bIsCMD and (not string(lpParameters).StartsWith('/C ')) then
  lpParameters := PChar('/C ' + lpParameters);

 ZeroMemory(@ShExecInfoW, SizeOf(ShExecInfoW));
 ShExecInfoW.Wnd := lphWnd;
 ShExecInfoW.cbSize := SizeOf(ShellExecuteInfoW);
 ShExecInfoW.fMask := SEE_MASK_NOCLOSEPROCESS;
 ShExecInfoW.lpVerb := lpVerb;
 ShExecInfoW.lpFile := PChar('"' + lpFile + '"');
 ShExecInfoW.lpParameters := lpParameters;
 ShExecInfoW.lpDirectory := lpDirectory;
 ShExecInfoW.nShow := nShowCommand;
 bResShellExecEx := ShellExecuteExW(@ShExecInfoW);
 Result := bResShellExecEx;

 try
  if (bResShellExecEx) and (bWaitForCompletion) then
   begin
    if not bUseExeIsRunningCheck then
     begin
      WaitForInputIdle(ShExecInfoW.hProcess, INFINITE);

      repeat
       TShellExecEx.seDelay(25);
       GetExitCodeProcess(ShExecInfoW.hProcess, lpExitCode);

       if bProcessMessages then
        Application.ProcessMessages;
      until (lpExitCode <> STILL_ACTIVE);
     end
    else
     begin
      while IsExeRunning(ExtractFileName(lpFile)) do
       begin
        TShellExecEx.seDelay(25);

        if bProcessMessages then
         Application.ProcessMessages;
       end;
     end;
   end;
 finally
  CloseHandle(ShExecInfoW.hProcess)
 end;
end;

end.

[himitsu]

Zitat:

Delphi-Quellcode:

      while IsExeRunning(ExtractFileName(lpFile)) do
       begin
        TShellExecEx.seDelay(25);

        if bProcessMessages then
         Application.ProcessMessages;
       end;
     end;

bProcessMessages ?

Dein seDelay macht das doch bereits, nur dass dort viele Sachen falsch/garnicht behandelt werden.
z.B. HotKeys und Menü-Ereignisse sind falsch oder gehen verloren.

Da kannst'e genauso gut im seDelay direkt das Application.ProcessMessages oder Application.HandleMessage; benutzen.

Dieser Parameter ist so oder so sinnlos, da immer Messages behandelt werden.

Zitat:

Delphi-Quellcode:

Tick := GetTickCount + DWord(Milliseconds);

In neuen Delphi-Projekten ist jetzt die Index- und Bereichsprüfung standardmäßig aktiv.
Nach 49,7 Tagen gibt es einen Überlauf und wenn du Diesen gut triffst, dann knallt es.

PS: TFile.Exists und TDirectory.Exists

[DieDolly]

Zitat:

Dein seDelay macht das doch bereits, nur dass dort viele Sachen falsch/garnicht behandelt werden.
z.B. HotKeys und Menü-Ereignisse sind falsch oder gehen verloren.

Ich weiß nicht mehr von wem der Code ist.

Zitat:

In neuen Delphi-Projekten ist jetzt die Index- und Bereichsprüfung standardmäßig aktiv.
Nach 49,7 Tagen gibt es einen Überlauf und wenn du Diesen gut triffst, dann knallt es.

Alternative? Der Code ist schon sehr alt.

Zitat:

PS: Delphi-Referenz durchsuchenTFile.Exists und Delphi-Referenz durchsuchenTDirectory.Exists

Ich nutze lieber meine eigene Implementierung. Die bleibt immer gleich und ist nur für Windows.

Würde mich über ein aktuelleres/besseres Delay freuen.

[himitsu]

Ja, die Delay-Funktion ist von ihm und sie soll ja auch Messages verarbeiten, entgegen einem Sleep oder stumpfen WaitFor.

Delay, zusammen mit noch einem Application.ProcessMessages, ist so aber ganz bestimmt so nicht von ihm :zwinker:


Das seDelay ohne PeekMessage und Co. (bei Ereignis die Funktion abbrechen),
dann würde deine Funktion das machen, was das Parameter bProcessMessages verspricht.
Oder einfach ein Sleep anstatt seDelay (das ist so kurz, dass des auf Message warten nahezu keine bemerkbare Wirkung hat).

[DieDolly]

Ich verstehe.
Entweder Sleep und ProcessMessages oder nur das seDelay. TranslateMessage und DispatchMessage in seDelay entspricht quasi dem Abarbeiten der MessageQueue?

[H.Bothur]

Moin,

kurze Rückmeldung: Der größte Idiot sitzt doch immer vor dem Monitor :-(

Der richtige Aufruf war

Delphi-Quellcode:

ShellExError := ShellExecute(Application.Handle,Nil,PChar('VLC.exe'),PChar('"' +FileName +'"'),Nil,SW_SHOW);

Das viel größere Problem war aber das ich beim Filename eine Verzeichnisebene vergessen habe :-(

Oh Mann :-( :-( Trotzdem vielen, vielen Dank für die ganze Hilfe !!

Hans

[Rolf Frei]

Zitat:

Zitat von H.Bothur (Beitrag 1528050)

Moin,

kurze Rückmeldung: Der größte Idiot sitzt doch immer vor dem Monitor :-(

Der richtige Aufruf war

Delphi-Quellcode:

ShellExError := ShellExecute(Application.Handle,Nil,PChar('VLC.exe'),PChar('"' +FileName +'"'),Nil,SW_SHOW);

Das viel größere Problem war aber das ich beim Filename eine Verzeichnisebene vergessen habe :-(

Oh Mann :-( :-( Trotzdem vielen, vielen Dank für die ganze Hilfe !!

Hans

Wie ich geschrieben habe läuft auch dein Orginalcode aus Post 1, wenn du da keine " drum herum machst (Siehe mein Beispiel von Ende Seite 2). Mit diesem Aufruf, wird der Default Player für mp4 Dateien gestartet und das Video abgespielt. Mit deiner Lösung von heute, muss der VLC installiert sein, was meiner Meinung nach nicht zwingend sein sollte.