Problem mit Rückgabewert bei ShowModal

[BerleFreund]

Hallo zusammen,

ich habe ein kleines Testprogramm für ShowModal geschrieben.
Form1 startet über einen Timer beim Programmstart ein ShowModal.
In Form1 ist nur ein Label welches den Rückgabewert aus ShowModal anzeigen soll.
In Form2 (ShowModal) sind nur die beiden Button "OK" und "Abbrechen". Den beiden
Butten ist beim ModalResult "mrOk" bzw. "mrCancel" zugewiesen. Jeder der beiden
Button beendet Form2.

Egal welchen der beiden Button ich drücke, in Form1 wird immer die gleiche Rückmeldung
ausgegeben.

Hier die beiden Units :

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;
  gestartet : boolean;

implementation

{$R *.dfm}

uses Unit2;

procedure TForm1.FormCreate(Sender: TObject);
begin
  gestartet := false;
  Timer1.Enabled := true;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if gestartet then
    Form1.Timer1.Enabled := false;

  if Form2.ShowModal = mrOK then
    Label1.Caption := 'Hurra ! Es Funktioniert !'
  else
  begin
    Label1.Caption := 'Negative Rückmeldung';
  end;
end;

end.

Delphi-Quellcode:

unit Unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm2 = class(TForm)
    Button1: TButton;
    Button2: TButton;

    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);

  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

uses unit1;

procedure TForm2.FormCreate(Sender: TObject);
begin
  gestartet := true;
end;

procedure TForm2.Button1Click(Sender: TObject);
begin
  Form2.Close;
end;

procedure TForm2.Button2Click(Sender: TObject);
begin
  Form2.Close;
end;

end.

Wo liegt mein Fehler ? Kann mir jemand einen Hinweis geben ?

Vielen Dank schon mal im Voraus.
BerleFreund

[himitsu]

Delphi-Quellcode:

Form.Close;

* ist die Form modal, dann wird ModalResult auf mrCancel gesetzt (und überschreibt somit das ModalResult, was vom Button kam, da dieses vor dem OnClick gesetzt wird)
* bei NonModal wird verzögert entweder Hide oder Free ausgeführt (jenachdem was TCloseAction sagt)


setze in deinen ButtonClick den ModalResult der form, pder mach im code garnichts, sondern weise beim ModalResult der Buttons das Gewünschte zu.

[DeddyH]

Wozu soll die Variable "gestartet" denn gut sein? Übrigens musst Du das modale Formular nicht manuell schließen, die Zuweisung von ModalResult genügt völlig.

[BerleFreund]

Danke DeddyH,

Dein Tip "Formular schließen" nicht nötig sondern ModalResult zuweisen funktioniert.

Ohne die Variable gestartet kommt jede Sekunde eine Fehlermeldung hoch. Sie dient
dazu den Timer nur einmal auszuführen.


Gruß
BerleFreund

[DeddyH]

Du kannst den Timer im OnTimer-Event doch auch ohne die Variable abstellen.

[himitsu]

Zitat:

gestartet

Er lässt die Fenster automatisch erstellen.
Und da wird es wohl vorgekommen sein, dass der Timer schon auslöste, bevor die Form2 erstellt wurde.

Warum wird die Form überhaupt automatisch erstellt, anstatt erst dann, wenn sie benötigt wird?

Delphi-Quellcode:

procedure TForm1.Timer1Timer(Sender: TObject);
var
  F: TForm2;
begin
  Timer1.Enabled := false;
  F := TForm2.Create(nil);
  try
    if F.ShowModal = mrOk then
      ...
  finally
    F.Free;
  end;
end;

Zitat:

Delphi-Quellcode:

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  ...
  Form1.Timer1.Enabled := false;

Du bist bereits in TForm1, dort verwendet man niemals diese globale Variable.
Wenn man unbedingt eine Variable benötigt, dann nimmt man hierfür das Self.

[bcvs]

Und wenn du das alles berücksichtigt, kannst du auch in Unit2 auf

Delphi-Quellcode:

uses unit1;

verzichten. Das ist eine unnötige zirkuläre Unitreferenz. Fällt nur nicht sofort auf, weil sie im Imlementation-Teil steht.