MouseEnter/MouseLeave ohne VCL!

[rey003]

Hallo Leute, :hi:
ich hab ein Problem mit den oben genannten Funktionen! Oder besser gesagt, es gibt diese Funktionen ja leider ohne VCL gar nicht! Ich habe mir eine eigene Komponente für NonVCL geschrieben, die wie eine Art Button funktionieren soll! Dieser "Button" soll jetzt auf MouseEnter und MouseLeave reagieren!
Bis jetzt hab ich es so gemacht, weil ich es nicht besser wusste: :gruebel:

MouseMove-Nachicht des Hauptfensters (wo die Komponente drauf sitzt)!

Delphi-Quellcode:

var
  Target       : HWND = 0;
  FMouseTarget : HWND = 0;
...
   
   WM_MOUSEMOVE:
    begin
      if (GetCursorPos(point)) then
        begin
          Target := WindowFromPoint(point);
          ScreenToClient(Target, point);
          Target := ChildWindowFromPoint(Target, point);
          if (FMouseTarget = hwnd_Main) and (Target <> hwnd_Main)
           then sendmessage(Target,WM_DSMOUSEENTER,0,0);
          if (FMouseTarget <> hwnd_Main) and (Target = hwnd_Main )
           then sendmessage(FMouseTarget,WM_DSMOUSELEAVE,0,0);
          FMouseTarget := Target;
        end;
    end;

Da das nur gilt wenn sich die Mouse auf dem Fenster befindet und nicht wenn die Mouse über der Komponente ist, hab ich bei der Komponente einfach nur das reingeschrieben:

Delphi-Quellcode:

  WM_MOUSEMOVE:
    begin
     //nicht wichtig 
      if Assigned(config^.FOnMouseMove)
       then config^.FOnMouseMove(config^.MainWnd,LOWORD(lParam),HIWORD(lParam));
     //das aber 
      sendmessage(GetParent(config^.MainWnd),WM_MOUSEMOVE,0,0);
    end;

Ich weiß das ist nicht grade sauber programmiert, aber mir fiel nichts besseres ein! :cry:
Nun hab ich aber leider festgestellt, dass das nun nicht mal immer funktioniert!
Sobald die Mouse zu schnell ist, kommt es zu einer Verzögerung und es funktioniert nicht mehr! (besonders bei MouseLeave) :evil:
So jetzt zu meiner Frage:
Wie würdet ihr sowas realisieren??? :?:
Ich hoffe ihr könnt mir helfen! Schon mal danke im Voraus! :zwinker:

[ste_ett]

WM_MOUSELEAVE
:)

-edit-

Sry, verlesen :(

[rey003]

WM_MouseLeave is ja eh so ein Teil was ich noch net ganz verstehe! :cry:
Das funktioniert ja überhaupt nicht! (zumindest nicht bei mir)

[Namenloser]

Delphi-Quellcode:

procedure MouseEnter(var Message: TMessage); message CM_MOUSEENTER;
procedure MouseLeave(var Message: TMessage); message CM_MOUSELEAVE;

Hat bei meiner Button-Komponente hervorragend funktioniert!

[rey003]

Mag sein... Ich hab aber keine VCL und damit kann ich die Nachichten der VCL auch nicht wirklich verwenden! :?

[jbg]

Du könntest WM_MOUSEMOVE und WM_MOUSELEAVE (Win98+) kombinieren.

[rey003]

Hmm... Ich hab ja versucht WM_MOUSELEAVE zu benutzen! Aber irgendwie funktioniert das überhaupt nicht!
Das Fenster reagiert auf die Nachicht gar nicht! Oder ich weiß gar nicht ob sie überhaupt geschickt wird! Muss man dafür erst vorher irgendetwas anderes ausführen um das zu aktivieren?

Ich habe auch schon mal nachgesehen wie das in der VCL gemacht wird (die müssen das ja auch irgendwie hinbekommen haben), aber das habe ich nicht wirklich verstanden! :?
Und das was ich mir ausgedacht hatte erfüllt seinen Zweck nur sehr unzuverlässig! :cry:

[jbg]

Zitat:

Zitat von rey003

Ich habe auch schon mal nachgesehen wie das in der VCL gemacht wird (die müssen das ja auch irgendwie hinbekommen haben)

Das funktioniert anders, da das schon zu Windows 3.1 (Delphi 1) Zeiten funktionieren musste. Dort wird in der Leerlauf-Zeit (Idle) die Mausposition abgefragt und das darunter liegende Control ermittelt. Unterscheidet sich dies vom vorher ermittelten Control, so wird für das alte ein CM_MOUSELEAVE und für das neue Control ein CM_MOUSEENTER ausgelöst.

Schon mal ins PSDK geschaut? Da würdest du alle Informationen finden, die du zum Nutzen von WM_MOUSELEAVE brachst. Aber da Weihnachten noch nicht so lange her ist, bin ich mal so nett und poste hier den Code:

Delphi-Quellcode:

var
  EventTrack: TTrackMouseEvent;
begin
  case Msg of
    WM_MOUSELEAVE:
      begin
        WindowHover := False;
        SetWindowText(Handle, 'Left');
      end;
    WM_MOUSEMOVE:
      begin
        if not WindowHover then
        begin
          WindowHover := True;
          SetWindowText(Handle, 'Entered');

          { WM_MOUSELEAVE soll generiert werden }
          EventTrack.cbSize := SizeOf(EventTrack);
          EventTrack.dwFlags := TME_LEAVE;
          EventTrack.hwndTrack := Handle;
          EventTrack.dwHoverTime := HOVER_DEFAULT;
          TrackMouseEvent(EventTrack);
        end;
      end;
    ...
  end;
end;

[rey003]

Reingeschaut schon! Aber ich glaub nicht wirklich verstanden! :?
Sooooviel hab ich mit NonVCL auch noch nicht gemacht! Bin noch am Lernen!

:thumb: Funktioniert perfekt! :thumb: (Genauso wie der Start von Delphi!) :wink:

Und ich hab auch wieder was dazu gelernt! :lol:
Also danke nochmal und schon mal einen guten Rutsch! :hello:

[Luckie]

Ich versuche das auch gerade:

Delphi-Quellcode:

    WM_MOUSELEAVE:
      begin
        WindowHover := False;
        LinkFont := CreateFont(LINKFONTSIZE, 0, 0, 0, 400, 0, 0, 0, ANSI_CHARSET, OUT_DEFAULT_PRECIS,
          CLIP_DEFAULT_PRECIS, DEFAULT_QUALITY, DEFAULT_PITCH, LINKFONTNAME);
        if LinkFont <> 0 then
          SendDlgItemMessage(hDlg, ID_STC_WEB, WM_SETFONT, Integer(LinkFont), Integer(true));
      end;
    WM_MOUSEMOVE:
      begin
        GetCursorPos(pt);
        GetWindowRect(GetDlgItem(hDlg, ID_STC_WEB), rect);
        if PtInRect(rect, pt) then
        begin
          begin
            WindowHover := True;
            LinkFont := CreateFont(LINKFONTSIZE, 0, 0, 0, 400, 0, 1, 0, ANSI_CHARSET, OUT_DEFAULT_PRECIS,
              CLIP_DEFAULT_PRECIS, DEFAULT_QUALITY, DEFAULT_PITCH, LINKFONTNAME);
            if LinkFont <> 0 then
              SendDlgItemMessage(hDlg, ID_STC_WEB, WM_SETFONT, Integer(LinkFont), Integer(true));
            EventTrack.cbSize := SizeOf(EventTrack);
            EventTrack.dwFlags := TME_LEAVE;
            EventTrack.hwndTrack := GetDlgItem(hDlg, ID_STC_WEB);
            EventTrack.dwHoverTime := HOVER_DEFAULT;
            TrackMouseEvent(EventTrack);
          end;
        end;

ID_STC_WEB ist ein Static Kontrol. Aber ich bekomme keine WM_MOUSELEAVE Nachricht. :gruebel:

[rey003]

Ich weiß nicht ob ich dein Problem jetzt richtig verstanden habe, aber ich hatte den Quelltext von jbg in die Nachichtenprocedure meiner eigenen "Komponente" geschrieben und konnte somit auf das WM_MOUSELEAVE von der Komponente (nur von diesem Window) reagieren!
Jetzt glaube ich, dass das TrackMouseEvent für dein Static zwar erstellt wird, aber die WM_MOUSELEAVE Nachicht nur in der Nachichtenprocedure deines Hauptfensters (oder wie man das in der Fachsprache bezeichnet :gruebel: ) bearbeitet wird! Dahin wird sie aber nicht geschickt sondern nur an das Static Kontrol! Du müsstest also die eine Nachicht an das Static abfangen und so anpassen wie du willst!

[Luckie]

Also das Static SubClassen. Ich hatte schon so etwas befürchtet.

[rey003]

Ja, da wirste wohl nicht drumherum kommen!

[Luckie]

So jetzt habe ich das Static ge-subclassed:

Delphi-Quellcode:

function LinkStcWndProc(hLinkStc, uMsg, wParam, lParam: DWORD): DWORD; stdcall;
var
  LinkFont          : HFONT;
  EventTrack        : TTrackMouseEvent;
begin
  Result := 0;
  case uMsg of
    WM_MOUSELEAVE:
      begin
        WindowHover := False;
        LinkFont := CreateFont(LINKFONTSIZE, 0, 0, 0, 400, 0, 0, 0, ANSI_CHARSET, OUT_DEFAULT_PRECIS,
          CLIP_DEFAULT_PRECIS, DEFAULT_QUALITY, DEFAULT_PITCH, LINKFONTNAME);
        if LinkFont <> 0 then
          SendMessage(hLinkStc, WM_SETFONT, Integer(LinkFont), Integer(true));
      end;
    WM_MOUSEMOVE:
      begin
        WindowHover := True;
        LinkFont := CreateFont(LINKFONTSIZE, 0, 0, 0, 400, 0, 1, 0, ANSI_CHARSET, OUT_DEFAULT_PRECIS,
          CLIP_DEFAULT_PRECIS, DEFAULT_QUALITY, DEFAULT_PITCH, LINKFONTNAME);
        if LinkFont <> 0 then
          SendMessage(hLinkStc, WM_SETFONT, Integer(LinkFont), Integer(true));
        EventTrack.cbSize := SizeOf(EventTrack);
        EventTrack.dwFlags := TME_LEAVE;
        EventTrack.hwndTrack := hLinkStc;
        EventTrack.dwHoverTime := HOVER_DEFAULT;
        TrackMouseEvent(EventTrack);
      end;
  else
    Result := CallWindowProc(OldStcWndProc, hLinkStc, uMsg, wParam, lParam);
  end;
end;

Das funktioniert auch, nur bekomme ich keine WM_MOUSEMOVE Nachrichten, wenn ich über das Static fahre mit der Maus. Alle anderen Nachrichten kommen an. Aber warum keine WM_MOUSEMOVE? :wall:

[xaromz]

Hallo,

kommt in Deiner MessageProc kein MouseMove an? Wie kann dann das Ganze funktionieren, wie Du sagst?

Gruß
xaromz

[Luckie]

Das SubClassen funktioniert. Wenn ich die Maus über das Formular bewege, bekomme ich die Nachricht 132, aber keine WM_MOUSEMOVE. Und wenn ich die Nachricht 132 abfangen, wird der Text kurz unterstrichen und ist dann wieder weg.

[xaromz]

Hallo,

kannst Du kurz ein Beispielprogramm posten?

Gruß
xaromz

[Luckie]

Moment, ich hänge es an.

[xaromz]

Hallo,

Das Problem war recht einfach (mir hat nur der Hebel gefehlt): Ohne SS_NOTIFY bekommt das STATIC keine Mouse-Messages mit. Jetzt noch eine Abfrage in der MessageProc, ob wie schon im Status Hover sind (sonst flimmerts), und außerdem die alte MessageProc immer aufrufen (schadet ja nicht).

Projekt ist im Anhang.

Gruß
xaromz

[Luckie]

Betsen Dank. An SS_NOTIFY hatte ich nicht mehr gedacht. Wir nähern uns dem Ende. Nur noch ein kleines Problem. Da du ja das Projeekt hast: Ich versuche gerade die Schrift des Labels blau zu bekommen und den Hintergrung grau, wie das Fenster:

Delphi-Quellcode:

    WM_CTLCOLORSTATIC:
      begin
        if lParam = GetDlgItem(hWnd, ID_STC_WEB) then
        begin
          SetTextColor(wParam, RGB(0, 0, 255));
          Brush := GetSysColor(COLOR_BTNFACE);
          SetBkColor(wParam, Brush);
          result := Brush;
          SetProp(hWnd, 'Brush', Brush);
        end
        else
          Result := DefWindowProc(hWnd, uMsg, wParam, lParam);
      end;

Funktioniert, nur wird nicht das ganze Static grau, sondern nur der Teil unter der Schrift.

Ich weiß, neues Thema, neuer Thread, aber xarmox ist gerade dabei. ;)

[xaromz]

Hallo,

die Message WM_CTLCOLORSTATIC erwartet als Rückgabewert einen HBrush. Den musst Du also auch zurückgeben:

Delphi-Quellcode:

        if lParam = GetDlgItem(hWnd, ID_STC_WEB) then
        begin
          SetTextColor(wParam, RGB(0, 0, 255));
          // Text-Hintergrund setzen
          SetBkColor(wParam, GetSysColor(COLOR_BTNFACE));
          // Brush zurückliefern
          Brush := GetSysColorBrush(COLOR_BTNFACE);
          Result := Brush;
          SetProp(hWnd, 'Brush', Brush);
        end

Gruß
xaromz

[Luckie]

Ich habe ihn doch zurückgegeben. :gruebel: Aber dein Code funktioniert. Besten Dank noch mal. Jetzt kan nich endlich das Projekt abschlieesen. Puh, war eine schwere Geburt. ;)

[xaromz]

Hallo,

Zitat:

Zitat von Luckie

Ich habe ihn doch zurückgegeben. :gruebel:

Nö, hast Du nicht :wink: . Du hattest einen Farbwert zurückgeliefert (GetSysColor). Gefragt war GetSysColorBrush.

Aber je schwerer die Geburt, desto...na ja, wie auch immer :stupid: .

Gruß
xaromz

[Luckie]

:wall: :oops:

Na ja jeden falls geht es jetzt. Wenn ich den Code noch etwas aufgeräumt habe, werde ich es hier vorstellen. Fehlt eigentlich nur noch ein kleines Tool, was das Byte-Array für das Icon erstellt.