jpeg- fehler #53

[zeina]

Zitat:

Zitat von Klaus01 (Beitrag 1432235)

.. du könntest bei TMemoryStream bleiben.

Delphi-Quellcode:

type
  TPictureTyp = (pw_None, pw_BMP, pw_JPG, pw_PNG);

function PictureTyp_pruefen(const imageStream: TMemoryStream): TPictureTyp;
var
  Buffer : Word;

begin
  imageStream.Read(Buffer,4);
 //High-Byte und Low-Byte im Buffer tauschen
  //(dadurch stimmt die Byte-Anordnung wieder mit der in der Bild-Datei überein)
  Buffer := Swap(Buffer);

  //Prüfung ob BMP, JPG oder PNG
  case Buffer of
    $424D: Result := pw_BMP;
    $FFD8: Result := pw_JPG;
    $8950: Result := pw_PNG;
  else
    Result := pw_None;
  end;
end;

Nur sehe ich in Deinem Code nicht, wie der MemoryStream "lmstImage" gefüllt wird.

Grüße
Klaus

der MemoryStream wird in dieser Zeile gefüllt

Delphi-Quellcode:

 if lGetRecord(lpTblGraph, 1) then
    begin
{$IFDEF TITAN}
      laImage := GetBlob(lpTblGraph);
{$ENDIF} // DEF TITAN
      lmstImage.Clear;
      lmstImage.Write(laImage[0], Length(laImage));
      lmstImage.Position := 0;

es tritt mir eine Fehler auf:
wenn ich (__).loadFromStream ????

Delphi-Quellcode:

procedure TFormFoto.ZeigeFoto(DB: String; ID: TiBtrvID);
var
  lpTblGraph: TpBtrvDBTableData;
  lbmpImage: TBitmap;
  lmstImage: Tmemorystream;
  laImage  : TaByte;
  lgrpImage: TGraphic;
  ljpgImage: TJPEGImage ;
  lpicImage:TPictureTyp ;
    Buffer : Word;

begin
  lbmpImage := nil;
  lmstImage := nil;
  ljpgImage := nil;
  try
    //lbmpImage := TBitmap.Create;
    lmstImage := Tmemorystream.Create;
    ljpgImage := TJPEGImage.Create;

    lpTblGraph := RelData('GR');
    PutSField('GR', 1, DB);
    PutIdField('GR', 2, ID);
    if lGetRecord(lpTblGraph, 1) then
    begin
{$IFDEF TITAN}
      laImage := GetBlob(lpTblGraph);
{$ENDIF} // DEF TITAN
      lmstImage.Clear;
      lmstImage.Write(laImage[0], Length(laImage));
      lmstImage.Position := 0;
      lmstImage.Read(Buffer,4);
      Buffer := Swap(Buffer);
      //lpicImage:= PictureTyp_pruefen(lmstImage);
      case  Buffer of
        $FFD8:
          begin
            ljpgImage.LoadFromStream(lmstImage);
            lbmpImage := TBitmap.Create;
            try
              lbmpImage.Assign(ljpgImage);
              lgrpImage.Free;
              lgrpImage := lbmpImage;
              Image1.picture.Graphic := (lgrpImage);
            finally
              lbmpImage.Free;
             end;
           end;
        $424D:
          begin
           lbmpImage.Transparent := True;
            lbmpImage.LoadFromStream(lmstImage);
            lbmpImage.TransparentColor := lbmpImage.Canvas.Pixels[0,lbmpImage.Height - 1];
            lbmpImage.ReleaseMaskHandle;
            lgrpImage.Free;
            lgrpImage := lbmpImage;
            Image1.picture.Graphic := (lgrpImage);
          end;
          $8950:
          begin
          Showmessage('ÄÄ');
          end;
      end;

      FormFoto.Caption := DB + '-' + IntToStr(ID);
      FotoResize;
    end
    else
    begin
      lgrpImage := nil;
    end;
  finally
   // lbmpImage.Free;
    lmstImage.Free;
    ljpgImage.Free;
  end;

end;

[Klaus01]

Delphi-Quellcode:

type
  TPictureTyp = (pw_None, pw_BMP, pw_JPG, pw_PNG);

function PictureTyp_pruefen(const imageStream: TMemoryStream): TPictureTyp;
var
  Buffer : Word;

begin
  imageStream.Read(Buffer,2);
 //High-Byte und Low-Byte im Buffer tauschen
  //(dadurch stimmt die Byte-Anordnung wieder mit der in der Bild-Datei überein)
  Buffer := Swap(Buffer);

  //Prüfung ob BMP, JPG oder PNG
  case Buffer of
    $424D: Result := pw_BMP;
    $FFD8: Result := pw_JPG;
    $8950: Result := pw_PNG;
  else
    Result := pw_None;
  end;
  imageStream.seek(0,soFromBeginning)  //zurücksetzen des Lesezeigers im stream
end;

[DeddyH]

Zitat:

Delphi-Quellcode:

var
  Buffer : Word;

begin
  imageStream.Read(Buffer,4);

Nur mal aus Interesse: weshalb werden 4 Byte in einen 2 Byte-Datentyp eingelesen?

[Klaus01]

Zitat:

Zitat von DeddyH (Beitrag 1432260)

Nur mal aus Interesse: weshalb werden 4 Byte in einen 2 Byte-Datentyp eingelesen?

ups - muss natürlich 2 sein.
Danke - werde es ausbessern.

Grüße
Klaus

[Delphi.Narium]

Delphi-Quellcode:

   if lGetRecord(lpTblGraph, 1) then
    begin
{$IFDEF TITAN}
      laImage := GetBlob(lpTblGraph);
{$ENDIF} // DEF TITAN
      lmstImage.Clear;
      lmstImage.Write(laImage[0], Length(laImage));
      lmstImage.Position := 0;
      lmstImage.Read(Buffer,2); // <- geändert
      Buffer := Swap(Buffer);
      //lpicImage:= PictureTyp_pruefen(lmstImage);
      case Buffer of
        $FFD8:
          begin
            lmstImage.Position := 0; // <- neu eingefügt.
            ljpgImage.LoadFromStream(lmstImage);

Fehler #53 heißt, dass ein JPeg kein JPeg ist oder das der Inhalt schlicht und einfach defekt ist. Die Prüfung der ersten beiden Byte auf $FFD8 schließt das Auftreten des Fehlers #53 nicht aus, verringert nur die Wahrscheinlichkeit seines Auftretens.

Speichere den MemoryStream bitte mal als Datei und lass Dir diese von 'nem anderen Programm (oder z. B. in 'nem Browser) anzeigen. Funktioniert das oder wird da auch 'ne Fehlermeldung ausgegeben?

Wenn der Fehler bestehen bleibt: Könntest Du bitte mal eine entsprechende Datei hier anhängen? Eventuell kann man da ja was sehen oder der Fehlerursache irgendwie auf den Grund gehen.

[zeina]

Danke an alle ...es Funktioniert:thumb: