TListbox füllen und abfragen

[khh]

Hallo zusammen, ich habe eine Listbox die ich in einer Schleife per :

Listbox1.Items.Add (ZQuery1.FieldByName('gesamtname').AsString); befülle

dieser gesamtname setzt sich aus nachfolgender Query zusammen.

select vorname || ', ' || name as gesamtname from mitarbeiter;

Kann ich da jetzt noch die user_id aus der DB (unsichtbar) hinterlegen und auf diese bei der Auswahl eines Namens in der Listbox zugreifen?

Danke für eure Hilfe

[mkinzler]

Verwende AddObject, dann kannst Du dort die ID hinterlegen

[khh]

ich danke dir

Gruss KHH

[Sir Rufo]

Der richtige Weg geht eigentlich etwas anders.

Aus der Query erstellt man sich ein DatenObject. Dieses DatenObject ab in eine ObjectList. Von der ObjectList füllt man dann die ListBox. Den anzuzeigenden Text nimmt man sich aus der (überschriebenen) Methode

Delphi-Quellcode:

TObject.ToString

Delphi-Quellcode:

procedure FillStrings( AStrings : TStrings; ADataList : TObjectList );
var
  LIdx : Integer;
begin
  AStrings.BeginUpdate;
  try
    AStrings.Clear;
    for LIdx := 0 to ADataList.Count - 1 do
    begin
      AStrings.AddObject( ADataList[LIdx].ToString, ADataList[LIdx] );
    end;
  finally
    AStrings.EndUpdate;
  end;
end;

Über das ausgewählte Item von so einem Listen-Control bekomme ich nun die Referenz, den Referenz-Typ und damit alle anderen zugehörigen Informationen.

Dadurch wird es egal, was für Objekte ich mit dem Listen-Control verknüpfen möchte - eben auch gemischt wie z.B. Personen, Firmen. Über den Referenz-Typ bekomme ich das heraus und kann damit verbundene Aktionen einleiten.

[khh]

alsoo
ich habe mir jetzt ein Objekt mit den entsprechenden Setter und Getter erstellt:
dann die Werte, beispielhaft, zugewiesen
MyMitarbeiter:= TMitarbeiter.create();
MyMitarbeiter.SetName('Meier');

und der Objektlist übergeben:
MyMitarbeiterList.Add(MyMitarbeiter);

wie komme ich jetzt an die einzelnen Werte, um sie in meineListbox zu schreiben?

oder hab ich das Ganze falsch verstanden ?

ich danke euch , gruss kH

[Sir Rufo]

Ob das in FPC schon so implementiert ist kann ich nicht adhoc sagen (müsste ich jetzt nachschauen ... kannst du ja auch machen ;)) in Delphi gibt es die virtuelle Methode TObject.ToString. Diese wird einfach überschrieben.

Delphi-Quellcode:

TPerson = class
private
  FFirstname : string;
  FLastname : string;
public
  function ToString : string; override;
  property Firstname : string read FFirstname write FFirstname;
  property Lastname : string read FLastname write FLastname;
end;

function TPerson.ToString : string;
begin
  Result := FLastname + ', ' + FFirstname;
end;

Das macht man dann für jede Klasse, die man in so ein Listencontrol reinklatschen möchte.

Und nun ganz einfach damit das Control füllen:

Delphi-Quellcode:

procedure FillStrings( AStrings : TStrings; ADataList : TObjectList );
var
  LIdx : Integer;
begin
  AStrings.BeginUpdate;
  try
    AStrings.Clear;
    for LIdx := 0 to ADataList.Count - 1 do
    begin
      AStrings.AddObject( 
        ADataList[LIdx].ToString, // da wird das jetzt benutzt
        ADataList[LIdx] );
    end;
  finally
    AStrings.EndUpdate;
  end;
end;

Die Methode

Delphi-Quellcode:

ToString

ist eben für so eine String-Repräsentation von einer Instanz vorgesehen um diese z.B. in so einem einfachen List-Control (ListBox, ComboBox, etc.) anzuzeigen.

[khh]

ich danke dir

[khh]

ähm, ich kapiere immer noch nicht ganz :-(

in deinem Beispiel existiert die function "ToString" in der Klasse TPerson.
Beim Füllen des Controlls benutzt du diese Funktion aus der ObjectListe.
Steh ich jetzt soo aufm Schlauch ?

Gruss KH

[mkinzler]

Für solche Zwecke wurde diese Methode in TObject eingeführt, standardmässig wird nur der Klassennamen ausgegeben. Wenn Du aber Deine Klassen so anpasst, dass hier was sinnvolles zurückgegeben wird, kannst du das für Deine Zwecke verwenden.

[khh]

ok, ich danke dir

[Sir Rufo]

Hmmm, mein Link zur Doku sagt genau das ...

Und es wird nicht die

Delphi-Quellcode:

ToString

Methode der

Delphi-Quellcode:

TObjectList

aufgerufen.

[himitsu]

Ist praktische ein Methode, die an allen Klassen dran hängt.
Kann man also ohne zu casten somit überall aufrufen.

Wie bereits erwähnt, geht es noch besser, wenn sie auch überschrieben wurde und was Sinnvolles zurückgibt, daß möglichst die "Stringrepresentation" des Objektinhaltes ausgibt.

[mkinzler]

Ich würde aber den PK zusätzlich in den Einträgen ablegen.

Delphi-Quellcode:

Listbox1.Items.AddObject (ZQuery1.FieldByName('gesamtname').Value), TObject( ZQuery1.FieldByName('<pk>').Value)) ...

[baumina]

Stimmt, diese Spam-BOTs nerven enorm.

[mkinzler]

Und ich habe nicht mal gemeerkt, dass ich im selben Thread 2 Mal (fast) das Selbe geantwortet habe :oops:

[Popov]

Die Frage ist eigentlich schon beantwortet, aber ich hab sie gerade bemerkt und zufällig ein kleines Beispiel parat. Im Beispiel werden zuerst Daten an TObjectList übergeben. ListBox ist nur für die Anzeige an und gibt sie legiglich virtuell wieder.

Delphi-Quellcode:

uses
  Contnrs, DateUtils;

type
  TMyDate = class
    DateStr: string;
  end;

var
  ol: TObjectList;

procedure TForm1.FormCreate(Sender: TObject);
var
  d: Integer;
  MyDate: TMyDate;
begin
  ol := TObjectList.Create(True);

  for d := Trunc(Now) - 365 to Trunc(Now) do
  begin
    MyDate := TMyDate.Create;
    MyDate.DateStr := FormatDateTime('dd.MM.yyyy, ddd', d);
    ol.Add(MyDate);
  end;

  ListBox1.Style := lbVirtual;
  ListBox1.Count := ol.Count;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  ol.Free;
end;

procedure TForm1.ListBox1Data(Control: TWinControl; Index: Integer;
  var Data: String);
begin
  Data := TMyDate(ol[Index]).DateStr;
end;