Ist es möglich die Scrollbar in MDI-Form abzuschalten ?

[_SolidSnake_]

Hallo zusammen.

Ist es möglich die Scrollbar in einer MDI-Form abzuschalten ? Ich hab bereits gegoogelt und auch hier im Forum gesucht aber leider nichts passendes gefunden.

Gruß
Micha

[Flocke]

Es könnte so gehen (nicht ausprobiert):

Delphi-Quellcode:

SetWindowLong(Form1.ClientHandle, GWL_STYLE,
  GetWindowLong(Form1.ClientHandle, GWL_STYLE) and (not (WS_HSCROLL or WS_VSCROLL)));
SetWindowPos(Form1.ClientHandle, 0, 0, 0, 0, 0, SWP_FRAMECHANGED or
  SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE or SWP_NOZORDER);

"Form1" durch den Namen des MDI-Hauptformulars ersetzen.

[_SolidSnake_]

Hallo Flocke.

Danke für die Antwort.

Ich hab den Code in das onCreate-Ereigniss der MDI-Form geschrieben aber es funktioniert leider nicht. Ich bekomme immer noch die Scrollbars wenn ich das MDI-Child über den Rand der Form bewege.

Gruß
Micha

[Flocke]

Wie ich geschrieben hatte: nicht ausprobiert.

Probiers mal in FormShow bzw. alternativ auf Menüeintrag oder Knopfdruck. Wenn's geht, dann müsste man das auch dynamisch ausschalten können wenn die Scrollbars schon angezeigt werden.

Wenn's nicht geht, dann kann man es wohl (mit einfachen Mitteln) überhaupt nicht ausschalten.

[_SolidSnake_]

Hallo.

Ich hab es nun in mehreren Möglichkeiten ausprobiert aber es bringt leider nichts, die Scrollbar wird immer wieder angezeigt.

Ich hab mir schon die halbe nacht den Kopf darüber zerbrochen und in zahlreichen Foren nach einer Lösung gesucht. Ich glaube fast, das man mit der Scrollbar wohl leben muss :roll:

Danke für die Hilfe :zwinker:

Gruß
Micha

[Noch Fragen]

Hallo zusammen,
setzt doch mal die Eigenschaft "Visible" der HorizScrollBar auf false.

Genauso auch die vertikale.

Gruß

Martin

[_SolidSnake_]

Hallo

Danke für die Antwort, aber das hab ich als erstes Versuch :zwinker:

Da reagiert er leider überhaupt nicht drauf.

Gruß
Micha

[Flocke]

Einen Hinweis habe ich gerade noch gefunden, habe aber gerade keine Zeit näher drauf einzugehen.

1. Du musst die Fensterprozedur von Form1.ClientHandle erweitern (Stichwort: GWL_WNDPROC)
2. Du musst WM_NCCALCSIZE abfangen und vor dem Weiterleiten an den Default-Handler

Delphi-Quellcode:

ShowScrollBar(HWnd, SB_BOTH, 0 /*false*/);

aufrufen.

[_SolidSnake_]

Hallo Flocke

Danke erstmal für den Hinweis. Leider hab ich noch nichts mit abgeleiteten Fenstern gemacht und komme da auch nicht wirklich weiter.

Ich hab mal ein wenig gegoogelt und einen Code für das ausschalten von den Scrollbars in einem Grid gefunden. Den hab ich ein wenig abgeändert aber ich bekomme immer noch eine Fehlermeldung das ein = erwartet aber ein '(' gefunden wurde. danach liegt der Cursor bei

Delphi-Quellcode:

procedure TNoScroll.WMNCCalcSize(var Msg: TMessage);

Der komplette Code sieht nun so aus

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TNoScroll = class(TControl)
  private
    procedure WMNCCalcSize(var Msg: TMessage);
      message WM_NCCALCSIZE;
  end;

  type
  TForm1 = class(TForm)
    procedure TNoScroll.WMNCCalcSize(var Msg: TMessage);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;



var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TNoScroll.WMNCCalcSize(var Msg: TMessage);
const
  Scrollstyles = WS_VSCROLL or WS_HSCROLL;
var
  Style: Integer;
begin
  Style := GetWindowLong(Form1.ClientHandle, GWL_STYLE);
  if (Style and Scrollstyles) <> 0 then
    SetWindowLong(Form1.ClientHandle, GWL_STYLE, Style and not Scrollstyles);
  inherited;
end;

end.

Wenn ich die Codezeile von Dir eintrage

Delphi-Quellcode:

ShowScrollBar(HWnd, SB_BOTH, 0 /*false*/);

Bekomm ich Fehlermeldungen das er statt dem / und * ein @ erwartet.

Gruß
Micha

[Angel4585]

warum TNoScroll? mach das doch direkt in TForm1

Delphi-Quellcode:

  type 
  TForm1 = class(TForm) 
  private     
    procedure WMNCCalcSize(var Msg: TMessage); 
      message WM_NCCALCSIZE; 
    { Private-Deklarationen } 
  public 
    { Public-Deklarationen } 
  end; 



var 
  Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure TForm1.WMNCCalcSize(var Msg: TMessage); 
const 
  Scrollstyles = WS_VSCROLL or WS_HSCROLL; 
var 
  Style: Integer; 
begin 
  Style := GetWindowLong(Self.ClientHandle, GWL_STYLE); 
  if (Style and Scrollstyles) <> 0 then 
    SetWindowLong(Self.ClientHandle, GWL_STYLE, Style and not Scrollstyles); 
  inherited; 
end;

so sollte das gehen..(nicht getestet)

[_SolidSnake_]

Hallo.

Danke, das hab ich eingesetzt.

Mir ist aufgefallen das Du oben noch

Delphi-Quellcode:

procedure TNoScroll.WMNCCalcSize(var Msg: TMessage);

benutzt, aber unten

Delphi-Quellcode:

procedure TForm1.WMNCCalcSize(var Msg: TMessage);

angegeben hast.

Ist das so ok ?

Wenn ich es genau so übernehme bekomm ich aber immer noch den selben Fehler das er ein = erwartet aber ein ( bekommt.

Gruß
Micha

[Angel4585]

*grins* typische Copy&Paste Fehler, habs korrigiert

[_SolidSnake_]

:( Hmmm ... echt hartnäckig diese Scrollbars :roll:

Nun funktioniert die Ausführung und er gibt mir keine Fehlermeldung mehr, aber ich bekomme immer noch die Scrollbars angezeigt.

Gruß
Micha

[Angel4585]

prüfe mal ob er überhaupt in die Pozedur einspringt, wenn ja dann musst du innerhalb der Prozedur was änder, wenn er nicht reinspringt musst du mal die Message ändern(weis grad leider nicht welche)

[_SolidSnake_]

Er führt die Prozedur beim starten der Anwendung 4 mal aus und wenn ich die größe der MDI-Form ändere, aber auf das anzeigen der Scrollbalken hat es keinen Einfluss.

[Angel4585]

aha.. springt er in die Abfrage rein? Wenn ja, welchen Wert hat "Style" dann?

[_SolidSnake_]

Wo kann ich das nachsehen welchen Wert er hat ? Oder muss ich dazu eine Ausgabe auf einem Label machen ?
Ich arbeite noch nicht lange mit Delphi und hab noch nicht alles raus.

[Angel4585]

geh mal auf die Zeile in der die den Wert haben willst und drück da F5, dann müsste links davon ein roter Punkt zu sehen sein. das ist ein Haltepunkt, da hällt das Programm an und du kannst im Quelltext dann mit der Maus über die Variable Fahren. der Wert kommt dann als Hint. Probiers einfach mal aus

Edit: Welche Version von Delphi hast du eigentlich? schreib das bitte auch in dein Profil.

[teebee]

Peter Below zeigt hier wie man es hinbekommt. Das Beispiel funktioniert wie gewünscht.

Gruß, teebee

[Flocke]

@Angel4585: Das mit dem Hauptfenster kann nicht klappen, weil das MDI-Client-Fenster noch mal ein Unterfenster vom Hauptfenster ist. Darum muss man auch ClientHandle und nicht Handle benutzen.

@teebee: Der Link von dir zeigt in etwa das, was ich meinte.

Die Varianten

Delphi-Quellcode:

ShowScrollBar(HWnd, SB_BOTH, 0 /*false*/);

bzw.

Delphi-Quellcode:

SetWindowLong(HWnd, GWL_STYLE, GetWindowLong(HWnd, GWL_STYLE) and (not (WS_HSCROLL or WS_VSCROLL)));

sind wahrscheinlich gleich gut, wobei ich persönlich die SetWindowLong-Variante vorziehen würde.

[_SolidSnake_]

Hallo.

Erstmal Danke an alle für die Hilfe.

Hallo Angel

Ich hab bei Style beim starten einen Wert von 0 gehabt.

Ich benutze Delphi 2005 Architect. Ich weiss, das ist für einen Anfänger eine heftig große Version, aber ich hab sie von meinem Chef für nen Apfel und nen Ei bekommen und zugegriffen. Er wollte eigentlich Delphi erlernen und hat es dann doch hingeschmissen.
Und da ich selbst gerade im Fernstudium zum Programmierer C++ und VBA stecke (Anfang) dachte ich mir, da es schon eine Ähnlichkeit gibt, versuch ich mich auch noch ein wenig an Delphi, was ich später eh als Hauptsprache weiterführen möchte.

--------------------------------------------------------------------------------------------

Hallo Teebee

Ich hab den Code wie angegeben eingetragen aber ich bekomme den Fehler "[Fehler] Unit1.pas(34): E2036 Variable erforderlich" und "[Fehler] Unit1.pas(12): E2065 Ungenügende Forward- oder External-Deklaration: 'TForm1.ClientWindowProc'".

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  If ClientHandle <> 0 Then Begin
    If GetWindowLong( ClientHandle, GWL_USERDATA ) <> 0 Then
      Exit; // cannot subclass client window, userdata already in use
    SetWindowLong( ClientHandle, GWL_USERDATA,
                   SetWindowLong( ClientHandle, GWL_WNDPROC,
                                  integer( @ClientWindowProc){hier bleibt der Cursor bei der Fehlermeldung stehen}));
  End;
end;

Der komplette Code sieht nun so aus:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    Function ClientWindowProc( wnd: HWND; msg: Cardinal; wparam,
                           lparam: Integer ): Integer; stdcall;
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  If ClientHandle <> 0 Then Begin
    If GetWindowLong( ClientHandle, GWL_USERDATA ) <> 0 Then
      Exit; // cannot subclass client window, userdata already in use
    SetWindowLong( ClientHandle, GWL_USERDATA,
                   SetWindowLong( ClientHandle, GWL_WNDPROC,
                                  integer( @ClientWindowProc)));
  End;
end;

Function ClientWindowProc( wnd: HWND; msg: Cardinal; wparam,
                           lparam: Integer ): Integer; stdcall;
Var
  f: Pointer;
Begin
  f:= Pointer( GetWindowLong( wnd, GWL_USERDATA ));
  Case msg of
    WM_NCCALCSIZE: Begin
        If ( GetWindowLong( wnd, GWL_STYLE ) and
             (WS_HSCROLL or WS_VSCROLL)) <> 0
        Then
          SetWindowLong( wnd, GWL_STYLE,
                         GetWindowLong( wnd, GWL_STYLE )
                         and not (WS_HSCROLL or WS_VSCROLL));
      End;
  End;
  Result := CallWindowProc( f, wnd, msg, wparam, lparam );
End;

end.

--------------------------------------------------------------------------------------------

Hallo Flocke

Ich hab mir unter Google soweit schonmal was über GWL_WNDPROC rausgesucht und bin dann auf Subclassing gestossen. Allerdings werd ich mich damit wohl erstmal tiefer beschäftigen müssen da ich in die Richtung noch garkeine Ahnung habe.

Gruß
Micha

[Flocke]

Schon fast richtig - allerdings ist ClientWndProc keine Methode von TForm1 sondern eigenständig.

Du musst es also oben aus der Deklaration von TForm1 entfernen und unten über das FormCreate setzen (damit's bekannt ist). Vielleicht solltest du es auch erst in FormShow machen, damit ClientHandle auf jeden Fall gültig ist.

Also:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm1 = class(TForm)
    procedure FormShow(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function ClientWindowProcNoSB(wnd: HWND; msg: Cardinal; wparam, lparam: Integer): Integer; stdcall;
begin
  if msg = WM_NCCALCSIZE then
    SetWindowLong(wnd, GWL_STYLE,
      GetWindowLong(wnd, GWL_STYLE) and not (WS_HSCROLL or WS_VSCROLL));
  Result := CallWindowProc(Pointer(GetWindowLong(wnd, GWL_USERDATA)),
    wnd, msg, wparam, lparam);
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  If ClientHandle <> 0 Then
    If GetWindowLong( ClientHandle, GWL_USERDATA ) = 0 Then
      SetWindowLong( ClientHandle, GWL_USERDATA,
                     SetWindowLong( ClientHandle, GWL_WNDPROC,
                                    integer( @ClientWindowProcNoSB)));
end;

end.

[_SolidSnake_]

Hallo Flocke.

Ich hab es bevor Du editiert hast so gemacht:

Delphi-Quellcode:

unit Unit1; 

interface 

uses 
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
  Dialogs; 

type 
  TForm1 = class(TForm) 
    procedure FormCreate(Sender: TObject); 
  private 
    { Private-Deklarationen } 
  public 
    { Public-Deklarationen } 
  end; 

  Function ClientWindowProc( wnd: HWND; msg: Cardinal; wparam, 
                           lparam: Integer ): Integer; stdcall; 

var 
  Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
  If ClientHandle <> 0 Then Begin 
    If GetWindowLong( ClientHandle, GWL_USERDATA ) <> 0 Then 
      Exit; // cannot subclass client window, userdata already in use 
    SetWindowLong( ClientHandle, GWL_USERDATA, 
                   SetWindowLong( ClientHandle, GWL_WNDPROC, 
                                  integer( @ClientWindowProc))); 
  End; 
end; 

Function ClientWindowProc( wnd: HWND; msg: Cardinal; wparam, 
                           lparam: Integer ): Integer; stdcall; 
Var 
  f: Pointer; 
Begin 
  f:= Pointer( GetWindowLong( wnd, GWL_USERDATA )); 
  Case msg of 
    WM_NCCALCSIZE: Begin 
        If ( GetWindowLong( wnd, GWL_STYLE ) and 
             (WS_HSCROLL or WS_VSCROLL)) <> 0 
        Then 
          SetWindowLong( wnd, GWL_STYLE, 
                         GetWindowLong( wnd, GWL_STYLE ) 
                         and not (WS_HSCROLL or WS_VSCROLL)); 
      End; 
  End; 
  Result := CallWindowProc( f, wnd, msg, wparam, lparam ); 
End; 

end.

Hat auch funktioniert, allerdings finde ich deine Version sauberer. :)

Da hab ich nun nicht mehr dran gedacht, das die Reihenfolge etwas damit zu tun haben könnte :wall:

Jedenfalls vielen Dank an alle die mir geholfen haben :-D

Da ich selbst bei Google und in anderen Foren 2 Tage an diesem Problem klebte und immer die gleiche Fragen gesehen aber nie eine Antwort gefunden habe hoffe ich das hiermit auch den anderen geholfen werden kann und werden den Code wenn keiner was dagegen hat in den anderen Foren wo ich die gleiche Frage gefunden habe als Antwort posten.

Anbei nochmal das ganze als Zip.

Gruß
Micha