Bevel nur an den Ecken

[Der schöne Günther]

Der Titel gewinnt jetzt keinen Preis für professionell klingende Umschreibungen. Aber mehr möchte ich auch nicht: Zwei Zeilen Text, und an den Ecken ein bisschen Umrandung. Das erste Bild zeigt ein TPanel, das zweite, was ich gerne hätte.

Gibt es da etwas? Oder müsste ich wieder irgendwelche Paint-Methoden überschreiben? Oder selbst ein Bild malen und das darunter legen? :(

[Sir Rufo]

Erstell dir ein eigenes Control (die Anforderung ist ja sehr überschaubar)

[stahli]

Wenn die Fläche weiß sein soll dann einfach von Panel ableiten und Paint überschreiben.
Wenn sie transparent sein soll wird es deutlich schwieriger.

[Der schöne Günther]

Selbstverständlich transparent :)

Wenn ich es richtig verstehe, dann wäre das Problem, dass man nicht einfach von bsp. einem Panel ableiten kann und dann noch etwas dazu zeichnet, sondern komplett selber malen muss. Wo setze ich denn da am besten an? Gibt es eine Art "Start here"-Komponente? Oder eine Art abstraktes Panel?

[stahli]

Transparenz ist in der VCL ein besonders Thema. (Da hat man in FMX wohl bessere Möglichkeiten, würde ich sagen.)

Ein paar Stichpunkte dazu:

1) Man kann Controls mit Regionen "ausstanzen".
Die haben dann Löcher oder Aussparungen und existieren dort nicht.
Man kann also dort nicht zeichnen, etwas darauf setzen oder Mausereignisse behandeln.

2) Man kann Controls nicht "transparent" füllen.
Man kann die Hintergrundfarbe übernehmen, so dass das Control transparent aussieht, aber nicht transparent ist.
Liegt ein Panel aber z.B. halb über einem Button und halb über einem Label ist eine Transparenz nahezu nicht möglich.
Man könnte höchstens einen "Screenshot vom Hintergrund" machen das Bitmap übernehmen und seinen eigenen Kram dazu malen.

3) Label like
Diese Komponenten zeichnen sich auf einen fremden Canvas (stimmt das noch?) insofern ist damit am ehesten eine transparente Darstellung möglich, weil man einfach nur die Texte und Linien zeichnet.

(Hmm, beim letzten Punkt bin ich jetzt gar nicht mehr so sicher (und habe gerade kein Delphi verfügbar) ...)

[BUG]

Das könnte mit TPaintBox (oder einem eigenen Abkömmling von TGraphicControl) gehen.

[DeddyH]

TGraphicControl würde ich auch bevorzugen. Kleines Beispiel:

Delphi-Quellcode:

type
  TDings = class(TGraphicControl)
  protected
    procedure Paint; override;
  end;

...

procedure TDings.Paint;
const
  BEVELWIDTH = 20;
begin
  inherited;
  Canvas.Brush.Style := bsClear;
  Canvas.Pen.Width := 2;
  Canvas.MoveTo(0, BEVELWIDTH);
  Canvas.LineTo(0, 0);
  Canvas.LineTo(BEVELWIDTH, 0);
  Canvas.MoveTo(Width - BEVELWIDTH, 0);
  Canvas.LineTo(Width, 0);
  Canvas.LineTo(Width, BEVELWIDTH);
  Canvas.MoveTo(Width, Height - BEVELWIDTH);
  Canvas.LineTo(Width, Height);
  Canvas.LineTo(Width - BEVELWIDTH, Height);
  Canvas.MoveTo(BEVELWIDTH, Height);
  Canvas.LineTo(0, Height);
  Canvas.LineTo(0, Height - BEVELWIDTH);
end;

procedure TFormTest.FormCreate(Sender: TObject);
begin
  FDings := TDings.Create(self);
  FDings.Left := 20;
  FDings.Top := 20;
  FDings.Width := 100;
  FDings.Height := 100;
  FDings.Parent := self;
end;

[Der schöne Günther]

Danke für die Hilfe soweit :thumb:, bei Gelegenheit probiere ich es mal aus. Ohne überhaupt bislang einen Finger gerührt zu haben: Wo müsste ich denn ansetzen, um auf dem Form Designer wieder andere Controls in mein

Delphi-Quellcode:

TDings

packen zu können?

[DeddyH]

Controls hineinzusetzen ist bei TGraphicControl nicht möglich, da es nicht von TWinControl abstammt und somit nicht als Parent fungieren kann. Sollte es aber nur um Beschriftungen gehen, die kann man ja als Properties deklarieren und im Paint einfach mit draufzeichnen.

[edit] Etwa so:

Delphi-Quellcode:

unit uDings;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TDings = class(TGraphicControl)
  private
    FInfoUnten: string;
    FInfoOben: string;
    procedure SetInfoOben(const Value: string);
    procedure SetInfoUnten(const Value: string);
  protected
    procedure Paint; override;
  published
    property InfoOben: string read FInfoOben write SetInfoOben;
    property InfoUnten: string read FInfoUnten write SetInfoUnten;
  end;

  TFormTest = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    FDings: TDings;
  public
    { Public-Deklarationen }
  end;

var
  FormTest: TFormTest;

implementation

{$R *.dfm}

procedure TDings.Paint;
const
  BEVELWIDTH = 20;
var
  R: TRect;
begin
  inherited;
  Canvas.Brush.Style := bsClear;
  Canvas.Pen.Width := 2;
  Canvas.MoveTo(0, BEVELWIDTH);
  Canvas.LineTo(0, 0);
  Canvas.LineTo(BEVELWIDTH, 0);
  Canvas.MoveTo(Width - BEVELWIDTH, 0);
  Canvas.LineTo(Width, 0);
  Canvas.LineTo(Width, BEVELWIDTH);
  Canvas.MoveTo(Width, Height - BEVELWIDTH);
  Canvas.LineTo(Width, Height);
  Canvas.LineTo(Width - BEVELWIDTH, Height);
  Canvas.MoveTo(BEVELWIDTH, Height);
  Canvas.LineTo(0, Height);
  Canvas.LineTo(0, Height - BEVELWIDTH);
  R := Rect(0, 0, Width, Height);
  InflateRect(R, -3, -2);
  DrawText(Canvas.Handle, PChar(FInfoOben), -1, R, DT_SINGLELINE or DT_TOP or DT_LEFT);
  DrawText(Canvas.Handle, PChar(FInfoUnten), -1, R, DT_SINGLELINE or DT_BOTTOM or DT_LEFT);
end;

procedure TFormTest.FormCreate(Sender: TObject);
begin
  FDings := TDings.Create(self);
  FDings.Left := 20;
  FDings.Top := 20;
  FDings.Width := 200;
  FDings.Height := 100;
  FDings.Parent := self;
  FDings.InfoOben := 'Oberer Text';
  FDings.InfoUnten := 'Unterer Text';
end;

procedure TDings.SetInfoOben(const Value: string);
begin
  FInfoOben := Value;
  Invalidate;
end;

procedure TDings.SetInfoUnten(const Value: string);
begin
  FInfoUnten := Value;
  Invalidate;
end;

end.

Das sieht dann so aus (die eklige Hintergrundfarbe des Formulars dient nur dazu, zu zeigen, dass TDings auch wirklich transparent ist.[/edit]