Button erstellen und Funktion zuweisen....

[CrashMan]

Also eine Button kann man ganz einfach nach dem Prinzip erstellen:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var
  NewButton: TButton;
begin
  // Neuen Button auf Form 1 erzeugen:
  NewButton := TButton.Create(Form1);
  // Eigenschaften des neuen Buttons festlegen:
  with NewButton do
  begin
    Parent := Form1;
    Caption := 'Neuer Button';
    Top := 10;
    Left := 10;
    Height := 30;
    Width := 100;
  end;
end;

Aber wie weise ich dem Button eine Funktion zu?

[Tpercon]

Delphi-Quellcode:

OnClick := mybuttonOnClick

mybuttonOnClick muß ne procedure sein, die die gleichen pArameter hat, wie die ursprüngliche OnClick Methode des Buttons!

[CalganX]

Hi,
du erstellst einfach eine Prozedur vom Typ z.B. TNotifyEvent (siehe Hilfe) und weist die zu.
So zum Beispiel:

Delphi-Quellcode:

procedure TForm1.MeinEigenesOnClick(Sender: TObject);
begin
  ShowMessage('Dynamischer Button wurde geklickt');
end;

{...}
procedure TForm1.FormCreate(Sender: TObject);
var
  NewButton: TButton;
begin
  NewButton := TButton.Create(Form1);
  with NewButton do
  begin
    Parent := Form1;
    Caption := 'Neuer Button';
    Top := 10;
    Left := 10;
    Height := 30;
    Width := 100;
    OnClick := MeinEigenesOnClick;
  end;
end;
{...}

Chris

[neolithos]

Delphi-Quellcode:

  TForm1 = class (TForm)
  private
    procedure NewButttonClick(Sender : TObject);
  ...
  end;

procedure TForm1.NewButttonClick(Sender : TObject);
begin
  // Mach was
end;

....


NewButton.OnClick := NewButttonClick;

[Ricane]

Wie kriegt man es denn hin, das man auch unterscheiden kann, welches Elemet gedrückt wurde?!

Leider kann man die OnClick Prozedur die dann kommen soll nicht noch mit mehr Attributen füttern, so das man das denn herausfindet...

Die Eigenschaft Sender bringt einen auch nicht besonders weiter...


Ricane

[Alexander]

Was genau meinst du mit Element?
Du kannst dem Button z.B. mit tag eine eindeutige Nummer zu weisen.
Oder meinst du sowas hier:

Delphi-Quellcode:

ShowMEssage(TButton(Sender).Name)

?

[CalganX]

Hi,
doch. In dem du die Eigenschaft "Name" des Buttons festlegst und dann schreibst:

Delphi-Quellcode:

procedure TfrmMain.NewButtonClick(Sender: TObject);
begin
  if (Sender as TButton).Text = 'NewButton' then
    // tu was
  else if (Sender as TButton).Text = 'AndererButton' then
    // tu was anderes
end;

Chris

[Ricane]

Zitat:

Zitat von neolithos

Delphi-Quellcode:

NewButton.OnClick := NewButttonClick;

Kann es sein, das das nicht funktioniert, wenn die eigene Prozedure in einer anderen Unit liegt?! Ich habe meine eigene Prozedur in einer anderen Unit und es will nicht...

Folgender Fehler: [Fehler] Db_ExportMain.pas(1010): Inkompatible Typen: 'Methodenzeiger und reguläre Prozedur'

Hier weise ich die Prozedur zu:

Code:

  btnImportConnection.OnClick := ZweiteVerbindung;

Und das ist die Prozedur!

Code:

Procedure ZweiteVerbindung(Sender: TObject);
Begin

  ShowMessage('Ich liege in einer anderen Unit!');

End;

Natürlich sind die Units gegenseitig in den USES Listen ....


Grüsse,

Ricane

[Stevie]

Die Prozedur muss innerhalb desjenigen Objektes deklariert sein, in dem sich auch des Element befindet, dem du diese Prozedur als Ereignisroutine zuweisen willst.

[Ricane]

Zitat:

Zitat von Stevie

Die Prozedur muss innerhalb desjenigen Objektes deklariert sein, in dem sich auch des Element befindet, dem du diese Prozedur als Ereignisroutine zuweisen willst.

Mit anderen Worten es funzt leider nicht ...

[Stevie]

Jepp, damit hab ich mich auch schon rumgeärgert, weil ich solche "Ereignisroutine-Prozeduren" in eine eigene Unit packen wollte. :evil:
Aber vielleicht gibts ja doch ne Möglichkeit? *fragendnachdelphispezialistenumguck*

[neolithos]

NewButtonClick kann auch in einer anderen Unit liegen, muss aber eine Methode sein.

Delphi-Quellcode:

TCmd = class
  procedure NewButtonClick(Sender : TObjcet);
end;

var fCmd : TCmd;


irgentwo erstellen
fCmd := TCmd.Create;

in FormCreate
btnNew.OnClick := fCmd.NewButtonClick;

[Motzi]

Es funktioniert mit einem kleinen Trick auch mit einer normalen Prozedur, allerdings darf man da dann nicht vergessen, dass Delphi intern ja noch den Self-Pointer mitgibt, eine Methode also immer einen versteckten Parameter mehr hat.

Delphi-Quellcode:

procedure DynamicClickProcedure(Self: TObject; Sender: TObject);
begin
  { Self ist immer nil, muss allerdings als Parameter enthalten sein um die richtige Parameterreihenfolge zu gewährleisten }
  if Sender is TButton then
    ShowMessage('Button ''' + TButton(Sender).Caption + ''' wurde gedrückt');
end;


procedure TForm1.FormCreate(Sender: TObject);
var
  NewButton: TButton;
begin
  NewButton := TButton.Create(Self);
  with NewButton do
  begin
    Parent := Self;
    Caption := 'Neuer Button';
    Top := 10;
    Left := 10;
    Height := 30;
    Width := 100;
    @OnClick := @DynamicClickProcedure;
  end;
end;

@Chakotay: im FormCreate-Event solltest du nie die globale Referenz (in deinem Beispiel "Form1") verwenden, sondern immer nur den Self-Pointer! Das OnCreate-Ereignis wird von der AfterConstruction-Methode aufgerufen. Zu diesem Zeitpunkt ist der Constructor zwar bereits abgearbeitet, allerdings wurde der globalen Variable noch nicht der neue Wert zugewiesen...

Edit: kleinen Fehler korrigiert - thx @ neolithos (nächstes Posting)

[neolithos]

Ich hab das mal getestet.

in Self steht bei nil und Sender der Schalter.

[Rumpi]

Hi,

vieleicht möchte ja jemand mehrere Buttons erstellen
...

Delphi-Quellcode:

procedure DynamicClickProcedure(Self: TButton; Sender: TObject);
begin
  if Assigned( Sender ) and (Sender is TButton) then
    with TButton( Sender ) do
    begin
      ShowMessage( Format( '%d. Button wurde gedrückt', [Tag] ));
      case Tag of
        1:  ;
        2:  ;
        3:  ;
        4:  ;
        5:  ;
        6:  ;
        7:  ;
        8:  ;
        9:  ;
       10:  ;
      end;
    end;
end;


procedure TForm1.FormCreate(Sender: TObject);
const
 cbHeight = 30;
 cbSpace  = 5;  
var
  NewButton: TButton; 
  i : Longint;
begin 
  for i := 1 to 10 do
  begin
    NewButton := TButton.Create(Self);
    with NewButton do 
    begin
      Parent := Self; 
      Caption := 'Neuer Button';
      Top := 10 + ((i-1) * cbHeight ) + ((i-1) * cbSpace); 
      Left := 10;
      Height := cbHeight; 
      Width := 100;
      Tag := i;
      @OnClick := @DynamicClickProcedure;
    end; 
  end;
end;

mfg Rumpi

[Motzi]

Zitat:

Zitat von neolithos

Ich hab das mal getestet.

in Self steht bei nil und Sender der Schalter.

Stimmt.. Self kann ja gar nicht den Wert des Buttons erhalten! :oops: Das kommt davon wenn man sowas nicht testen kann und es aus dem Kopf schreiben muss.. :roll: ;)

Also Sender verwenden und nicht Self...!

[neolithos]

Steht in Self überhaupt mal was trinn!
Bzw.
Zuwas ist Self überhaupt?

[Stevie]

Self muss sein, weil es ja eine Methode ist, die zu einem Klassenobjekt gehört. Aber wieso ist denn dann Self = nil?
Wäre dann nicht das hier sinnvoll?

Delphi-Quellcode:

Self := ASender;

[Motzi]

Ein Methodenzeiger ist eigentlich ein Record, der aus 2 Zeigern besteht, einerseits der Zeiger auf das Objekt und andrerseits der Zeiger auf die Funktion. Der Zeiger auf das Objekt wird benötigt, damit innerhalb der Methode der Self-Pointer verfügbar ist.

Wer weiß wie Delphi Funktions-Parameter übergibt weiß, dass diese in folgender Reihenfolge in den Registern abgelegt werden: EAX, EDX, ECX
Hat die Funktion/Prozedur mehr Parameter werden diese dann ab Stack abgelegt.

Bei einer Methode ist es nun so, dass der Self-Pointer (also der Zeiger auf das Objekt auf das die Methode angwendet werden soll) in EAX übergeben wird, also praktisch den ersten Parameter der Prozedur darstellt. In normalen Methoden ist das nicht ersichtlich, will man nun aber einem Methodenzeiger eine Prozedur zuweisen, so muss man das beachten, damit die Parameter in der richtigen Reihenfolge bleiben.

Wenn man dem Methodenzeiger eine Methode zuweist, zb so:

Delphi-Quellcode:

NewButton.OnClick := Form1.ButtonClick;

Dann werden in dem Methodenzeiger NewButton.OnClick 2 Zeiger gespeichert - die Objekt-Referenz Form1 und der Zeiger auf die Funktion ButtonClick. Wird nun das OnClick-Ereignis ausgelöst, so wird die gespeicherte Objekt-Referenz (Form1) in EAX kopiert, alle anderen Parameter in ihre Register kopiert (oder eben auf dem Stack abgelegt) und dann die Funktion "gecallt".

In meinem Code ändere ich jedoch nur den Teil des Methodenzeigers, der den Zeiger auf die Funktion darstellt - der Teil, der eigentlich die Objekt-Referenz erhalten sollte bleibt unverändert, ist also im Normalfall immer nil...

[neolithos]

:dancer: Man lernt nie aus! :dancer2:

[Stevie]

Also, im Moment geht's mir noch ein bisschen :wiejetzt:
Also darf ich in solchen "selbstgeschriebenen" Ereignisroutinen kein Self verwenden, ja?

[Motzi]

Wenn es eine Methode ist natürlich schon, wenn es eine Prozedur ist nein (es sein denn du manipulierst zusätzlich auch noch die Objekt-Referenz)... :)

[Stevie]

Die Objekt-Referenz manipulieren? So, wie ich oben geschrieben habe(Self := Sender), oder anders?

[Motzi]

Anders... du musst die Objekt-Referenz des Methodenzeigers manipulieren...

[Stevie]

WIE??? :roll:

[neolithos]

Delphi-Quellcode:

procedure DynClick(Self, Sender : TObject);
begin
  if Self <> nil then  // steht immer nil
     ShowMessage('Self: ' + Self.ClassName);
  ShowMessage(TButton(Sender).Caption);
end;

procedure TForm1.FormCreate(Sender: TObject);
asm
//  @Button4.OnClick := @DynClick;
//  so steht self auf Form1
// in eax steht Self
  mov edx, [eax + offset Button4] // Adresse der Instance des Schalters
  mov [edx + $124], eax // DynClick(Self ) := form1
  mov [edx + $120], offset DynClick
end;

Kann ich die $124 und $120 auch noch durch einen Symbolischen Namen ersetzen.

[Stevie]

Urgs, Assembler-Code!!! :gruebel:
Kann eigentlich Sender auch was anderes sein, außer das Objekt selber, vorausgesetzt die Methode wird ganz "normal" durch einen Klick oder ein anderes Ereignis von seitens des Anwenders ausgelöst?

[Motzi]

Dein Code ist ein bisschen unpraktisch, da er absolute Offsets verwendet ($120 / $124)... Delphi kann natürlich die absoluten Offsets der Objekt-Felder berechnen, aber ich bezweifle, dass du mir so einfach sagen kannst an welchem Offset das OnMouseDown-Ereignis liegt...

Ich bevorzuge daher etwas in dieser Richtung:

Delphi-Quellcode:

type
  PMethodPointer = ^TMethodPointer;
  TMethodPointer = packed record
    pMethod: Pointer;
    pObject: TObject;
  end;


procedure ProcFormClick(Self: TObject; Sender: TObject);
begin
  ShowMessage('Procedure');
  TForm(Self).OnClick := TForm1(Self).FormClick;
end;

procedure TForm1.FormClick(Sender: TObject);
begin
  ShowMessage('Method');
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  aMP: TMethodPointer;
begin
  aMP.pMethod := @ProcFormClick;
  aMP.pObject := Self;
  OnClick := TNotifyEvent(aMP);
end;

Ein Methoden-Zeiger hat immer die Größe 8, daher ist der Record MethodPointer zu jedem Methoden-Zeiger kompatibel. Der strenge Compiler lässt eine einfache Zuweisung von TMethodPointer an zB TNotifyEvent nicht zu, daher muss der Record immer zuerst in den entsprechenden Methoden-Zeiger gecastet werden.

[neolithos]

Ok! :)
und notiert.