AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Delphi UTF-8 Drucker Befehle direkt an Drucker senden

UTF-8 Drucker Befehle direkt an Drucker senden

Ein Thema von TUX_der_Pinguin · begonnen am 15. Dez 2021 · letzter Beitrag vom 16. Dez 2021
Antwort Antwort
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#1

UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 15. Dez 2021, 10:51
Hallo,

um Befehle zu einem Barcode-Drucker zu schicken habe ich bisher folgenden Code verwendet, das Problem ist das ich jetzt Text als UTF-8 an den Drucker senden muss, der Code kann jedoch nur AnsiString verarbeiten.
Delphi-Quellcode:
var
  Template: TStringList;
  dwCount: DWORD;
  AnsiData: AnsiString;
  hPrinter: THandle;
  DocInfo: TDocInfo1;
  dwJob: DWORD;
  dwBytesWritten: DWORD;

begin
  //init
  dwCount := Length(Template.Text);
  AnsiData := AnsiString(Template.Text);

  if OpenPrinter('Printername', hPrinter, nil) then
  begin
    try
      DocInfo.pDocName := 'RAWPrint';
      DocInfo.pOutputFile := nil;
      DocInfo.pDatatype := 'RAW';

      dwJob := StartDocPrinter(hPrinter, 1, @DocInfo);
      if dwJob <> 0 then
      begin
        try

          if StartPagePrinter(hPrinter) then
          begin

            try
              if WritePrinter(hPrinter, PAnsiChar(AnsiData), dwCount, dwBytesWritten) then
              begin
                if dwBytesWritten <> dwCount then
                  raise Exception.Create('Daten konnten nicht an Drucker gesendet werden!');
              end;{if}
            finally
              EndPagePrinter(hPrinter)
            end;{try..finally}

          end;{if}

        finally
          EndDocPrinter(hPrinter);
        end;{try..finally}
      end;{if}

    finally
      ClosePrinter(hPrinter);
    end;{try..finally}
  end
  else
    ShowMessage('Fehler: Barcode-Druck fehlgeschlagen!');

Bei meiner Suche nach einer Lösung bin ich über folgendes Beispiel gestolpert, damit das funktioniert muss der Drucker aber freigegeben werden. Was ich testweise gemacht habe und es funktioniert, das Barcode Label wird korrekt gedruckt.
Delphi-Quellcode:
procedure TForm1.Button2Click(Sender: TObject);
var
  F: TStreamWriter;
  T: TStringList;

begin

  T := TStringList.Create;
  try

    T.LoadFromFile('..\..\Test.txt', TEncoding.UTF8);

    F := TStreamWriter.Create('\\localhost\Printername', False, TEncoding.UTF8);
    try
      F.Write(T.Text);
    finally
      FreeAndNil(F);
    end;

  finally
    FreeAndNil(T);
  end;
end;
Meine Frage ist, gibt es eine Möglichkeit den Text auch ohne die Freigabe direkt über den Namen des Druckers (Druckerspooler) an den Drucker zu schicken?

Oder gibt es noch eine andere Alternative wie ich den Text als UTF-8 an den Drucker gesendet bekomme?
  Mit Zitat antworten Zitat
peterbelow

Registriert seit: 12. Jan 2019
Ort: Hessen
670 Beiträge
 
Delphi 11 Alexandria
 
#2

AW: UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 15. Dez 2021, 11:03
Versuch mal sowas wie

if WritePrinter(hPrinter, PAnsiChar(@SomeUtf8String[1]), dwCount, dwBytesWritten) then anstelle von

if WritePrinter(hPrinter, PAnsiChar(AnsiData), dwCount, dwBytesWritten) then in deinem ursprünglichen Kode. Du mußt nur sicherstellen dass dwCount die Zahl der Bytes im UTF8-String ist und nicht die Zahl der Zeichen. Und natürlich darf der String nicht leer sein...
Peter Below
  Mit Zitat antworten Zitat
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 15. Dez 2021, 12:03
Versuch mal sowas wie

if WritePrinter(hPrinter, PAnsiChar(@SomeUtf8String[1]), dwCount, dwBytesWritten) then anstelle von

if WritePrinter(hPrinter, PAnsiChar(AnsiData), dwCount, dwBytesWritten) then in deinem ursprünglichen Kode. Du mußt nur sicherstellen dass dwCount die Zahl der Bytes im UTF8-String ist und nicht die Zahl der Zeichen. Und natürlich darf der String nicht leer sein...
Funktioniert leider nicht.

Die Anzahl der Bytes habe ich sowohl mit ByteLength() versucht zu ermitteln also auch mit..
dwCount := TEncoding.UTF8.GetByteCount(Template.Text);
Aber das Fazit war immer, das gar nichts mehr an den Drucker geschickt wurde.
  Mit Zitat antworten Zitat
Benutzerbild von Olli73
Olli73

Registriert seit: 25. Apr 2008
Ort: Neunkirchen
647 Beiträge
 
#4

AW: UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 15. Dez 2021, 12:29
Mal versucht einen String als UTF8String zu deklarieren? Template.Text ist jedenfalls KEIN UTF-8, sondern Unicode!
  Mit Zitat antworten Zitat
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 15. Dez 2021, 12:56
Mal versucht einen String als UTF8String zu deklarieren? Template.Text ist jedenfalls KEIN UTF-8, sondern Unicode!
Danke für den Tipp, das ist es gewesen. Irgendwie hatte ich im Kopf weil bei Template.LoadFromFile('', TEncoding.UTF8) angegeben habe, das es sich um UTF-8 handelt, aber ist natürlich alles Unicode intern.

Delphi-Quellcode:
var
  Template: TStringList;
  dwCount: DWORD;
  UTF8Str: UTF8String;
  hPrinter: THandle;
  DocInfo: TDocInfo1;
  dwJob: DWORD;
  dwBytesWritten: DWORD;

begin
  //init
  UTF8Str := UTF8String(Template.Text);
  dwCount := TEncoding.UTF8.GetByteCount(Template.Text);

  if OpenPrinter('Printername', hPrinter, nil) then
  begin
    try
      DocInfo.pDocName := 'RAWPrint';
      DocInfo.pOutputFile := nil;
      DocInfo.pDatatype := 'RAW';

      dwJob := StartDocPrinter(hPrinter, 1, @DocInfo);
      if dwJob <> 0 then
      begin
        try

          if StartPagePrinter(hPrinter) then
          begin

            try
              if WritePrinter(hPrinter, PAnsiChar(@UTF8Str[1]), dwCount, dwBytesWritten) then
              begin
                if dwBytesWritten <> dwCount then
                  raise Exception.Create('Daten konnten nicht an Drucker gesendet werden!');
              end;{if}
            finally
              EndPagePrinter(hPrinter)
            end;{try..finally}

          end;{if}

        finally
          EndDocPrinter(hPrinter);
        end;{try..finally}
      end;{if}

    finally
      ClosePrinter(hPrinter);
    end;{try..finally}
  end
  else
    ShowMessage('Fehler: Barcode-Druck fehlgeschlagen!');
  Mit Zitat antworten Zitat
HolgerX

Registriert seit: 10. Apr 2006
Ort: Leverkusen
961 Beiträge
 
Delphi 6 Professional
 
#6

AW: UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 15. Dez 2021, 17:48
Hmm..

In deinem Original Code hättest Du nur zwei Zeile ändern müssen..

Delphi-Quellcode:

begin
  //init
  AnsiData := UTF8Encode(Template.Text); <--------------
  dwCount := Length(AnsiData ); <--------------

  if OpenPrinter('Printername', hPrinter, nil) then
  begin
(Ja ich Verwende Delphi 6 Pro und will NICHT wechseln!)
  Mit Zitat antworten Zitat
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#7

AW: UTF-8 Drucker Befehle direkt an Drucker senden

  Alt 16. Dez 2021, 08:55
Hmm..

In deinem Original Code hättest Du nur zwei Zeile ändern müssen..

Delphi-Quellcode:

begin
  //init
  AnsiData := UTF8Encode(Template.Text); <--------------
  dwCount := Length(AnsiData ); <--------------

  if OpenPrinter('Printername', hPrinter, nil) then
  begin
Danke, das hat es noch einfacher gemacht.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:36 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz