Alle Arbeitsgruppen, alle Rechner und dann alle freigaben?

[Zerolith]

Hallo!

also ich möchte mit Hellwalker gern ein Programm schreiben dass
das NEtzwerk nach Arbeitsgruppen durchsucht, dann alle Rechner finded und schließlich alle Freigaben aufließtet.

Dass ich am Ende alle Rechner-Freigaben nach Dateien Durchstöbern kann.

Meines Wissens müsste dass ja mit ein paar API Befehlen möglich sein... bräuchte ein hinweiße des Handlings - Theoretisch funktionierts ja - hab au kein problem mit rekursiver Programmierung. Lediglich happerts bei mir an der Geringen API kenntnis.

also - bin gespannt auf Antworten

thx

[Christian Seehase]

Moin Zerolith,

da kommen für Dich wohl am ehesten die Funktionen WNetOpenEnum, WNetEnumResource und WNetCloseEnum in Frage.

Eigentlich müsstest Du zu denen hier auch Beispiele finden.

[Zerolith]

aha ? :shock:

:|

kein plan - -n paar bespiele - find nix passendes mit der boardsuche...
schau mal morgen

was is ne gute Quelle?

MSDN? PSDK? DelphiHilfe?

[Chewie]

Zitat:

Zitat von Zerolith

was is ne gute Quelle?

MSDN? PSDK? DelphiHilfe?

Die ersten beiden, das PSDK ist ja eh komplett im MDSN enthalten.

Suche im Forum: Schau mal hier.

[fossi3]

Was ist Hellwalker?
Noch nie gehört!

[Christian Seehase]

Moin fossi,

Zitat:

Zitat von fossi3

Was ist Hellwalker?

ein User des Forums ;-)

[Zerolith]

Thx @ Christian

werd mir das mal zu gemüte führen

cya

[Mario]

Hier mal als Basis:

Delphi-Quellcode:

function TThreadGetComputer.RechnerInWG(lpnr: PNetResource): Boolean;

 procedure AddComputerToList(Value: TNetResource);
 begin
   strRemoteName := Value.lpRemoteName;
   if Value.dwDisplayType <> RESOURCEDISPLAYTYPE_SERVER THEN Exit;
   ListBox.Items.Add(strRemoteName);
 end;

const
 // RESOURCE_CONNECTED RESOURCE_CONTEXT RESOURCE_GLOBALNET RESOURCE_REMEMBERED
 c_dwScope = RESOURCE_GLOBALNET;
 // RESOURCETYPE_ANY RESOURCETYPE_DISK RESOURCETYPE_PRINT
 c_dwType  = RESOURCETYPE_DISK;

var cbBuffer: DWORD;
    hEnum, dwResult, dwResultEnum : DWORD;
    lpnrLocal : array [0..16384 div SizeOf(TNetResource)] of TNetResource;
    i : Integer;
    cEntries : Longint;
begin

//
// basiert auf Microsoft Beispiel "Enumerating Network Resources" in C++
//
// [url]http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wnet/networks_77sj.asp[/url]
//

 cbBuffer := 16384;
 centries := -1;
 dwResult := WNetOpenEnum( c_dwScope,
                           c_dwType,
                           0, // 0 = All resources
                           lpnr,
                           hEnum);

 if dwResult <> NO_ERROR
  then
   begin
    Result := False;
    // Fehlerbehandlung('Fehler bei WNetOpenEnum (%d)',[dwResult]);
    Exit;
   end;

 FillChar( lpnrLocal, cbBuffer, 0 );

 dwResultEnum := WNetEnumResource(hEnum,
                                  DWORD(cEntries),
                                  @lpnrLocal,
                                  cbBuffer);

 if dwResultEnum = NO_ERROR
  then
   begin // dwResultEnum = NO_ERROR
    for i := 0 to cEntries - 1 do
     begin
      AddComputerToList(lpnrLocal[i]);
      if (c_dwScope = RESOURCE_GLOBALNET) AND
         (RESOURCEUSAGE_CONTAINER = (lpnrLocal[i].dwUsage AND RESOURCEUSAGE_CONTAINER)) AND
         (Not Terminated)
       then RechnerInWG(@lpnrLocal[i]);
     end;
   end // dwResultEnum = NO_ERROR
  else
   begin // dwResultEnum <> NO_ERROR
    IF dwResultEnum <> ERROR_NO_MORE_ITEMS
     THEN
      begin
       Result := False;
       // Fehlerbehandlung (Format('Fehler bei WNetEnumResource (%d)',[dwResultEnum]));
       Exit;
      end;
   end; // dwResultEnum <> NO_ERROR

 dwResult := WNetCloseEnum(hEnum);

 if dwResult <> NO_ERROR
  then
   begin
    Result := False;
    // Fehlerbehandlung (Format('Fehler bei WNetCloseEnum (%d)',[dwResult]));
    Exit;
   end;

 Result := True;
end;

Dieser Code listet alle Rechner im Netz auf.

[Zerolith]

ehm - was muss ich der Funktion übergeben?

[Mario]

NIL

[Zerolith]

ups *G*

thx - funktioniert....

und wie kann ich alle Arbeitsgruppen scannen?

[Mario]

Ich vermute mal, hier liegt der Schlüssel:

Delphi-Quellcode:

// RESOURCE_CONNECTED RESOURCE_CONTEXT RESOURCE_GLOBALNET RESOURCE_REMEMBERED 
c_dwScope = RESOURCE_GLOBALNET;

Schau mal ins SDK, dass müsste Dir da weiterhelfen.

[Zerolith]

k - thx!

[Christian Seehase]

Moin Zusammen,

die Resourcen sind strukturiert.

1. Zuerst werden (mit nil) die Provider ermittelt (in reinen Windowsnetzen, wird man da nur einen erhalten, nämlich "Microsoft Windows-Netzwerk",
2. dann die darin enthaltenen Domänen/Arbeitsgruppen (wenn man den Provider angibt),
3. dann die darin enthaltenen Rechner (eben bei Angabe von Domäne bzw. Arbeitsgruppe, das wird bei dieser Funktion (WNetEnumResource) nicht weiter unterschieden,
4. und, zu guter Letzt, die Freigaben der Rechner

Solange eine aufgezählte Resource die Usage RESOURCEUSAGE_CONTAINER hat, kann man darin suchen.

Man muss eigentlich "nur" noch filtern (durch Angabe/Überprüfung von Type, DisplayType und Usage) was man haben will.

[webhuhn]

mhh.. ich hab ein ähnliches problem:
ich will alle rechner der netzwerkes in einem ListView auflisten...

aber mit dem code hier komme ich nicht ganz klar :-(

gibt es noch eine andere möglichkeit?

[Assarbad]

NetServerEnum und WNetEnumResource benutzen

[webhuhn]

nur wie?
das is mein problem

[Assarbad]

Geh mal auf meine Seite und schau dir den Source von LoggedOn2 an. Da findest du ein Beispiel zu NetServerEnum(). Ist glaub ich in der Datei LoggedOnFunc.pas

Für die andere Funktion haste ja weiter oben schon Beispiele.

[webhuhn]

dein quellcode lässt sich bei mir net compilieren,er meckert bei:

Code:

...
VAR
  "NIL_HANDLE: Integer ABSOLUTE 0;" ( << die zeile mag er net)
  NetApiBufferFree: TNetApiBufferFree = NIL; //NT31+
  NetServerEnum: TNetServerEnum = NIL; //NT31+
...

Error:
[Error] LoggedOnFunc.pas(26): Variable name expected


auf der LoggedOnFun.pas

[Mario]

Hier ist Dein Angriffspunkt:

Delphi-Quellcode:

procedure AddComputerToList(Value: TNetResource); 
begin 
   strRemoteName := Value.lpRemoteName; 
   if Value.dwDisplayType <> RESOURCEDISPLAYTYPE_SERVER THEN Exit; 
   ListBox.Items.Add(strRemoteName);
end;

ListBox.Items.Add(strRemoteName);

Dann brauchst Du nur noch die Funktion aufrufen:

Delphi-Quellcode:

RechnerInWG(NIL)

[webhuhn]

das is alles O.o

mehr brauchts dazu net?
oder muss ich das in den alte code einfügen?

achja:und wenn das alles is: tuts das unter win9x/2000/XP?

[Mario]

@Assarbad: Dein Source ist für den C++ Builder? Damit kann Delphi doch nix anfangen, oder?

@webhuhn: Ich bezog mich auf die erste Seite dieser Diskussion. Da hatte ich den Code gepostet. Schaue da noch mal nach, Du musst nur noch die uses ergänzen, bis er nicht mehr meckert.

Gehen sollte es unter allen Systemen.

[webhuhn]

achso, danke :D

dass es unter allen systeme läuft wäre gut ,weil das, was ich im moment hab tuts unter Win9X irgendwie net.. :-(


edit:
mhh.. der meckert :(

welche uses muss ich ergänzen?
ShellApi hab ich ergänz aber funktionieren tuts net

[Mario]

so sollte es tun (aber jetzt nicht getestet):

Delphi-Quellcode:

unit Unit1;

interface

uses Windows;

implementation

function RechnerInWG(lpnr: PNetResource): Boolean;

procedure AddComputerToList(Value: TNetResource);
var strRemoteName: String;
begin
   strRemoteName := Value.lpRemoteName;
   if Value.dwDisplayType <> RESOURCEDISPLAYTYPE_SERVER THEN Exit;
   ListBox.Items.Add(strRemoteName);
end;

const 
// RESOURCE_CONNECTED RESOURCE_CONTEXT RESOURCE_GLOBALNET RESOURCE_REMEMBERED 
c_dwScope = RESOURCE_GLOBALNET; 
// RESOURCETYPE_ANY RESOURCETYPE_DISK RESOURCETYPE_PRINT 
c_dwType  = RESOURCETYPE_DISK; 

var cbBuffer: DWORD; 
    hEnum, dwResult, dwResultEnum : DWORD; 
    lpnrLocal : array [0..16384 div SizeOf(TNetResource)] of TNetResource; 
    i : Integer; 
    cEntries : Longint; 
begin 

// 
// basiert auf Microsoft Beispiel "Enumerating Network Resources" in C++ 
// 
// [url]http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wnet/networks_77sj.asp[/url] 
// 

cbBuffer := 16384; 
centries := -1; 
dwResult := WNetOpenEnum( c_dwScope, 
                           c_dwType, 
                           0, // 0 = All resources 
                           lpnr, 
                           hEnum); 

if dwResult <> NO_ERROR 
  then 
   begin 
    Result := False; 
    // Fehlerbehandlung('Fehler bei WNetOpenEnum (%d)',[dwResult]); 
    Exit; 
   end; 

FillChar( lpnrLocal, cbBuffer, 0 ); 

dwResultEnum := WNetEnumResource(hEnum, 
                                  DWORD(cEntries), 
                                  @lpnrLocal, 
                                  cbBuffer); 

if dwResultEnum = NO_ERROR 
  then 
   begin // dwResultEnum = NO_ERROR 
    for i := 0 to cEntries - 1 do 
     begin 
      AddComputerToList(lpnrLocal[i]);
      if (c_dwScope = RESOURCE_GLOBALNET) AND
         (RESOURCEUSAGE_CONTAINER = (lpnrLocal[i].dwUsage AND RESOURCEUSAGE_CONTAINER))
       then RechnerInWG(@lpnrLocal[i]);
     end; 
   end // dwResultEnum = NO_ERROR 
  else 
   begin // dwResultEnum <> NO_ERROR 
    IF dwResultEnum <> ERROR_NO_MORE_ITEMS 
     THEN 
      begin 
       Result := False; 
       // Fehlerbehandlung (Format('Fehler bei WNetEnumResource (%d)',[dwResultEnum])); 
       Exit; 
      end; 
   end; // dwResultEnum <> NO_ERROR 

dwResult := WNetCloseEnum(hEnum); 

if dwResult <> NO_ERROR 
  then 
   begin 
    Result := False; 
    // Fehlerbehandlung (Format('Fehler bei WNetCloseEnum (%d)',[dwResult])); 
    Exit; 
   end; 

Result := True; 
end; 

end.

Aber Achtung! Bei großen Netzwerken kann das eine Weile dauern.

[webhuhn]

erstmal danke :D

aber warum meckert er da :

Code:

procedure AddComputerToList(Value: TNetResource);
var strRemoteName: String;
begin
   strRemoteName := Value.lpRemoteName;
   if Value.dwDisplayType <> RESOURCEDISPLAYTYPE_SERVER THEN Exit;
   ListBox.Items.Add(strRemoteName);
end;

das da:

[Error] Unit1.pas(30): Undeclared identifier: 'ListBox'
[Error] Unit1.pas(30): Missing operator or semicolon
[Fatal Error] Project1.dpr(5): Could not compile used unit 'Unit1.pas'

?

thx 4 hlp

[Mario]

Das ist die Listbox, die die Routine befüllen will. Die musst Du natürlich angeben, also z.B.:

Delphi-Quellcode:

Form1.ListBox1.Items.Add(strRemoteName);

[webhuhn]

hatte mich einfach vertippt :-(

sry :(

tuts jetzt, danke nochmal :D

#edit:

auch auf 98 :D

BIG THX :D

[webhuhn]

hi

ich bins ( schon wieder ;D )

gibt es auch eine möglichkeit den Progress des Rechnersuchens mit ner Progressbar darzustellen?

thx 4 hlp

[Mario]

Zitat:

Zitat von webhuhn

gibt es auch eine möglichkeit den Progress des Rechnersuchens mit ner Progressbar darzustellen?

Nicht das ich wüßte. Die Funktion ruft sich selbst solange auf, bis Windows keine Daten mehr bereit stellt. Nicht ohne Grund zeigt Windows, wenn man in die Netzwerkumgebung geht, nur die Eieruhr...

[MikeS]

Moin!
werden auch Rechner mit Linux aufgelistet??

[Mario]

Es werden alle die Rechner angezeigt, die dir die Netzwerkumgebung anzeigt.