listbox und inhalt anzeigen textbox oder richtext

[slm]

Hallo leute bin absoluter anfänger,

ich wollte was kleines schreiben kriegs aber nicht hin.

ich will ein formular in dem links ein listbox ist und rechts ein textedit (oder richedit),
in der listbox sollen die dateinamen von txt dateien stehen (zb. IDE.txt oder SCSI.txt) mit
einem klick auf auf den dateinamen soll dann rechts (textedit oder richtext) der inhalt angezeigt werden, wenn möglich formatiert.

mit items.add kann ich zwar in die listbox werte eintragen aber das will ich ja nicht :stupid:
ich willn ordner anlegen in der textdateien sind und daraus soll es dann die dateinamen übernehmen und mitm klick rechts den inhalt ausgeben jetzt hab ich mich wiederholt.

kann mir jemand da helfen bin verzweifelt :gruebel: :gruebel: :wall:

bitte um antwort

mfg slm

[Kidix]

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    Memo1: TMemo;
    procedure FormShow(Sender: TObject);
    procedure ListBox1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

Procedure FindFiles (aPath, aFindMask: String; aWithSub: Boolean; aResult: tStrings);
Var
  FindRec: tSearchRec;
Begin
  // Wenn die Stringliste nil ist oder aPath oder aFind nicht angegeben ist
  // dann raus
  If (aPath = '') or (aFindMask = '') or Not Assigned (aResult) Then
    Exit;

  // Wenn am Ende der Pfadangabe noch kein \ steht, dieses hinzufügen
  If aPath[Length (aPath)] <> '\' Then
    aPath := aPath + '\';

  // Im aktuellen Verzeichnis nach der Datei suchen
  If FindFirst (aPath + aFindMask, faAnyFile, FindRec) = 0 Then
    Repeat
      If (FindRec.Name <> '.') and (FindRec.Name <> '..') Then
        // ...Ergebnis in die Stringlist einfügen
        aResult.Add (aPath + FindRec.Name);
    Until FindNext (FindRec) <> 0;

  FindClose (FindRec);

  // Wenn nicht in Unterverzeichnissen gesucht werden soll dann raus
  If Not aWithSub Then
    Exit;

  // In Unterverzeichnissen weiter suchen
  If FindFirst (aPath + '*.*', faAnyFile, FindRec) = 0 Then
    Repeat
      If (FindRec.Name <> '.') and (FindRec.Name <> '..') Then
        // Feststellen, ob es sich um ein Verzeichnis handelt
        If Boolean (FindRec.Attr and faDirectory) Then
          // Funktion erneut aufrufen, um Verzeichnis zu durchsuchen (Rekursion)
          FindFiles (aPath + FindRec.Name, aFindMask, aWithSub, aResult);
    Until FindNext (FindRec) <> 0;

   FindClose (FindRec);
End;

procedure TForm1.FormShow(Sender: TObject);
begin
FindFiles ('c:\deinordner', '*.txt', false, ListBox1.Items);
end;

procedure TForm1.ListBox1Click(Sender: TObject);
begin
memo1.Lines.LoadFromFile(listbox1.Items[listbox1.itemindex]);
end;

end.

so sollte es gehen!

[slm]

kidix das hast du nicht grad eben geschrieben oder????


:thumb:

danke für die schnelel antwort werds gleich ausprobieren

[Kidix]

ne, das sind fertige codesnippets die du hier z.B. in der CodeLibrary findest!

[slm]

Kidix ich danke dir

:thumb: :thumb: :thumb:

:hello:

es hat geklappt

ich habe stunden gebraucht und nichts hinbekommen :wall:

rumgoogeln und rumgoogeln und und...

[barf00s]

ja klar -

als ob googlen nichts bringen würde

[Thanatos81]

@slm
Falls Geschwindigkeit bei dir essentiell ist, schau dir doch auch mal FindAllFiles an. Könnte unter bestimmten Voraussetzungen schneller sein als der Code von kidix.

OT
@barf00s
Ich glaube zwar auch, dass Google mit den richtigen Stichwörtern etwas zu Tage bringen würde. Aber war dieses "Nachtreten" nötig? Das Thema war doch eigentlich schon abgeschlossen :roll:
/OT

[slm]

sorry leute googeln bringt natürlich was wenn man in die richtige richtung sucht

:gruebel:

das von kidix reicht vorerstmal aus

hab aber da ne andere frage wie kann ich in der listbox nur die dateinamen anzeigen lassen ohne pfad und ohne dateinamenerweiterung

die erweiterung kann ich ja umgehen wenn ich sage es soll *.* alles suchen, dann findet es ja auch dateien ohne erweiterung
aber den pfad zeigt er dann noch an.

wenn ich aPath weglasse geht es natürlich nicht (soweit ich verstanden habe) da dann die datei nicht gefunden werden kann

[Kidix]

Diese Zeile sollte dir helfen:

Delphi-Quellcode:

aResult.Add (aPath + FindRec.Name);

zu

Delphi-Quellcode:

aResult.Add (FindRec.Name);

[marabu]

Vielleicht ist ja auch die Komponente FileListBox brauchbar...

Bei mir in der Palette "Win3.1" zu finden.

Grüße vom marabu