Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Object-Pascal / Delphi-Language (https://www.delphipraxis.net/32-object-pascal-delphi-language/)
-   -   Delphi Json-Objekte: Merge (https://www.delphipraxis.net/204227-json-objekte-merge.html)

Der schöne Günther 8. Mai 2020 12:37

Delphi-Version: 10.2 Tokyo

Json-Objekte: Merge
 
Gibt es im Delphi-Standardumfang etwas um zwei Json-Objekte zu vereinigen? Angenommen ich habe zwei Objekte A und B, beim Vereinigen soll das Ergebnis C alle Paare aus A ∪ B enthalten. Bei doppelten IDs soll B bevorzugt werden. Beispiel:

Code:
{
  "id": "ABC 123",
  "numbers": [1,2,3],
  "message": "Hallo Welt"
}
und

Code:
{
  "id": "ABC 123",
  "numbers": [10]
}
soll ergeben:

Code:
{
  "id": "ABC 123",
  "numbers": [10],
  "message": "Hallo Welt"
}
Gibt es da etwas? Wenn nicht, was gibt es im 3rd Party-Bereich?

Moombas 8. Mai 2020 12:44

AW: Json-Objekte: Merge
 
Das könntest du theoretisch selber schreiben aber wie ergeben sich die Paare, wenn nicht aus der gleichen id?

Und müsste numbers nicht in C so aussehen: "numbers": [1,2,3,10], ?

Der schöne Günther 8. Mai 2020 12:51

AW: Json-Objekte: Merge
 
Nein, ich sagte ja: Wenn es "Kollisionen" gibt, dann haben die Werte aus B Vorrang.

"numbers" gibt es (wie "id") in beiden, also wird der Wert aus dem zweiten Objekt für das Ergebnis hergenommen.

Ich sehe grade, was ich mir wünsche scheint schon jemand in der RFC 7396 festgelegt zu haben:
https://tools.ietf.org/html/rfc7396

jobo 9. Mai 2020 15:41

AW: Json-Objekte: Merge
 
Ich weiß nicht, welche Bordmittel für Dich in Betracht kommen und wie exakt die Aufgabe beschrieben ist.

Dieser Code in sqlite
Delphi-Quellcode:
create table jsondata (data json);
insert into jsondata values
      ('{"id": "ABC 123", "numbers": [1,2,3], "message": "Hallo Welt"}'),
      ('{"id": "ABC 123", "numbers": [10]}' );
select json_group_object(key, value) AS jsondatamerged
  from jsondata, json_each(data);
erstellt z.B. eine vollständige Vereingung aller Werte. Ähnlich, ginge es sicher auch, genau Dein Beispiel abzubilden.
Falls das mit SQL ein mögliches Vorgehen ist:
Mir ist nicht ganz klar, ob Dein Beispiel nur ein Ansatz ist oder mehr Elemente(key:value) im Spiel sind, wie dynamisch und wie es dann ablaufen soll.

Uwe Raabe 9. Mai 2020 16:14

AW: Json-Objekte: Merge
 
Ist jetzt nicht so viel Aufwand:
Delphi-Quellcode:
uses
  System.JSON;

function MergeJsonPreferB(A, B: TJSONObject): TJSONObject;
var
  pair: TJSONPair;
begin
  Result := TJSONObject(B.Clone);
  for pair in A do
    if Result.Get(pair.JsonString.Value) = nil then
      Result.AddPair(TJSONPair(pair.Clone));
end;

Der schöne Günther 11. Mai 2020 08:41

AW: Json-Objekte: Merge
 
Danke, aber ich bin jetzt noch den zusätzlichen Schritt nach der RFC gegangen sodass z.B. auch gilt:

Code:
   //   ORIGINAL       PATCH           RESULT
   //   ------------------------------------------
   //   {"a": {         {"a": {         {"a": {
   //    "b": "c",       "b": "x",       "b": "x"
   //    "d": "e"}       "d": null       }
   //   }               }               }
Sieht dann ungefähr so aus:

Delphi-Quellcode:
class function TJSONHelper.MergePatch(
  target: TJsonValue;
  const patch: TJsonValue
): TJsonValue;
var
  pair: TJsonPair;
  pairName: String;
begin
  if(patch is TJsonObject) then
    begin
      if(not (target is TJsonObject)) then
        target := TJsonObject.Create()
      else
        target := target.Clone() as TJsonValue;
      try
        Result := target.Clone() as TJsonValue;
        try
          for pair in (patch as TJsonObject) do
            begin
              pairName := pair.JsonString.Value;
              (result as TJsonObject).RemovePair(pairName).Free() ;

              if(not pair.JsonValue.Null) then
                (result as TJsonObject).AddPair(
                  pairName,
                  MergePatch(
                    (target as TJsonObject).GetValue(pair.JsonString.Value),
                    pair.JsonValue
                  )
                );
            end;
        except
          Result.Destroy(); raise;
        end;
      finally
        target.Destroy();
      end;
    end
  else
    Result := patch.Clone() as TJsonValue;
end;

jobo 12. Mai 2020 05:32

AW: Json-Objekte: Merge
 
Also was man so merge nennt..
Eine Operation die einen identischen (NULL-)Wert, nein Key, löscht, würde ich anders nennen. Aber ich schreibe ja auch keine RFC.
Auch das platte Überschreiben eines Arrays mit einem anderen Wert/Array fühlt sich weder nach merge noch nach patch an.

Du wirst natürlich wissen, was Du brauchst. Wie man es dann nennt, ist wahrscheinlich zweitrangig. Das NULL Verhalten finde ich dennoch grenzwertig. Es ist eine sensible Ecke bei JSON (Libs) und Verarbeitungsalgorithmen (NULL oder key missing).

Der schöne Günther 12. Mai 2020 07:46

AW: Json-Objekte: Merge
 
Ich habe an der Stelle auch erst gestockt, über null oder key/value weglassen kann man sich immer streiten. Für mich ist es genau das richtige.

Beispiel:

Angenommen ich habe irgendwo ein
Delphi-Quellcode:
TStruct = record
   maxItemCount: Nullable<Word>;
   (...)
end;
Beim Initialisieren wird
Delphi-Quellcode:
maxItemCount
mit z.B.
Delphi-Quellcode:
500
belegt. Dann wird irgendein Template/Benutzereinstellungen/sonstwas geladen. Die möchte explizit sagen "Keine Obergrenze". Dann ist sie, in JSON-Form,
Code:
{"maxItemCount": null}
. Ich wandele
Delphi-Quellcode:
TStruct
nach Json um, wende das Template als Patch an und wandele es wieder zurück nach
Delphi-Quellcode:
TStruct
. Die Obergrenze ist nun entfernt,
Delphi-Quellcode:
maxItemCount
ist
Delphi-Quellcode:
nil
.


Alle Zeitangaben in WEZ +1. Es ist jetzt 04:45 Uhr.

Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2020 by Daniel R. Wolf