Problem mit Skalierung eines Bitmap im BitBtn

[Helmi]

Hallo,

ich steh grad auf dem Schlauch.

Ich lade in eine Bitmap-Variable ein Bitmap und möchte dies skaliert in einen BitBtn laden.
Ich hab das Ganze mal in ein Test-Projekt ausgelagert.

Das Ganze versuch ich mit StrechDraw.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  bmp, bmp2: TBitmap;
  i: Integer;
  i_max: Integer;
  i_min: Integer;

begin
  bmp := TBitmap.Create;
  bmp2 := TBitmap.Create;

  try
    bmp.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');

    i_max := Max(bmp.Height, BitBtn1.Height);
    i_min := Min(bmp.Height, BitBtn1.Height);

    i := i_max div i_min;

    BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, BitBtn1.Height, (BitBtn1.Width div i)), bmp2);
    BitBtn1.Glyph.Assign(bmp2);
  finally
    FreeAndNil(bmp);
    FreeAndNil(bmp2);
  end;
end;

Nur mit der oberen Ausführung erhalte ich gar kein Bild im BitBtn.
Ersetz ich bmp2 durch bmp, dann erhalte ich zwar ein Bild im BitBtn, aber in unveränderter Größe.

Delphi-Quellcode:

    BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, BitBtn1.Height, (BitBtn1.Width div i)), bmp);
    BitBtn1.Glyph.Assign(bmp);

Die Berechnung von i dient nur der Skalierung bei gleichbleibendem Größenverhältnis.

Was mach ich falsch? (Nein - nicht ich, Delphi :mrgreen:)

[DeddyH]

Welche Größe hat denn bmp2?

[edit]Vielleicht ist es hiermit einfacher:

Delphi-Quellcode:

procedure StretchGraphic(const src, dest: TGraphic;
  DestWidth, DestHeight: integer);
var
  temp, aCopy: TBitmap;
  faktor: double;
begin
  Assert(Assigned(src) and Assigned(dest));
  if src.Width > DestWidth then
    begin
      faktor := DestWidth / src.Width;
      if (src.Height * faktor) > DestHeight then
        faktor := DestHeight / src.Height;
    end
  else
    begin
      faktor := DestHeight / src.Height;
      if (src.Width * faktor) > DestWidth then
        faktor := DestWidth / src.Width;
    end;
  try
    aCopy := TBitmap.Create;
    try
      aCopy.PixelFormat := pf24Bit;
      aCopy.Assign(src);
      temp := TBitmap.Create;
      try
        temp.Width := round(src.Width * faktor);
        temp.Height := round(src.Height * faktor);
        SetStretchBltMode(temp.Canvas.Handle, HALFTONE);
        StretchBlt(temp.Canvas.Handle, 0, 0, temp.Width, temp.Height,
          aCopy.Canvas.Handle, 0, 0, aCopy.Width, aCopy.Height, SRCCOPY);
        dest.Assign(temp);
      finally
        temp.Free;
      end;
    finally
      aCopy.Free;
    end;
  except
    on E: Exception do
      MessageBox(0, PChar(E.Message), nil, MB_OK or MB_ICONERROR);
  end;
end;

[/edit]

[jfheins]

Zitat:

Zitat von Helmi (Beitrag 1095175)

Was mach ich falsch? (Nein - nicht ich, Delphi :mrgreen:)

Delphi kann nicht hellsehen und tut daher bmp2 erstmal mit einem leeren Bitmap vorbelegen. Da du danch auch nichts mehr reinmalst, bleibt es leer ;)

[Satty67]

Ich werfe dann noch eine Skalierungs-Funktion hinterher. Man sollte sowieso nicht soviele Aufgabe in eine einzelne Funktion packen.

Mit dem Ergebnis Initialisierst Du das Ziel-Bitmap. Kannst auch auf X/Y Parameter (also direkte Übergabe von Width/Height) umschreiben oder einem Rect für StretchDraw.

Delphi-Quellcode:

function ScaleSize(Size : TSize; MaxBorderLength : Integer): TSize;
var
  Ratio : Double;
begin
  Ratio := Size.cx / Size.cy;
  if (Ratio >= 1) {Landscape} then
  begin
    Result.cx := MaxBorderLength;
    Result.cy := Trunc(MaxBorderLength / Ratio);
  end else begin
    Result.cy := MaxBorderLength;
    Result.cx := Trunc(MaxBorderLength * Ratio);
  end;
end;

[himitsu]

Zitat:

Zitat von Helmi (Beitrag 1095175)

Was mach ich falsch? (Nein - nicht ich, Delphi :mrgreen:)

Ja, doch du. :tongue:

Delphi-Quellcode:

BitBtn1.Glyph.Assign(bmp2);
...
FreeAndNil(bmp2);

Du weist dem ButtonGlyph die Referenz zu deinem bmp2 zu und gibst danach dieses Objekt frei, da kann ja nix mehr angzeigt wergen. :zwinker:
> Du kannst ja mal probehalber das

Delphi-Quellcode:

bmp2.Free;

auskommentieren. (bin mal gespannt, ob ich Recht hab :angle2: )

BitBtn1.Glyph.Width und .Height setzen
und dann in BitBtn1.Glyph.Canvas das Bild reinkopieren

[Satty67]

Dann wäre aber die Methode Assign diesmal anders als üblicherweise.

[Helmi]

Zitat:

Zitat von himitsu (Beitrag 1095186)

Delphi-Quellcode:

BitBtn1.Glyph.Assign(bmp2);
...
FreeAndNil(bmp2);

Du weist dem ButtonGlyph die Referenz zu deinem bmp2 zu und gibst danach dieses Objekt frei, da kann ja nix mehr angzeigt wergen. :zwinker:
> Du kannst ja mal probehalber das

Delphi-Quellcode:

bmp2.Free;

auskommentieren. (bin mal gespannt, ob ich Recht hab :angle2: )

Leider (oder doch Gott sei Dank :mrgreen:) hast du nicht recht - das bringt gar nichts.

Inspiriert von meinem Code bin ich durch diesen Link worden.
Nur damit ändert sich die Größe des Bildes nicht.

Zitat:

Zitat von DeddyH (Beitrag 1095177)

Welche Größe hat denn bmp2?

erst mal gar keine :-)
Eine Größenangabe ergab leider auch keine Veränderung, ausser dass ich im BitBtn ein weisses Feld sah.

Zitat:

Zitat von DeddyH (Beitrag 1095177)

[edit]Vielleicht ist es hiermit einfacher:
[/edit]

Sah ganz gut aus - nur wurde das Bild sehr klein dargestellt, obwohl ich die Höhe und Breite des BitBtns angab

[edit]
DeddyH´s Code funktioniert - hatte nur Width und Height verwechselt

[himitsu]

Hmm, ich glaub ich hab da noch eine versteckte Referenzzählung gefunden, welches es intern gibt. :gruebel:

Bin aber dennoch mal gespannt, ob das Weglassen von .Free etwas bringt.

Ansonsten kannst du bmp2 und Glyph mal in einer Datei speichern (SaveToFile) und nachsehn wie die enthaltenen Bilder aussehn.

[ConnorMcLeod]

Zitat:

Zitat von Helmi (Beitrag 1095175)

Schlauch.

Delphi-Quellcode:

    bmp.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');
    BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, BitBtn1.Height, (BitBtn1.Width div i)), bmp2);
    BitBtn1.Glyph.Assign(bmp2);

Merkst Du was?
Du lädst in bmp.
Zeichnest aber bmp2.
HTH W.

[Helmi]

Ich hab jetzt nochmal ein wenig rumgespielt und bin auf folgende Lösung gekommen:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  bmp, bmp2: TBitmap;

begin
  bmp := TBitmap.Create;
  bmp2 := TBitmap.Create;

  try
    bmp.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');

    bmp2.Width := BitBtn1.Width;
    bmp2.Height := BitBtn1.Height;

    bmp2.Canvas.StretchDraw(Rect(0, 0, bmp2.Width, bmp2.Height), bmp);

    BitBtn1.Glyph.Assign(bmp2);
    Image1.Picture.Assign(bmp2);
  finally
    FreeAndNil(bmp);
    FreeAndNil(bmp2);
  end;
end;

[himitsu]

Delphi-Quellcode:

BitBtn1.Glyph.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');
BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, BitBtn1.Width - 10, BitBtn1.Height - 10), BitBtn1.Glyph);
BitBtn1.Glyph.Width := BitBtn1.Width - 10;
BitBtn1.Glyph.Height := BitBtn1.Height - 10;

// oder

X := BitBtn1.Width - 10;
Y := BitBtn1.Height - 10;
BitBtn1.Glyph.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');
BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, X, Y), BitBtn1.Glyph);
BitBtn1.Glyph.Width := X;
BitBtn1.Glyph.Height := Y;

:mrgreen:

[Satty67]

Zitat:

Zitat von Helmi (Beitrag 1095218)

Ich hab jetzt nochmal ein wenig rumgespielt und bin auf folgende Lösung gekommen

Die schönere HALFTONE Umsetzung, die DeddyH ins Spiel gebracht hat, hast Du wieder verworfen?

Ist auch nicht garantiert proportional, ausser die Quellbilder sind in der Richtung festgelegt.

[Helmi]

Zitat:

Zitat von himitsu (Beitrag 1095224)

Delphi-Quellcode:

BitBtn1.Glyph.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');
BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, BitBtn1.Width - 10, BitBtn1.Height - 10), BitBtn1.Glyph);
BitBtn1.Glyph.Width := BitBtn1.Width - 10;
BitBtn1.Glyph.Height := BitBtn1.Height - 10;

// oder

X := BitBtn1.Width - 10;
Y := BitBtn1.Height - 10;
BitBtn1.Glyph.LoadFromFile('E:\MaskLight\Programm\Masken\Achsen_MKS.bmp');
BitBtn1.Glyph.Canvas.StretchDraw(Rect(0, 0, X, Y), BitBtn1.Glyph);
BitBtn1.Glyph.Width := X;
BitBtn1.Glyph.Height := Y;

:mrgreen:

Warum noch das Anpassen von BitBtn1.Glyph.Width /bzw. .Height?
Bringt bei mir nichts - also es verändert sich nichts

[himitsu]

Wenn das Bild verkleinert wurde, dann ist das verkleinerte Bild ja nun kleiner, als das was geladen wurde ... also noch die Größe des Glyph an die Größe des verkleinerten Bildes anpassen. :angle:


Jetzt noch statt des StretchDraw das StretchBlt von DeddyH rein und man hat mit wenig Code ein wunderschönes Bild.
Wenn jetzt die Größe nicht gefällt, dann kann man ja die Berechnung von X und Y entsprechend ändern.

[Helmi]

Zitat:

Zitat von himitsu (Beitrag 1095233)

Jetzt noch statt des StretchDraw das StretchBlt von DeddyH rein und man hat mit wenig Code ein wunderschönes Bild.
Wenn jetzt die Größe nicht gefällt, dann kann man ja die Berechnung von X und Y entsprechend ändern.

Irgendwie bin ich jetzt aber ein wenig frustiert :-) - DeddyH´s Code funktioniert sehr gut - meiner nur bedingt :cry:

[himitsu]

Was ist denn "bedingt"?

StretchDraw kopiert nur ganze Pixel (läßt also beim Verkleinern einfach welche web und beim Vergrößern werden welche mehrfach gezeichnet)
und StretchBlt verrechnet die Pixel miteinander.

Dafür sind Funktionen/Berechnungen wie in StretchDraw dann natürlich schneller, als aufwändigere Varianten, wie StretchBlt. (falls es mal auf Quantität ankommt und nicht auf Qualität)

[Helmi]

Zitat:

Zitat von himitsu (Beitrag 1095238)

Was ist denn "bedingt"?

Ich muss da noch was anpassen :-)

Zitat:

Zitat von himitsu (Beitrag 1095238)

StretchDraw kopiert nur ganze Pixel (läßt also beim Verkleinern einfach welche web und beim Vergrößern werden welche mehrfach gezeichnet)
und StretchBlt verrechnet die Pixel miteinander.

Würd das erklären dass mein Bitmap verkleinert mittels StretchBlt unschärfer ausschaut als mittels StretchDraw?

[ConnorMcLeod]

Ja, es kommt aber auch auf die Auflösung der Datei und die Größe des Glyphs an.

[himitsu]

Und die Art des Bildes.

Bilder mit wenige Struktur, wenig Farben und scharfen Farbgrenzen sehen mit der einen Methode ohne Kantenglättung schonmal besser (schärfer) aus,
wärend deteilreiche Fotos mit Kantenglättung/Pixelverrechnung nicht so verpixelt wirken.

[DeddyH]

OK, OK, ich habe meine Routine noch etwas erweitert (und gleich noch eine potentielle Fehlerquelle eliminiert):

Delphi-Quellcode:

procedure StretchGraphic(const src, dest: TGraphic;
  DestWidth, DestHeight: integer; Smooth: Boolean = true);
var
  temp, aCopy: TBitmap;
  faktor: double;
begin
  Assert(Assigned(src) and Assigned(dest));
  if (src.Width = 0) or (src.Height = 0) then
    raise Exception.CreateFmt('Invalid source dimensions: %d x %d',[src.Width, src.Height]);
  if src.Width > DestWidth then
    begin
      faktor := DestWidth / src.Width;
      if (src.Height * faktor) > DestHeight then
        faktor := DestHeight / src.Height;
    end
  else
    begin
      faktor := DestHeight / src.Height;
      if (src.Width * faktor) > DestWidth then
        faktor := DestWidth / src.Width;
    end;
  try
    aCopy := TBitmap.Create;
    try
      aCopy.PixelFormat := pf24Bit;
      aCopy.Assign(src);
      temp := TBitmap.Create;
      try
        temp.Width := round(src.Width * faktor);
        temp.Height := round(src.Height * faktor);
        if Smooth then
          SetStretchBltMode(temp.Canvas.Handle, HALFTONE);
        StretchBlt(temp.Canvas.Handle, 0, 0, temp.Width, temp.Height,
          aCopy.Canvas.Handle, 0, 0, aCopy.Width, aCopy.Height, SRCCOPY);
        dest.Assign(temp);
      finally
        temp.Free;
      end;
    finally
      aCopy.Free;
    end;
  except
    on E: Exception do
      MessageBox(0, PChar(E.Message), nil, MB_OK or MB_ICONERROR);
  end;
end;

[Helmi]

Zitat:

Zitat von DeddyH (Beitrag 1095307)

OK, OK, ich habe meine Routine noch etwas erweitert (und gleich noch eine potentielle Fehlerquelle eliminiert):

Hallo DeddyH,

Dank dir für die Erweiterung. Bei Smooth = false schauts sehr gut aus

[DeddyH]

Das freut mich :)

[Helmi]

Eine Frage hätt ich aber noch:

Was genau bewirkt diese Zeile:

Delphi-Quellcode:

SetStretchBltMode(temp.Canvas.Handle, HALFTONE);

?

Wenn ich die Hilfe zu "HALFTONE" verstanden habe, so bekommen im Dest-Bitmap die neuen notwendigen Pixel die durchschnittliche Farbe der umliegenden Pixel. Oder hab ich da was missverstanden?

[DeddyH]

Die Pixel der Quelle werden in Pixelblöcke des Ziels kopiert. Dabei entspricht die "durchschnittliche" Farbe des Pixelblocks des Ziels der Farbe des Quellpixels. Das hat zur Folge, dass Übergänge auf dem Ziel weicher aussehen.

[Helmi]

Zitat:

Zitat von DeddyH (Beitrag 1095323)

Die Pixel der Quelle werden in Pixelblöcke des Ziels kopiert. Dabei entspricht die "durchschnittliche" Farbe des Pixelblocks des Ziels der Farbe des Quellpixels. Das hat zur Folge, dass Übergänge auf dem Ziel weicher aussehen.

Ah, ok! - Danke für die Erklärung!

[himitsu]

SetStretchBltMode
und Jupp, hast richtig verstanden ... jedes Pixel bekommt den Durchschnitt der Pixel-Anteile, welche in ihm liegen würden.

[edit]
faule RedBox