AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Json-Objekte: Merge

Ein Thema von Der schöne Günther · begonnen am 8. Mai 2020 · letzter Beitrag vom 12. Mai 2020
Antwort Antwort
Der schöne Günther

Registriert seit: 6. Mär 2013
5.324 Beiträge
 
Delphi 10 Seattle Enterprise
 
#1

Json-Objekte: Merge

  Alt 8. Mai 2020, 12:37
Delphi-Version: 10.2 Tokyo
Gibt es im Delphi-Standardumfang etwas um zwei Json-Objekte zu vereinigen? Angenommen ich habe zwei Objekte A und B, beim Vereinigen soll das Ergebnis C alle Paare aus A ∪ B enthalten. Bei doppelten IDs soll B bevorzugt werden. Beispiel:

Code:
{
  "id": "ABC 123",
  "numbers": [1,2,3],
  "message": "Hallo Welt"
}
und

Code:
{
  "id": "ABC 123",
  "numbers": [10]
}
soll ergeben:

Code:
{
  "id": "ABC 123",
  "numbers": [10],
  "message": "Hallo Welt"
}
Gibt es da etwas? Wenn nicht, was gibt es im 3rd Party-Bereich?
  Mit Zitat antworten Zitat
Benutzerbild von Moombas
Moombas

Registriert seit: 22. Mär 2017
Ort: bei Flensburg
431 Beiträge
 
FreePascal / Lazarus
 
#2

AW: Json-Objekte: Merge

  Alt 8. Mai 2020, 12:44
Das könntest du theoretisch selber schreiben aber wie ergeben sich die Paare, wenn nicht aus der gleichen id?

Und müsste numbers nicht in C so aussehen: "numbers": [1,2,3,10], ?
Der Weg ist das Ziel aber man sollte auf dem Weg niemals das Ziel aus den Augen verlieren.

Geändert von Moombas ( 8. Mai 2020 um 12:47 Uhr)
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.324 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: Json-Objekte: Merge

  Alt 8. Mai 2020, 12:51
Nein, ich sagte ja: Wenn es "Kollisionen" gibt, dann haben die Werte aus B Vorrang.

"numbers" gibt es (wie "id") in beiden, also wird der Wert aus dem zweiten Objekt für das Ergebnis hergenommen.

Ich sehe grade, was ich mir wünsche scheint schon jemand in der RFC 7396 festgelegt zu haben:
https://tools.ietf.org/html/rfc7396
  Mit Zitat antworten Zitat
jobo

Registriert seit: 29. Nov 2010
2.867 Beiträge
 
Delphi 2010 Enterprise
 
#4

AW: Json-Objekte: Merge

  Alt 9. Mai 2020, 15:41
Ich weiß nicht, welche Bordmittel für Dich in Betracht kommen und wie exakt die Aufgabe beschrieben ist.

Dieser Code in sqlite
Delphi-Quellcode:
create table jsondata (data json);
insert into jsondata values
      ('{"id": "ABC 123", "numbers": [1,2,3], "message": "Hallo Welt"}'),
      ('{"id": "ABC 123", "numbers": [10]}' );
select json_group_object(key, value) AS jsondatamerged
  from jsondata, json_each(data);
erstellt z.B. eine vollständige Vereingung aller Werte. Ähnlich, ginge es sicher auch, genau Dein Beispiel abzubilden.
Falls das mit SQL ein mögliches Vorgehen ist:
Mir ist nicht ganz klar, ob Dein Beispiel nur ein Ansatz ist oder mehr Elemente(key:value) im Spiel sind, wie dynamisch und wie es dann ablaufen soll.
Gruß, Jo
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
7.851 Beiträge
 
Delphi 10.4 Sydney
 
#5

AW: Json-Objekte: Merge

  Alt 9. Mai 2020, 16:14
Ist jetzt nicht so viel Aufwand:
Delphi-Quellcode:
uses
  System.JSON;

function MergeJsonPreferB(A, B: TJSONObject): TJSONObject;
var
  pair: TJSONPair;
begin
  Result := TJSONObject(B.Clone);
  for pair in A do
    if Result.Get(pair.JsonString.Value) = nil then
      Result.AddPair(TJSONPair(pair.Clone));
end;
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.324 Beiträge
 
Delphi 10 Seattle Enterprise
 
#6

AW: Json-Objekte: Merge

  Alt 11. Mai 2020, 08:41
Danke, aber ich bin jetzt noch den zusätzlichen Schritt nach der RFC gegangen sodass z.B. auch gilt:

Code:
   //   ORIGINAL       PATCH           RESULT
   //   ------------------------------------------
   //   {"a": {         {"a": {         {"a": {
   //    "b": "c",       "b": "x",       "b": "x"
   //    "d": "e"}       "d": null       }
   //   }               }               }
Sieht dann ungefähr so aus:

Delphi-Quellcode:
class function TJSONHelper.MergePatch(
  target: TJsonValue;
  const patch: TJsonValue
): TJsonValue;
var
  pair: TJsonPair;
  pairName: String;
begin
  if(patch is TJsonObject) then
    begin
      if(not (target is TJsonObject)) then
        target := TJsonObject.Create()
      else
        target := target.Clone() as TJsonValue;
      try
        Result := target.Clone() as TJsonValue;
        try
          for pair in (patch as TJsonObject) do
            begin
              pairName := pair.JsonString.Value;
              (result as TJsonObject).RemovePair(pairName).Free() ;

              if(not pair.JsonValue.Null) then
                (result as TJsonObject).AddPair(
                  pairName,
                  MergePatch(
                    (target as TJsonObject).GetValue(pair.JsonString.Value),
                    pair.JsonValue
                  )
                );
            end;
        except
          Result.Destroy(); raise;
        end;
      finally
        target.Destroy();
      end;
    end
  else
    Result := patch.Clone() as TJsonValue;
end;
  Mit Zitat antworten Zitat
jobo

Registriert seit: 29. Nov 2010
2.867 Beiträge
 
Delphi 2010 Enterprise
 
#7

AW: Json-Objekte: Merge

  Alt 12. Mai 2020, 05:32
Also was man so merge nennt..
Eine Operation die einen identischen (NULL-)Wert, nein Key, löscht, würde ich anders nennen. Aber ich schreibe ja auch keine RFC.
Auch das platte Überschreiben eines Arrays mit einem anderen Wert/Array fühlt sich weder nach merge noch nach patch an.

Du wirst natürlich wissen, was Du brauchst. Wie man es dann nennt, ist wahrscheinlich zweitrangig. Das NULL Verhalten finde ich dennoch grenzwertig. Es ist eine sensible Ecke bei JSON (Libs) und Verarbeitungsalgorithmen (NULL oder key missing).
Gruß, Jo
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.324 Beiträge
 
Delphi 10 Seattle Enterprise
 
#8

AW: Json-Objekte: Merge

  Alt 12. Mai 2020, 07:46
Ich habe an der Stelle auch erst gestockt, über null oder key/value weglassen kann man sich immer streiten. Für mich ist es genau das richtige.

Beispiel:

Angenommen ich habe irgendwo ein
Delphi-Quellcode:
TStruct = record
   maxItemCount: Nullable<Word>;
   (...)
end;
Beim Initialisieren wird maxItemCount mit z.B. 500 belegt. Dann wird irgendein Template/Benutzereinstellungen/sonstwas geladen. Die möchte explizit sagen "Keine Obergrenze". Dann ist sie, in JSON-Form,
Code:
{"maxItemCount": null}
. Ich wandele TStruct nach Json um, wende das Template als Patch an und wandele es wieder zurück nach TStruct . Die Obergrenze ist nun entfernt, maxItemCount ist nil .
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 10:43 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2020 by Daniel R. Wolf