AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

CSV-Datei mit Delphi einlesen

Ein Thema von bertillechoula · begonnen am 8. Jan 2019 · letzter Beitrag vom 10. Jan 2019
Antwort Antwort
Seite 1 von 2  1 2   
bertillechoula

Registriert seit: 8. Jan 2019
1 Beiträge
 
#1

CSV-Datei mit Delphi einlesen

  Alt 8. Jan 2019, 23:14
Hallo zusammen,

ich bin studentin in Fh Dortmund und ich muss eine Grundwelle Programmieren. Also eine graphische Oberfläche mit Delphi programmieren. Um diese zu machen muss ich die Datensätze einer CSV-Datei mit Delphi einlesen. Das versuche ich schon lange ohne hinzukriegen. Bitte ich bitte um Ihre Hilfe.

Danke schön
  Mit Zitat antworten Zitat
Benutzerbild von p80286
p80286

Registriert seit: 28. Apr 2008
Ort: Stolberg (Rhl)
6.204 Beiträge
 
Delphi 7 Personal
 
#2

AW: CSV-Datei mit Delphi einlesen

  Alt 8. Jan 2019, 23:49
Du hast natürlich die Suchfunktion genutzt und die Orientierung bei den vielen Beiträgen verloren.
Darum zum Einstieg:https://www.delphipraxis.net/110025-...v-dateien.html

Ansonsten zeig mal den Code, den Du bisher hast.

Gruß
K-H
Programme gehorchen nicht Deinen Absichten sondern Deinen Anweisungen
R.E.D retired error detector
  Mit Zitat antworten Zitat
9. Jan 2019, 05:49
Dieses Thema wurde am "09. Jan 2019, 05:49 Uhr" von "Luckie" aus dem Forum "Die Delphi-IDE" in das Forum "Algorithmen, Datenstrukturen und Klassendesign" verschoben.
hoika

Registriert seit: 5. Jul 2006
Ort: Magdeburg
6.630 Beiträge
 
Delphi XE4 Professional
 
#4

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 05:57
Hallo,
zwei TStringList.
Die erste liest die Datei komplett per LoadFromFile, die zweite benutzt Delimiter, DelimitedText, und StrictDelimiter um je eine Zeile aufzudröseln.
Heiko

Geändert von hoika ( 9. Jan 2019 um 09:53 Uhr)
  Mit Zitat antworten Zitat
Schokohase

Registriert seit: 17. Apr 2018
569 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#5

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 09:42
Hier ein kleines Beispielprojekt
Delphi-Quellcode:
program CsvReader;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.Classes,
  System.SysUtils;

type
  TEndOfLineOption = (eolCR, eolLF, eolCRLF);

  TCsvReader = class
  private
    FReader: TStreamReader;
    FQuoteChar: Char;
    FDelimiter: Char;
    FEndOfLine: TEndOfLineOption;
    procedure Initialize();
    function GetEndOfStream: Boolean;
  public
    constructor Create(Stream: TStream); overload;
    constructor Create(Stream: TStream; DetectBOM: Boolean); overload;
    constructor Create(Stream: TStream; Encoding: TEncoding; DetectBOM: Boolean = False; BufferSize: Integer = 4096); overload;
    constructor Create(const Filename: string); overload;
    constructor Create(const Filename: string; DetectBOM: Boolean); overload;
    constructor Create(const Filename: string; Encoding: TEncoding; DetectBOM: Boolean = False; BufferSize: Integer = 4096); overload;
    destructor Destroy; override;

    property Delimiter: Char read FDelimiter write FDelimiter;
    property EndOfLine: TEndOfLineOption read FEndOfLine write FEndOfLine;
    property EndOfStream: Boolean read GetEndOfStream;
    property QuoteChar: Char read FQuoteChar write FQuoteChar;

    procedure OwnStream();

    function ReadLine(): TArray<string>;
  end;

  { TCsvReader }

constructor TCsvReader.Create(Stream: TStream; Encoding: TEncoding; DetectBOM: Boolean; BufferSize: Integer);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Stream, Encoding, DetectBOM, BufferSize);
end;

constructor TCsvReader.Create(Stream: TStream; DetectBOM: Boolean);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Stream, DetectBOM);
end;

constructor TCsvReader.Create(Stream: TStream);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Stream);
end;

constructor TCsvReader.Create(const Filename: string; Encoding: TEncoding; DetectBOM: Boolean; BufferSize: Integer);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Filename, Encoding, DetectBOM, BufferSize);
end;

constructor TCsvReader.Create(const Filename: string; DetectBOM: Boolean);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Filename, DetectBOM);
end;

constructor TCsvReader.Create(const Filename: string);
begin
  inherited Create();
  Initialize();
  FReader := TStreamReader.Create(Filename);
end;

destructor TCsvReader.Destroy;
begin
  FReader.Free();
  inherited;
end;

function TCsvReader.GetEndOfStream: Boolean;
begin
  Result := FReader.EndOfStream;
end;

procedure TCsvReader.Initialize;
begin
  FDelimiter := ',';
  FQuoteChar := '"';
  FEndOfLine := eolCRLF;
end;

procedure TCsvReader.OwnStream;
begin
  FReader.OwnStream();
end;

function TCsvReader.ReadLine: TArray<string>;
var
  str: string;
  c: Char;
  LineDelimiter: string;
  sl: TStringList;
  QuoteCountEven: Boolean;
  EndsWithLineDelimiter: Boolean;
begin
  case EndOfLine of
    eolCR:
      LineDelimiter := #13;
    eolLF:
      LineDelimiter := #10;
    eolCRLF:
      LineDelimiter := #13#10;
  else
    raise Exception.Create('Fehlermeldung');
  end;

  if FReader.EndOfStream then
    raise EInvalidOpException.Create('End of stream');

  str := string.Empty;
  repeat
    c := Char(FReader.Read());
    str := str + c;
    QuoteCountEven := str.CountChar(QuoteChar) mod 2 = 0;
    EndsWithLineDelimiter := str.EndsWith(LineDelimiter);
  until FReader.EndOfStream or (EndsWithLineDelimiter and QuoteCountEven);

  if not QuoteCountEven then
    raise EInvalidOpException.Create('Quote parse error');

  if EndsWithLineDelimiter then
    str := str.Substring(0, str.Length - LineDelimiter.Length);

  sl := TStringList.Create();
  try
    sl.Delimiter := Delimiter;
    sl.StrictDelimiter := True;
    sl.DelimitedText := str;
    Result := sl.ToStringArray();
  finally
    sl.Free();
  end;
end;

procedure Main();
const
  sample = '' + //
    'a,b,c' + sLineBreak + //
    'a,"b",c' + sLineBreak + //
    'a,"b1,b2",c' + sLineBreak + //
    'a,"b1' + sLineBreak + 'b2",c';
var
  s: TStringStream;
  r: TCsvReader;
  l: TArray<string>;
begin
  s := TStringStream.Create(sample);
  try
    r := TCsvReader.Create(s);
    try
      r.Delimiter := ',';
      r.QuoteChar := '"';
      r.EndOfLine := eolCRLF;

      while not r.EndOfStream do
      begin
        l := r.ReadLine();
        WriteLn(string.Join(' | ', l));
      end;

    finally
      r.Free();
    end;
  finally
    s.Free();
  end;
end;

begin
  try
    Main();
  except
    on E: Exception do
      WriteLn(E.ClassName, ': ', E.Message);
  end;
  Readln;

end.
Ausgabe
Code:
a | b | c
a | b | c
a | b1,b2 | c
a | b1
b2 | c
  Mit Zitat antworten Zitat
Benutzerbild von Neutral General
Neutral General

Registriert seit: 16. Jan 2004
Ort: Bendorf
4.907 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#6

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 09:48
Hier ein kleines Beispielprojekt
Und mit "Beispielprojekt" meinst du eine komplette fertige CSV-Klasse die er einfach abschreiben kann?
Super
Michael
"Programmers talk about software development on weekends, vacations, and over meals not because they lack imagination,
but because their imagination reveals worlds that others cannot see."
  Mit Zitat antworten Zitat
Schokohase

Registriert seit: 17. Apr 2018
569 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#7

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 09:59
Hier ein kleines Beispielprojekt
Und mit "Beispielprojekt" meinst du eine komplette fertige CSV-Klasse die er einfach abschreiben kann?
Super
Wenn sie (nicht er) ganz schlau ist dann per Copy/Paste.

Den Aufreger kann ich jetzt gar nicht verstehen, schließlich wurde auch schon ein Link auf einen anderen fertigen CsvReader gepostet. Aber das ist bestimmt etwas anderes ... oh ja, da muss man den Source downloaden, das ist tatsächlich etwas anderes. Du hast Recht.
  Mit Zitat antworten Zitat
Benutzerbild von Neutral General
Neutral General

Registriert seit: 16. Jan 2004
Ort: Bendorf
4.907 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#8

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 13:08
Wenn sie (nicht er) ganz schlau ist dann per Copy/Paste.


Den Aufreger kann ich jetzt gar nicht verstehen, schließlich wurde auch schon ein Link auf einen anderen fertigen CsvReader gepostet. Aber das ist bestimmt etwas anderes ... oh ja, da muss man den Source downloaden, das ist tatsächlich etwas anderes. Du hast Recht.
Bin dem Link nicht gefolgt, und auch das finde ich nicht unbedingt gut.
Wenn sie nicht weiß wie man eine CSV Datei einlesen kann, dann bringt ihr eine komplett fertige Klasse nichts.
Die wird sie nämlich sehr wahrscheinlich (auch) nicht verstehen.
D.h. entweder ist sie kein Stück weiter oder sie kopiert den Code einfach und im besten Fall hat sie nichts gelernt und kriegt bei der Klausur Probleme.
Im schlechteren Fall wird es auffallen wenn eine Studentin im ersten Semester die offensichtlich noch keine Meisterin der Programmierung ist eine 1a ausprogrammierte CSV-Klasse abliefert - Im Gegensatz zu den meisten anderen Studenten die sich wahrscheinlich ein bisschen Code in einem ButtonClick-Event zusammengeschustert haben der bestenfalls sogar in (verschiedene) Methoden ausgelagert ist.

Sie soll ihren Code bzw. ihre Versuche posten und dann kann man sehen wo man mit der Hilfe ansetzt.
Michael
"Programmers talk about software development on weekends, vacations, and over meals not because they lack imagination,
but because their imagination reveals worlds that others cannot see."

Geändert von Neutral General ( 9. Jan 2019 um 13:10 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
36.980 Beiträge
 
Delphi 2006 Professional
 
#9

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 13:14
Bitte lasst doch diese ewige pädagogische Diskussion, wenn jemand (vollständigen) Code postet. Das hat bisher noch nie zu etwas geführt. Helft, wie ihr meint, dass Hilfe angebracht ist.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von p80286
p80286

Registriert seit: 28. Apr 2008
Ort: Stolberg (Rhl)
6.204 Beiträge
 
Delphi 7 Personal
 
#10

AW: CSV-Datei mit Delphi einlesen

  Alt 9. Jan 2019, 21:51
Ich geb es zu, ich hab' eine Quelle verlinkt, in der man eine recht gute ANSI-Implementierung des CSV-Readers findet. Und ich gebe weiterhin zu, das ich diese Version ausgeweidet habe, um meine eigene Implementierung zu erstellen. Und ich bin Schokohase dankbar, daß er eine moderne UTF8? taugliche Version erstellt und publiziert hat, weil man da unter Umständen auch etwas lernen kann.

Wenn Source sich mit einem richtigen Problem beschäftigt, gehört er publiziert. Wer ernsthaft an solchen Problemen arbeitet, wird sich damit auch auseinander setzen. Das sich dabei manchmal schlechte Angewohnheiten einschleichen (Einzeiler) geschenkt.

Und ich pers. bin immer noch jedem dankbar, der hier seinen Source publziert hat, und auch denen, die ihn kommentiert haben.

Und wenn der/die TE das Problem mit C&P erschlägt, beim nächsten mal wird auch das ihm/ihr nicht weiter helfen, weil dann der Punkt gekommen ist, an dem stupides kopieren nun nicht mehr ausreicht.

Übrigens "falsche" Probleme sind die so beliebten Taschenrechner mit ihren 4 Grundrechenarten. Ob es da die 346te Implementierung gibt oder nicht, das ist so relevant wie ein Sack Reis........

Gruß
K-H

@Hoika
Deine Version beachtet die möglichen Zeilenumbrüche in einem String nicht. Sie ist mit großer Vorsicht zu genießen.
Programme gehorchen nicht Deinen Absichten sondern Deinen Anweisungen
R.E.D retired error detector
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 02:28 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf