Delphi 7, Int64 und Ini.ReadInteger

[Popov]

Weiß einer ob man bei Delphi 7 bei Ini Int64 Werte über das WriteInteger speichern oder ReadInteger laden kann? Ich hab alles versucht was mir eingefallen ist, aber da kommt nichts raus. Ich weiß, gelegentlich muss man den Funktionen nachhelfen und denen Sagen, dass es sich um Int64 handelt, aber wie gesagt ich hab alles ausprobiert was mir eingefallen ist.

Zur Not speichere ich den Wert als Hex über String, das sollte möglich sein, aber trotzdem...

[jaenicke]

Hast du denn einmal geschaut was WriteInteger macht?

Delphi-Quellcode:

begin
  WriteString(Section, Ident, IntToStr(Value));
end;

Da es aktuell kein WriteInteger gibt, das Int64 kann, auch nicht in Delphi XE6 z.B., kannst du das nur analog selbst einbauen. Du kannst ja eine eigene Ini-Klasse ableiten, die das kann.
Ich glaube auch nicht, dass es noch eine entsprechende Ergänzung für die veralteten INI-Dateien geben wird...

[Popov]

Nun, ich dachte es gibt eine Möglichkeit, nur ich komme nicht drauf. In der Zwischenzeit habe ich das als Lösung gebastelt und es scheint zu funktionieren.

Schreiben:

Delphi-Quellcode:

  WriteIniString(Section, Ident, '$' + IntToHex(i64, 16));
...

Lesen

Delphi-Quellcode:

  s := ReadIniString(Section, Ident, '$' + IntToHex(0, 16));
  Result := StrToInt64(s);

[DeddyH]

Oder mit der erwähnten Ableitung:

Delphi-Quellcode:

type
  TIniFile = class(IniFiles.TIniFile)
  public
    procedure WriteInt64(const Section, Ident: string; Value: int64);
    function ReadInt64(const Section, Ident: string; DefaultValue: int64): int64;
  end;

{ TIniFile }

function TIniFile.ReadInt64(const Section, Ident: string;
  DefaultValue: int64): int64;
var
  HexString: string;
begin
  HexString := ReadString(Section, Ident, '');
  Result := StrToIntDef(HexString, DefaultValue);
end;

procedure TIniFile.WriteInt64(const Section, Ident: string; Value: int64);
var
  HexString: string;
begin
  HexString := '$' + IntToHex(Value, 16);
  WriteString(Section, Ident, HexString);
end;

[Sir Rufo]

Warum eigentlich der Umweg über einen HexString?

Schließlich gibt es eine

Delphi-Quellcode:

Int64

Überladung für IntToStr und zurück geht es mit StrToInt64.

Wie gesagt es ist ja nicht falsch, aber eben ein Umweg ...

[Bernhard Geyer]

Zitat:

Zitat von Sir Rufo (Beitrag 1296317)

Warum eigentlich der Umweg über einen HexString?

Schließlich gibt es eine

Delphi-Quellcode:

Int64

Überladung für IntToStr und zurück geht es mit StrToInt64.

Wie gesagt es ist ja nicht falsch, aber eben ein Umweg ...

Vor allem ist der direkte Weg besser wenn man mal einige Werte von 32-Bit auf 64-Bit Integer umstellt.

[DeddyH]

Wenn das unter Delphi 7 schon geht, ist es natürlich besser, aber ich war diesbezüglich nicht sicher.

[Dalai]

Den Typ Int64 gibt es mindestens schon seit Delphi 5 (und damit auch die Überladungen der relevanten Funktionen).

MfG Dalai

[Popov]

Zitat:

Zitat von Sir Rufo (Beitrag 1296317)

Warum eigentlich der Umweg über einen HexString?

Naja, großer Umwege ist es nicht, vielleicht ein ganz kleiner, wenn überhaupt. Im Grunde ist es fast das Gleiche ob man den Integer in String oder in Hex konvertiert. Natürlich klappt das auch ohne Hex. Ich habs genommen, weil ich bei IntToHex wusste, dass das kein Problem ist.

[dGeek]

Das Thema ist alt, ja. Wenn jemand das ohne Hex-String machen möchte, ich hab es so gemacht:

Delphi-Quellcode:

function IsNumeric(const aString: string; const bAcceptNegativeNumbers: Boolean = True): Boolean;
var
 bRes: Boolean;
begin
 bRes := StrToInt64Def(aString, 0) = StrToInt64Def(aString, 1);

 if bRes and (not bAcceptNegativeNumbers) and (StrToInt64(aString) < 0) then
  bRes := False;

 Result := bRes;
end;

procedure IniWriteInt64(var IniFile: TIniFile; const Section: string; const Ident: string; Value: Int64);
begin
 IniFile.WriteString(Section, Ident, IntToStr(Value));
end;

function IniReadInt64(var IniFile: TIniFile; const Section: string; const Ident: string; Default: Int64): Int64;
var
 sTmp: String;
begin
 sTmp := IniFile.ReadString(Section, Ident, IntToStr(Default));

 if functions.IsNumeric(sTmp, False) then
  Result := StrToInt64(sTmp)
 else
  Result := Default;
end;

Erklärung zu IsNumeric:
wenn man einen Int64-Wert normal mit IniX.WriteInteger() speichert und der Wert größer als Integer (also 2147483647) ist, dann wird ein negativer Wert gespeichert.
IsNumeric prüft, ob der gelesene Wert ein negativer Wert ist. Wenn ja Default zurückgeben.

Das ist meine Lösung ohne Hex :P

Aufruf z.B.:

Delphi-Quellcode:

procedure TJabutMainForm.Button1Click(Sender: TObject);
var
 myIni: TIniFile;
 myInt64: Int64;
begin
 myIni := TIniFile.Create('myIni.ini');

 try
  // Speichern
  myInt64 := 91147483647;
  IniWriteInt64(myIni, 'Section', 'Ident', myInt64);

  // Lesen
  myInt64 := IniReadInt64(myIni, 'Section', 'Ident', 0);
 finally
  myIni.Free;
 end;
end;