Konstanten-Fehler

[milkilord]

Hallo iebe Delphiler,
ich wollte mal fragen, ob jemand weiß, warum bei:

Delphi-Quellcode:

Form1.Icon1.Picture.Assign(load_picture('http://www.google.com' + Form1.today[4]));

Den Fehler:

Code:

Konstantenobjekt kann nicht als Var-Parameter weitergegeben werden

Die Funktion:

Delphi-Quellcode:

function load_picture(var url : String) : TGIFImage;
var
  Stream : TMemoryStream;
  GIF : TGIFImage;
begin
  if url <> '' then
    begin
      Stream := TMemoryStream.Create;
      Form1.IdHTTP1.Get(url, Stream);
      Stream.Position := 0;
      GIF := TGIFImage.Create;
      GIF.LoadFromStream(stream);
      Result := GIF;
      GIF.Free;
      Stream.Free;
    end
  else
    begin
      Exit;
    end;
end;

und wie ich den Fehler behebe?

[DeddyH]

Du brauchst eine Variable.

Delphi-Quellcode:

var s: string;
...
s := 'http://www.google.com' + Form1.today[4];
Form1.Icon1.Picture.Assign(load_picture(s));

Alternativ kannst Du das "var" beim Funktionsparameter weglassen, da dieser innerhalb der Funktion sowieso nicht geändert wird.

[edit] Nachtrag: die Funktion sieht sowieso etwas komisch aus. Du weist dem Result das GIF zu und gibst dieses anschließend frei. Das wird fürchterlich knallen. [/edit]

[Neutral General]

Hallo

1) Wenn du eine Procedur mit Var-Parameter hast, kannst du für diesen Parameter nur Variablen übergeben und keine konstanten Werte ('http://www.google.com' ist z.B. ein konstanter Wert).

2) Lösen kannst du DAS Problem indem du das var vor deinem Parameter wegmachst, weil es in diesem Fall eigentlich unnötig ist:

Delphi-Quellcode:

function load_picture(url : String) : TGIFImage;

3) .. Funktionieren wird dein Code trotzdem nicht, weil du das in load_picture erstellte GIF direkt wieder freigibst.

Die Funktion sollte so aussehen:

Delphi-Quellcode:

function load_picture(url : String) : TGIFImage;
var
  Stream : TMemoryStream;
  GIF : TGIFImage;
begin
  if url <> '' then
  begin
    Stream := TMemoryStream.Create;
    try
      Form1.IdHTTP1.Get(url, Stream);
      Stream.Position := 0;
      GIF := TGIFImage.Create;
      GIF.LoadFromStream(stream);
      Result := GIF;   
    finally
      Stream.Free;
    end;
  end;
end;

Du könntest/solltest die procedure vllt. auch als Methode von TForm1 definieren. Dann müsstest du nicht Form1.IdHTTP1.Get schreiben sondern nur IdHTTP1.Get, was dann auch mit jeder Instanz von TForm1 funktioniert und nicht nur mit der Variable Form1.

[himitsu]

Lösung:

Delphi-Quellcode:

function load_picture(const url : String) : TGIFImage;

.

Warum hast du das überhaupt als Var-Parameter (Variable) angelegt?


[add]
Ich würde es eher so absichern, da sonst immernoch potentielle Speicherlecks vorhanden wären.

Delphi-Quellcode:

function load_picture(url : String) : TGIFImage;
var
  Stream : TMemoryStream;
begin
  if url <> '' then
  begin
    Result := TGIFImage.Create;
    try 
      Stream := TMemoryStream.Create;
      try
        Form1.IdHTTP1.Get(url, Stream);
        Stream.Position := 0;
        Result.LoadFromStream(Stream);
      finally
        Stream.Free;
      end;
    except
      Result.Free;
    end;
  end else
    Result := nil;
end;

Wenn man eine Variable wie Form1. benötigt, ist so gut wie sicher, daß da etwas in der Planung falsch gelaufen ist und daß IdHTTP1 entweder mit als Parameter an die Funktion übergeben werden sollte oder daß diese Funktion als Methode in TForm1 hineingehört.

Die Warnung bezüglich des "undefinierten Funktionsergebnisses" sollte man nicht ignorieren.

Und das

Delphi-Quellcode:

Exit

... nja, unnötig, aber was soll's ... ist nur unschön/unnötig, aber wenigstens nicht böse/schlimm.

[milkilord]

Danke für die schnellen Antworten. Hat alles wunderbar funktioniert!

Das ist hier einfach das beste Delphi-Forum.