CSV-Datei mit Delphi einlesen

[bertillechoula]

Hallo zusammen,

ich bin studentin in Fh Dortmund und ich muss eine Grundwelle Programmieren. Also eine graphische Oberfläche mit Delphi programmieren. Um diese zu machen muss ich die Datensätze einer CSV-Datei mit Delphi einlesen. Das versuche ich schon lange ohne hinzukriegen. Bitte ich bitte um Ihre Hilfe.

Danke schön

[p80286]

Du hast natürlich die Suchfunktion genutzt und die Orientierung bei den vielen Beiträgen verloren.
Darum zum Einstieg:https://www.delphipraxis.net/110025-...v-dateien.html

Ansonsten zeig mal den Code, den Du bisher hast.

Gruß
K-H

[DP-Maintenance]

Dieses Thema wurde am "09. Jan 2019, 05:49 Uhr" von "Luckie" aus dem Forum "Die Delphi-IDE" in das Forum "Algorithmen, Datenstrukturen und Klassendesign" verschoben.

[hoika]

Hallo,
zwei TStringList.
Die erste liest die Datei komplett per LoadFromFile, die zweite benutzt Delimiter, DelimitedText, und StrictDelimiter um je eine Zeile aufzudröseln.

[Schokohase]

Hier ein kleines Beispielprojekt

Delphi-Quellcode:

program CsvReader;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.Classes,
  System.SysUtils;

type
  TEndOfLineOption = (eolCR, eolLF, eolCRLF);

  TCsvReader = class
  private
    FReader: TStreamReader;
    FQuoteChar: Char;
    FDelimiter: Char;
    FEndOfLine: TEndOfLineOption;
    procedure Initialize();
    function GetEndOfStream: Boolean;
  public
    constructor Create(Stream: TStream); overload;
    constructor Create(Stream: TStream; DetectBOM: Boolean); overload;
    constructor Create(Stream: TStream; Encoding: TEncoding; DetectBOM: Boolean = False; BufferSize: Integer = 4096); overload;
    constructor Create(const Filename: string); overload;
    constructor Create(const Filename: string; DetectBOM: Boolean); overload;
    constructor Create(const Filename: string; Encoding: TEncoding; DetectBOM: Boolean = False; BufferSize: Integer = 4096); overload;
    destructor Destroy; override;

    property Delimiter: Char read FDelimiter write FDelimiter;
    property EndOfLine: TEndOfLineOption read FEndOfLine write FEndOfLine;
    property EndOfStream: Boolean read GetEndOfStream;
    property QuoteChar: Char read FQuoteChar write FQuoteChar;

    procedure OwnStream();

    function ReadLine(): TArray<string>;
  end;

  { TCsvReader }

constructor TCsvReader.Create(Stream: TStream; Encoding: TEncoding; DetectBOM: Boolean; BufferSize: Integer);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Stream, Encoding, DetectBOM, BufferSize);
end;

constructor TCsvReader.Create(Stream: TStream; DetectBOM: Boolean);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Stream, DetectBOM);
end;

constructor TCsvReader.Create(Stream: TStream);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Stream);
end;

constructor TCsvReader.Create(const Filename: string; Encoding: TEncoding; DetectBOM: Boolean; BufferSize: Integer);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Filename, Encoding, DetectBOM, BufferSize);
end;

constructor TCsvReader.Create(const Filename: string; DetectBOM: Boolean);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Filename, DetectBOM);
end;

constructor TCsvReader.Create(const Filename: string);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Filename);
end;

destructor TCsvReader.Destroy;
begin
  FReader.Free();
  inherited;
end;

function TCsvReader.GetEndOfStream: Boolean;
begin
  Result := FReader.EndOfStream;
end;

procedure TCsvReader.Initialize;
begin
  FDelimiter := ',';
  FQuoteChar := '"';
  FEndOfLine := eolCRLF;
end;

procedure TCsvReader.OwnStream;
begin
  FReader.OwnStream();
end;

function TCsvReader.ReadLine: TArray<string>;
var
  str: string;
  c: Char;
  LineDelimiter: string;
  sl: TStringList;
  QuoteCountEven: Boolean;
  EndsWithLineDelimiter: Boolean;
begin
  case EndOfLine of
    eolCR:
      LineDelimiter := #13;
    eolLF:
      LineDelimiter := #10;
    eolCRLF:
      LineDelimiter := #13#10;
  else
    raise Exception.Create('Fehlermeldung');
  end;

  if FReader.EndOfStream then
    raise EInvalidOpException.Create('End of stream');

  str := string.Empty;
  repeat
    c := Char(FReader.Read());
    str := str + c;
    QuoteCountEven := str.CountChar(QuoteChar) mod 2 = 0;
    EndsWithLineDelimiter := str.EndsWith(LineDelimiter);
  until FReader.EndOfStream or (EndsWithLineDelimiter and QuoteCountEven);

  if not QuoteCountEven then
    raise EInvalidOpException.Create('Quote parse error');

  if EndsWithLineDelimiter then
    str := str.Substring(0, str.Length - LineDelimiter.Length);

  sl := TStringList.Create();
  try
    sl.Delimiter := Delimiter;
    sl.StrictDelimiter := True;
    sl.DelimitedText := str;
    Result := sl.ToStringArray();
  finally
    sl.Free();
  end;
end;

procedure Main();
const
  sample = '' + //
    'a,b,c' + sLineBreak + //
    'a,"b",c' + sLineBreak + //
    'a,"b1,b2",c' + sLineBreak + //
    'a,"b1' + sLineBreak + 'b2",c';
var
  s: TStringStream;
  r: TCsvReader;
  l: TArray<string>;
begin
  s := TStringStream.Create(sample);
  try
    r := TCsvReader.Create(s);
    try
      r.Delimiter := ',';
      r.QuoteChar := '"';
      r.EndOfLine := eolCRLF;

      while not r.EndOfStream do
      begin
        l := r.ReadLine();
        WriteLn(string.Join(' | ', l));
      end;

    finally
      r.Free();
    end;
  finally
    s.Free();
  end;
end;

begin
  try
    Main();
  except
    on E: Exception do
      WriteLn(E.ClassName, ': ', E.Message);
  end;
  Readln;

end.

Ausgabe

Code:

a | b | c
a | b | c
a | b1,b2 | c
a | b1
b2 | c

[Neutral General]

Zitat:

Zitat von Schokohase (Beitrag 1422924)

Hier ein kleines Beispielprojekt

Und mit "Beispielprojekt" meinst du eine komplette fertige CSV-Klasse die er einfach abschreiben kann?
Super :roll:

[Schokohase]

Zitat:

Zitat von Neutral General (Beitrag 1422927)

Zitat:

Zitat von Schokohase (Beitrag 1422924)

Hier ein kleines Beispielprojekt

Und mit "Beispielprojekt" meinst du eine komplette fertige CSV-Klasse die er einfach abschreiben kann?
Super :roll:

Wenn sie (nicht er) ganz schlau ist dann per Copy/Paste.

Den Aufreger kann ich jetzt gar nicht verstehen, schließlich wurde auch schon ein Link auf einen anderen fertigen CsvReader gepostet. Aber das ist bestimmt etwas anderes ... oh ja, da muss man den Source downloaden, das ist tatsächlich etwas anderes. Du hast Recht.

[Neutral General]

Zitat:

Zitat von Schokohase (Beitrag 1422928)

Wenn sie (nicht er) ganz schlau ist dann per Copy/Paste.

:thumb: :roll:

Zitat:

Zitat von Schokohase (Beitrag 1422928)

Den Aufreger kann ich jetzt gar nicht verstehen, schließlich wurde auch schon ein Link auf einen anderen fertigen CsvReader gepostet. Aber das ist bestimmt etwas anderes ... oh ja, da muss man den Source downloaden, das ist tatsächlich etwas anderes. Du hast Recht.

Bin dem Link nicht gefolgt, und auch das finde ich nicht unbedingt gut.
Wenn sie nicht weiß wie man eine CSV Datei einlesen kann, dann bringt ihr eine komplett fertige Klasse nichts.
Die wird sie nämlich sehr wahrscheinlich (auch) nicht verstehen.
D.h. entweder ist sie kein Stück weiter oder sie kopiert den Code einfach und im besten Fall hat sie nichts gelernt und kriegt bei der Klausur Probleme.
Im schlechteren Fall wird es auffallen wenn eine Studentin im ersten Semester die offensichtlich noch keine Meisterin der Programmierung ist eine 1a ausprogrammierte CSV-Klasse abliefert - Im Gegensatz zu den meisten anderen Studenten die sich wahrscheinlich ein bisschen Code in einem ButtonClick-Event zusammengeschustert haben der bestenfalls sogar in (verschiedene) Methoden ausgelagert ist.

Sie soll ihren Code bzw. ihre Versuche posten und dann kann man sehen wo man mit der Hilfe ansetzt.

[Luckie]

Bitte lasst doch diese ewige pädagogische Diskussion, wenn jemand (vollständigen) Code postet. Das hat bisher noch nie zu etwas geführt. Helft, wie ihr meint, dass Hilfe angebracht ist.

[p80286]

Ich geb es zu, ich hab' eine Quelle verlinkt, in der man eine recht gute ANSI-Implementierung des CSV-Readers findet. Und ich gebe weiterhin zu, das ich diese Version ausgeweidet habe, um meine eigene Implementierung zu erstellen. Und ich bin Schokohase dankbar, daß er eine moderne UTF8? taugliche Version erstellt und publiziert hat, weil man da unter Umständen auch etwas lernen kann.

Wenn Source sich mit einem richtigen Problem beschäftigt, gehört er publiziert. Wer ernsthaft an solchen Problemen arbeitet, wird sich damit auch auseinander setzen. Das sich dabei manchmal schlechte Angewohnheiten einschleichen (Einzeiler) geschenkt.

Und ich pers. bin immer noch jedem dankbar, der hier seinen Source publziert hat, und auch denen, die ihn kommentiert haben.

Und wenn der/die TE das Problem mit C&P erschlägt, beim nächsten mal wird auch das ihm/ihr nicht weiter helfen, weil dann der Punkt gekommen ist, an dem stupides kopieren nun nicht mehr ausreicht.

Übrigens "falsche" Probleme sind die so beliebten Taschenrechner mit ihren 4 Grundrechenarten. Ob es da die 346te Implementierung gibt oder nicht, das ist so relevant wie ein Sack Reis........

Gruß
K-H

@Hoika
Deine Version beachtet die möglichen Zeilenumbrüche in einem String nicht. Sie ist mit großer Vorsicht zu genießen.

[hoika]

Hallo,

Zitat:

Und ich pers. bin immer noch jedem dankbar, der hier seinen Source publziert hat, und auch denen, die ihn kommentiert haben.

Genau davon lebt dieses Forum!

Zitat:

@Hoika
Deine Version beachtet die möglichen Zeilenumbrüche in einem String nicht. Sie ist mit großer Vorsicht zu genießen.

Ich habe doch die geheime Zutat zu meinem Code gar nicht gepostet ? ;)

Prinzipiell finde ich es gut, dass ein Code-Jünger verstehen soll,
warum der Code funktioniert, nicht nur.

PS:
Ich hatte mal einen Probe-Mitarbeiter mit dem Spruch
"Es klappt jetzt alles, aber ich weiß nicht, wieso".
*verblüfft zurückschau*

[jobo]

wirklich verblüfft?
Gerade ein fachlicher Neuling kann doch gar nicht verstehen, wieso etwas funktioniert. Gelehrt wird häufig ja auch nur das wie, nicht das warum. Stichwort "Blackbox"
Es wird halt einfach eine Vorgehensweise vermittelt, eine Reihe von Klassenfunktionen, .. Ende
Der Rest ist Privatvergnügen, Neugier, Glücksache, ..

Und mal ehrlich, hier geht es auch bei den Nichtneulingen immer wieder darum, dazuzulernen.
Ein nicht mehr neues, wahrscheinlich nicht wirklich häufig praktiziertes, aber sehr gutes Lernverfahren ist Pairprograming. Die Veröffentlichung von Code bietet zumindest im Forum (mit der immanenten Möglichkeit zur Diskussion < dafür ist es da) die Möglichkeit, ähnlich vorzugehen.

Da sich auch hier mal wieder ein Neuling nicht mehr regt, ist die Vermutung naheliegend, dass diese seltsamen Geplänkel eher abschrecken, als zu helfen.

[Luckie]

Zitat:

Da sich auch hier mal wieder ein Neuling nicht mehr regt, ist die Vermutung naheliegend, dass diese seltsamen Geplänkel eher abschrecken, als zu helfen.

Und deswegen ist hier jetzt auch Schluss mit dieser überflüssigen Diskussion.

[Schokohase]

Zitat:

Zitat von Luckie (Beitrag 1423039)

Zitat:

Da sich auch hier mal wieder ein Neuling nicht mehr regt, ist die Vermutung naheliegend, dass diese seltsamen Geplänkel eher abschrecken, als zu helfen.

Und deswegen ist hier jetzt auch Schluss mit dieser überflüssigen Diskussion.

Kannst du diesen Teil nicht einfach in einen anderen Thread auslagern?

Titel: Pädagogische Diskussion zu: CSV-Datei mit Delphi einlesen
(ein alternatives Entsorgen wäre mir allerdings auch recht)