FreeAndNIL mit Nebenwirkung

[Maekkelrajter]

Eine Routine zur Abfrage von Album-Daten von der Spotify Web API zeigt ein merkwürdiges Verhalten:

Delphi-Quellcode:

Function TSpManager.CCRequest(accesspoint:string; offset: Integer = 0; Limit: Integer = 50):TJSONValue;
  var
       Client: TRestClient;
       Request: TRESTRequest;
       URL: string;
begin
  result:= NIL;
  If not CCAuthenticationValid Then exit;
  URL:= 'https://api.spotify.com' + accesspoint;
  Client:= TRESTClient.Create(URL);
  Request:= TRESTRequest.Create(Client);
  try
    Client.contentType:= 'application/json';
    Client.Accept:= 'application/json';
    Request.AddParameter('Authorization','Bearer ' +  stcf.AccessData.CCAccessToken , pkHTTPHEADER, [poDoNotEncode]);
    Request.AddParameter('offset',offset.ToString,pkGetOrPost, [poDoNotEncode]);
    Request.AddParameter('limit',limit.ToString,pkGetOrPost, [poDoNotEncode]);
    Request.Execute;
    If Request.Response.StatusCode = 200 Then
    begin
      result:= Request.response.JSONValue;  // im Debugger: TJSONObject(result) = (True, $3277D20) (korrekt)
    end;
  finally
    FreeAndNIL(Client);                     // im Debugger:TJSONObject(result) = (True, nil) (Fehler)
  end;
end;

Die Abfrage ist OK und liefert das gewünschte Ergebnis. Aber auf geheimnisvolle Weise zerstört das 'FreeAndNIL' den Rückgabewert und erzeugt bei dessen weiterer Vearbeitung Accessviolations.
Mache ich irgendwas falsch oder ist das womöglich ein Bug? Vielleicht weiß hier jemand mehr.
Als Workaround erzeuge ich Request und Client im 'OnCreate' der TSpManager - Klasse und entsorge sie im OnDestroy; Das funktioniert einwandfrei.

Gruß LP

[Neutral General]

Du kannst auch eine Kopie der Response-Daten zurückgeben statt einer Referenz.
Dann sollte das auch funktionieren

[DeddyH]

Der Request "gehört" dem Client und dem wiederum "gehört" der JSONValue. Gibt man also den Client frei (wieso man FreeAndNil auf lokale Variablen anwendet, wird mir immer ein Rätsel bleiben, aber egal), sind auch die anderen beiden weg. Es bleibt also nur, eine Kopie des JSONValues zu erzeugen und den dann zurückzugeben, wie Neutral General bereits erwähnt hat. Die muss man dann aber auch irgendwann wieder selbst freigeben.

[Maekkelrajter]

Danke für die erhellenden Hinweise!
Ja, da fällt es mir wie Schuppen von den Augen, zumal ich nicht zum erstenmal mit dem Problem zu tun habe, dass Objekt-Variablen eben 'nur' Zeiger sind. :shock:
Ich nehme an, dass im vorliegenden Fall mit 'Kopie' eine sog. 'Deep Copy' gemeint ist. Das ist ja eigentlich ziemlich umständlich, aber es funktioniert:

Delphi-Quellcode:

function DeepCopy(aValue: TObject): TObject;
var
  MarshalObj: TJSONMarshal;
  UnMarshalObj: TJSONUnMarshal;
    JSONValue: TJSONValue;
begin
  Result:= nil;
  MarshalObj := TJSONMarshal.Create;
  UnMarshalObj := TJSONUnMarshal.Create;
  try
    JSONValue := MarshalObj.Marshal(aValue);
    try
      if Assigned(JSONValue) then
         Result:= UnMarshalObj.Unmarshal(JSONValue);
    finally
      JSONValue.Free;
    end;
  finally
     MarshalObj.Free;
     UnMarshalObj.Free;
  end;
end;

Function TSpManager.CCRequest(accesspoint:string; offset: Integer = 0; Limit: Integer = 50):TJSONValue;
    var Client: TRestClient;
        Request: TRESTRequest;
        URL: string;
begin
  result:= NIL;
  URL:= 'https://api.spotify.com'  + accesspoint;
  Client:= TRESTClient.Create(URL);
  Request:= TRESTRequest.Create(Client);
  try
    [...]
     Request.Execute;
     If Request.Response.StatusCode = 200 Then
     begin
       result:= TJSONValue(DeepCopy(TObject(Request.response.JSONValue)));
     end;
  finally
    Client.free;
  end;
end;

Lästig dabei ist allerdings, dass die Kopie explizit freigegeben werden muss, was auch bei der folgenden Alternative nötig ist:

Delphi-Quellcode:

Function TSpManager.CCRequest(accesspoint:string; offset: Integer = 0; Limit: Integer = 50):TJSONValue;
    var Client: TRestClient;
        Request: TRESTRequest;
        URL: string;
begin
  [...]
  try
    [...]
    Request.Execute;
    If Request.Response.StatusCode = 200 Then
    begin
      result := TJSONObject.ParseJSONValue(TEncoding.utf8.GetBytes(Request.response.content), 0)
    end;
  finally
    Client.free;
  end;
end;

Letztlich habe ich das Problem gelöst, indem ich FRequest und FClient als Class Member deklariert habe.
Das funktioniert anscheinend zuverlässig und vermutlich schneller als die o.g. Alternativen

Gruß LP