UTF-8 Drucker Befehle direkt an Drucker senden

[TUX_der_Pinguin]

Hallo,

um Befehle zu einem Barcode-Drucker zu schicken habe ich bisher folgenden Code verwendet, das Problem ist das ich jetzt Text als UTF-8 an den Drucker senden muss, der Code kann jedoch nur AnsiString verarbeiten.

Delphi-Quellcode:

var
  Template: TStringList;
  dwCount: DWORD;
  AnsiData: AnsiString;
  hPrinter: THandle;
  DocInfo: TDocInfo1;  
  dwJob: DWORD;
  dwBytesWritten: DWORD;

begin
  //init
  dwCount := Length(Template.Text);
  AnsiData := AnsiString(Template.Text);

  if OpenPrinter('Printername', hPrinter, nil) then
  begin
    try
      DocInfo.pDocName := 'RAWPrint';
      DocInfo.pOutputFile := nil;
      DocInfo.pDatatype := 'RAW';

      dwJob := StartDocPrinter(hPrinter, 1, @DocInfo);
      if dwJob <> 0 then
      begin
        try

          if StartPagePrinter(hPrinter) then
          begin

            try
              if WritePrinter(hPrinter, PAnsiChar(AnsiData), dwCount, dwBytesWritten) then
              begin
                if dwBytesWritten <> dwCount then
                  raise Exception.Create('Daten konnten nicht an Drucker gesendet werden!');
              end;{if}
            finally
              EndPagePrinter(hPrinter)
            end;{try..finally}

          end;{if}

        finally
          EndDocPrinter(hPrinter);
        end;{try..finally}
      end;{if}

    finally
      ClosePrinter(hPrinter);
    end;{try..finally}
  end
  else
    ShowMessage('Fehler: Barcode-Druck fehlgeschlagen!');

Bei meiner Suche nach einer Lösung bin ich über folgendes Beispiel gestolpert, damit das funktioniert muss der Drucker aber freigegeben werden. Was ich testweise gemacht habe und es funktioniert, das Barcode Label wird korrekt gedruckt.

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
var
  F: TStreamWriter;
  T: TStringList;

begin

  T := TStringList.Create;
  try

    T.LoadFromFile('..\..\Test.txt', TEncoding.UTF8);

    F := TStreamWriter.Create('\\localhost\Printername', False, TEncoding.UTF8);
    try
      F.Write(T.Text);
    finally
      FreeAndNil(F);
    end;

  finally
    FreeAndNil(T);
  end;
end;

Meine Frage ist, gibt es eine Möglichkeit den Text auch ohne die Freigabe direkt über den Namen des Druckers (Druckerspooler) an den Drucker zu schicken?

Oder gibt es noch eine andere Alternative wie ich den Text als UTF-8 an den Drucker gesendet bekomme?

[peterbelow]

Versuch mal sowas wie

Delphi-Quellcode:

if WritePrinter(hPrinter, PAnsiChar(@SomeUtf8String[1]), dwCount, dwBytesWritten) then

anstelle von

Delphi-Quellcode:

if WritePrinter(hPrinter, PAnsiChar(AnsiData), dwCount, dwBytesWritten) then

in deinem ursprünglichen Kode. Du mußt nur sicherstellen dass dwCount die Zahl der Bytes im UTF8-String ist und nicht die Zahl der Zeichen. Und natürlich darf der String nicht leer sein...

[TUX_der_Pinguin]

Zitat:

Zitat von peterbelow (Beitrag 1499139)

Versuch mal sowas wie

Delphi-Quellcode:

if WritePrinter(hPrinter, PAnsiChar(@SomeUtf8String[1]), dwCount, dwBytesWritten) then

anstelle von

Delphi-Quellcode:

if WritePrinter(hPrinter, PAnsiChar(AnsiData), dwCount, dwBytesWritten) then

in deinem ursprünglichen Kode. Du mußt nur sicherstellen dass dwCount die Zahl der Bytes im UTF8-String ist und nicht die Zahl der Zeichen. Und natürlich darf der String nicht leer sein...

Funktioniert leider nicht.

Die Anzahl der Bytes habe ich sowohl mit ByteLength() versucht zu ermitteln also auch mit..

Delphi-Quellcode:

dwCount := TEncoding.UTF8.GetByteCount(Template.Text);

Aber das Fazit war immer, das gar nichts mehr an den Drucker geschickt wurde.

[Olli73]

Mal versucht einen String als UTF8String zu deklarieren? Template.Text ist jedenfalls KEIN UTF-8, sondern Unicode!

[TUX_der_Pinguin]

Zitat:

Zitat von Olli73 (Beitrag 1499149)

Mal versucht einen String als UTF8String zu deklarieren? Template.Text ist jedenfalls KEIN UTF-8, sondern Unicode!

Danke für den Tipp, das ist es gewesen. Irgendwie hatte ich im Kopf weil bei Template.LoadFromFile('', TEncoding.UTF8) angegeben habe, das es sich um UTF-8 handelt, aber ist natürlich alles Unicode intern.

Delphi-Quellcode:

var
  Template: TStringList;
  dwCount: DWORD;
  UTF8Str: UTF8String;
  hPrinter: THandle;
  DocInfo: TDocInfo1;
  dwJob: DWORD;
  dwBytesWritten: DWORD;

begin
  //init
  UTF8Str := UTF8String(Template.Text);
  dwCount := TEncoding.UTF8.GetByteCount(Template.Text);

  if OpenPrinter('Printername', hPrinter, nil) then
  begin
    try
      DocInfo.pDocName := 'RAWPrint';
      DocInfo.pOutputFile := nil;
      DocInfo.pDatatype := 'RAW';

      dwJob := StartDocPrinter(hPrinter, 1, @DocInfo);
      if dwJob <> 0 then
      begin
        try

          if StartPagePrinter(hPrinter) then
          begin

            try
              if WritePrinter(hPrinter, PAnsiChar(@UTF8Str[1]), dwCount, dwBytesWritten) then
              begin
                if dwBytesWritten <> dwCount then
                  raise Exception.Create('Daten konnten nicht an Drucker gesendet werden!');
              end;{if}
            finally
              EndPagePrinter(hPrinter)
            end;{try..finally}

          end;{if}

        finally
          EndDocPrinter(hPrinter);
        end;{try..finally}
      end;{if}

    finally
      ClosePrinter(hPrinter);
    end;{try..finally}
  end
  else
    ShowMessage('Fehler: Barcode-Druck fehlgeschlagen!');

[HolgerX]

Hmm..

In deinem Original Code hättest Du nur zwei Zeile ändern müssen.. ;)

Zitat:

Zitat von TUX_der_Pinguin (Beitrag 1499137)

Delphi-Quellcode:

begin
  //init
  AnsiData := UTF8Encode(Template.Text);   <--------------
  dwCount := Length(AnsiData );            <--------------

  if OpenPrinter('Printername', hPrinter, nil) then
  begin

[TUX_der_Pinguin]

Zitat:

Zitat von HolgerX (Beitrag 1499178)

Hmm..

In deinem Original Code hättest Du nur zwei Zeile ändern müssen.. ;)

Zitat:

Zitat von TUX_der_Pinguin (Beitrag 1499137)

Delphi-Quellcode:

begin
  //init
  AnsiData := UTF8Encode(Template.Text);   <--------------
  dwCount := Length(AnsiData );            <--------------

  if OpenPrinter('Printername', hPrinter, nil) then
  begin

Danke, das hat es noch einfacher gemacht.