einlesen eines String aus einem TFileStream

[Eisenmann]

Hallo Forenteilnehmer,

ich habe seit langer Zeit mein, in Delphi geschriebenes Programm, mal wieder hervor geholt und versuche es schon eine ganze Weile unter 10.4 Sydney zum laufen zu bringen. Beim Einlesen von selbst geschriebenen Dateien bekomme in bei Strings einen Fehler, den ich einfach nicht finde. Die Werte int64 werden richtig erkannt. Auch die abgespeicherten Zeichenlängen müssten richtig sein, da im Wechsel von Strings und int64 kein Fehler zu erkennen ist. Nur der Inhalt von den Strings wird nicht richtig zurück gegeben.


Das Speichern mache ich mit:

Code:

fS.WriteBuffer(laenge,sizeOf(l));
fS.WriteBuffer(PWideChar(daten)^,laenge);

wobei daten="Test312345Test1235.bge" und laenge = 22 ist.


gelesen wird es mit:

Code:

SetLength(skala.dateiname,d.l); 
fS.ReadBuffer(PwideChar(skala.dateiname)^,d.l);

das Ergebnis in "Liste überwachter Ausdrücke" unter "Wert des Ausdruck kopieren" ist aber
:'Test312345Tspeichern'#0#0


Ich vermute, der Fehler ist bei der Umstellung auf Delphi 2009 passiert. Da gab es eine größere Änderung der Daten in Delphi.
Mein Programm hatte auch mit größere Dateien vorher funktioniert.
Jetzt bin ich in Rente und hätte mein Programm gerne unter dem neuen Delphi weiter gepflegt.

Ein mit der alter Version gespeicherter Wert ist z.B. '畋獮獴楴敬婟楥扴牥楥档ㅟ〰弰〰㔰弲㌲戮敧'#0#0#0#0#0#0#0#0#0#0#0#0#0#0 #0#0#0#0#0#0 statt Kunststile_Zeitbereich_1000_00052_23.bge
mit d.l also Zeichenlänge = 40.

Ich weiß, dass man hieraus keine Fehleranalyse machen kann.
Vielleicht kann mir aber jemand einen Tipp geben, wonach ich suchen soll.
Ich habe versucht mich durch die Datei "https://www.embarcadero.com/images/old/pdf/Delphi-Unicode181213.pdf" aber leider bisher ohne Erfolg.
Der Quellcode war früher immer mit PChar geschrieben. Änderungen mit PAnsiChar und PWideChar brauchten keine bemerkbaren Verbesserung.

Über einen Tipp würde ich mich sehr freuen.

[venice2]

Stream auf 0 gesetzt?

Delphi-Quellcode:

FStream.seek(Pos, soFromBeginning);

Zitat:

Der Quellcode war früher immer mit PChar geschrieben.

Kannst du auch so belassen.
Der Compiler weis was er nehmen muß bei Unicode PWideChar bei Ansi PansiChar.
Kommt drauf an was du übergibst.

Kann aber sein das es nicht das ist was du als Antwort erwartest. :glaskugel:

[Uwe Raabe]

laenge gibt die Anzahl der Zeichen im String an, WriteBuffer und ReadBuffer erwartet aber die Anzahl der Bytes. Ein WideChar hat 2 Bytes. Deswegen kommen nur die ersten 11 Zeichen an.

[venice2]

Zitat:

Zitat von Uwe Raabe (Beitrag 1496964)

laenge gibt die Anzahl der Zeichen im String an, WriteBuffer und ReadBuffer erwartet aber die Anzahl der Bytes. Ein WideChar hat 2 Bytes. Deswegen kommen nur die ersten 11 Zeichen an.

Bei der Einbehaltung der Übergabe von PChar ergäbe sich das Problem erst gar nicht. Oder?

Delphi-Quellcode:

fS.WriteBuffer(laenge,sizeOf(PChar));

??

[DeddyH]

Er will ja zuerst die Stringlänge und dann den String selbst in den Stream schreiben.

Delphi-Quellcode:

fS.WriteBuffer(laenge, SizeOf(laenge));
fS.WriteBuffer(PWideChar(daten)^, laenge * SizeOf(Char));

[venice2]

Zitat:

Zitat von DeddyH (Beitrag 1496966)

Er will ja zuerst die Stringlänge und dann den String selbst in den Stream schreiben.

Delphi-Quellcode:

fS.WriteBuffer(laenge, SizeOf(laenge));
fS.WriteBuffer(PWideChar(daten)^, laenge * SizeOf(Char));

Ok.. Habe dann wohl was nicht korrekt verstanden.

[Eisenmann]

Hallo,
und danke für die sehr sehr schnellen Antworten.
Ich werde da jetzt mal einiges ausprobieren.

[Sequitar]

Kleine Demo (phne pchars)

Delphi-Quellcode:

program savemystringtoastream;

{$APPTYPE CONSOLE}
{$R *.res}

uses classes,
  System.SysUtils;

procedure teststring_tostream;
var
  f: tstream;
  atext, atext2: string;
  len: byte;

begin

  try
    f := tmemorystream.Create;
    f.Position := 0; // optional here
    atext := 'mytest';
    len := length(atext); // 6
    f.write(len, sizeof(len)); // +1
    f.write(atext[1], length(atext) * sizeof(char)); // +2*6

    // init
    f.Position := 0;
    len := 0;
    atext2 := '';
    f.Read(len, sizeof(len)); // get length from stream
    setlength(atext2, len); // allocate new string
    f.Read(atext2[1], len * sizeof(char));
    assert(atext = atext2);
    atext := '';
    atext2 := '';
  finally
    f.free; { TODO -oUser -cConsole Main : Insert code here }

  end;

end;

begin
  teststring_tostream;

end.

Kann u.U. aber für sehr lange strings lange dauern. Daher hatte ich mir hierfür mal einen helper geschrieben, der das mit tbytes und readbuffer sehr zügig löst.

Delphi-Quellcode:

Type
 Tlargefile_reader_base = Class(TInterfacedObject, Ilargefileimporter)
  Private
  Private
    Content: Tbytes;
    Fendianess: Tendianess;
    Fchunksize: Tfilereadchunksize;
  Private
//..
end;
//..
Procedure Tlargefile_reader_base.Loadstream(Stream: Tstream;
  Endianess: Tendianess = Bigendian);
Begin
  Setlength(Content, Stream.Size);
  Stream.Position := 0;
  If Endianess = Bigendian Then
    Stream.ReadBuffer(Content, Stream.Size) // standard little endian
  Else
    Raise Exception.Create('Loading Little-Endian coded files not implemented');
  Fendianess := Endianess;
End;


Procedure Tlargefile_reader_base.Setastext(Atext: String);
Var
  P: Pchar;
  C: PByte;
  Max: Pchar;
Begin
  Setlength(Content, Length(Atext));
  Max := @Atext[Length(Atext)]; // last element
  P := @Atext[1];
  C := @Content[0];
  While P <> Max Do
  Begin
    C^ := Ord(P^);
    Inc(C);
    Inc(P);
    
  End;
  // last element
 
  C^ := Ord(P^);
  // Inc(C);
  // Inc(P);
End;


Function Tlargefile_reader_base.Getastext: String;
Var
  C: PByte;
  P: Pchar;
  Max: PByte;
Begin
  // Result := Utils.Bytestostr(content);
  Max := @Content[High(Content)]; // last element
  Setlength(Result, Length(Content));
  P := @Result[1];
  C := @Content[0];
  // for c in self.content do
  While C <> Max Do
  Begin
    P^ := Char(C^);
    Inc(P);
    Inc(C, Bytesize);
  End;
  // last element
  P^ := Char(C^);
End;

[himitsu]

TStringStream
TStringReader und TStreamWriter
TBytesString + TEncoding
TReader und TWriter mit ObjectBinaryToText und ObjectTextToBinary (PS: das wird auch für die .DFM und .FMX verwendet)

XML
JSON
INI

uvm.

[Eisenmann]

Hallo und Danke an alle, die mir geantwortet haben,
ganz besonderen Dank an Sequitar, erste Test zeigen, dass mein Programm so funktioniert.
Ich mache heute Abend ein "Fass auf".
:dancer: danke :dancer:, das Problem hatte ich schon lange und es scheint jetzt endlich gelöst zu sein.
Grüße aus dem Saarland
der Eisenmann