XMLAttribut auslesen

[Luckie]

Ich habe folgendes XML Dokument:

XML-Code:

<importkennungen>
  <Zeitraum jahr="2007">
    <Ziel kennung="11A13">(#BUNG07)\Lieferschein</Ziel>
    <Ziel kennung="11A15">(#BUNG07)\Rechnung</Ziel>
    <Ziel kennung="11A11">(#BUNG07)\Firma2\Lieferschein</Ziel>
  </Zeitraum>
  <Zeitraum jahr="2006">
    <Ziel kennung="11A13">(#BUNG06)\Lieferschein</Ziel>
    <Ziel kennung="11A15">(#BUNG06)\Rechnung</Ziel>
    <Ziel kennung="11A11">(#BUNG06)\Firma2\Lieferschein</Ziel>
  </Zeitraum>
  <Zeitraum jahr="2005">
    <Ziel kennung="11A13">(#BUNG05)\Lieferschein</Ziel>
    <Ziel kennung="11A15">(#BUNG05)\Rechnung</Ziel>
    <Ziel kennung="11A11">(#BUNG05)\Firma2\Lieferschein</Ziel>
  </Zeitraum>
  <Zeitraum jahr="2004">
    <Ziel kennung="11A13">(#BUNG04)\Lieferschein</Ziel>
    <Ziel kennung="11A15">(#BUNG04)\Rechnung</Ziel>
    <Ziel kennung="11A11">(#BUNG04)\Firma2\Lieferschein</Ziel>
  </Zeitraum>
</importkennungen>

Wie komme ich jetzt an die Attribute dran? Ich habe es so versucht ein Attribut auszuwählen:

Delphi-Quellcode:

function TConfigFile.GetIsYearConfigured(const Year: String): Boolean;
var
  DummyNode: IXMLDOMNode;
  Attr: IXMLAttribute;
begin
  result := False;
  DummyNode := FXmlDoc.selectSingleNode('\importkennungen\zeitraum');
  if DummyNode <> nil then
  begin
    Attr.name := 'jahr';
    result := Attr.value <> '';
  end;
end;

Aber da sagt mir, dass Attr.name readonly ist und ich keinen Wert zuweisen könnte. Aber wie kann ich ein Attribut jetzt auswählen und auslesen. Ein Knoten kann ja auch mehrere Attribute haben.

Ach so, un dich müsste dann och durch alle Knoten "Zeitraum" durch itterieren, um zu sehen, ob da das gesuchte Jahr vorkommt.

[Luckie]

So, durch die SubNodes "Zeitraum" kann ich schon mal durch it6terieren:

Delphi-Quellcode:

function TConfigFile.GetIsYearConfigured: Boolean;
var
  ChildNodes: IXMLDOMNodeList;
  SubNode: IXMLDOMNode;
  Attr: IXMLAttribute;
  i: Integer;
  s: String;
begin
  result := False;
  if FYear <> '' then
  begin
    ChildNodes := FXmlDoc.documentElement.selectNodes('Zeitraum');
    for i := 0 to ChildNodes.length - 1 do
    begin
      SubNode := ChildNodes.item[i];

      //s := Attr.value;
      //Writeln(s);
    end;
  end
  else
    raise Exception.Create(rsNoYear);
end;

Nur wie komme ich jetzt an das Attribut "jahr" dran?

[Hawkeye219]

Hallo Luckie,

hilft das?

Gruß Hawkeye

[Luckie]

Das habe ich auch schon gefunden, nur helfen tut es nicht wirklich. Ich habe es jetzt so:

Delphi-Quellcode:

function TConfigFile.GetIsYearConfigured: Boolean;
var
  ChildNodes: IXMLDOMNodeList;
  SubNode: IXMLDOMNode;
  Attr: IXMLDOMAttribute;
  i: Integer;
  s: String;
begin
  result := False;
  if FYear <> '' then
  begin
    ChildNodes := FXmlDoc.documentElement.selectNodes('zeitraum');
    for i := 0 to ChildNodes.length - 1 do
    begin
      SubNode := ChildNodes.item[i];
      s := FxmlDoc.documentElement.getAttribute('jahr');
      ShowMessage(s);
    end;
  end
  else
    raise Exception.Create(rsNoYear);
end;

... aber das funktioniert auch nicht:

Zitat:

Could not convert variant of type (Null) into type (String)

[martin-sun]

Das Attribut selbst wird als Subnode dargestellt. Rankommen kannst du mit folgendem XPath Ausdruck:

Code:

FXmlDoc.selectSingleNode('/importkennungen/Zeitraum/@jahr');

Das @ zeigt, dass es sich um keinen wirklichen Subnode handelt, sondern nur um ein Attribut.

Über das nodeValue oder text attribut (weiß jetzt nicht genau welches) kommst du dann an den Inhalt.

Martin

[Luckie]

Zitat:

Zitat von martin-sun

Das Attribut selbst wird als Subnode dargestellt.

Das muss man ja auch erstmal wissen. :?

Zitat:

Rankommen kannst du mit folgendem XPath Ausdruck:

Code:

FXmlDoc.selectSingleNode('/importkennungen/Zeitraum/@jahr');

Aber so komme ich immer nur an das von dem ersten Element dran:

Delphi-Quellcode:

function TConfigFile.GetIsYearConfigured: Boolean;
var
  ChildNodes: IXMLDOMNodeList;
  SubNode: IXMLDOMNode;
  Attr: IXMLDOMAttribute;
  i: Integer;
  s: String;
begin
  result := False;
  if FYear <> '' then
  begin
    ChildNodes := FXmlDoc.documentElement.selectNodes('zeitraum');
    for i := 0 to ChildNodes.length - 1 do
    begin
      SubNode := ChildNodes.item[i];
      s := FXmlDoc.selectSingleNode('/importkennungen/zeitraum/@jahr').nodeValue;
      ShowMessage(s);
    end;

Ich muss aber durch alle durchitterieren.

[martin-sun]

Bin mir jetzt nicht ganz sicher, aber versuch mal folgendes:

Code:

'/importkennungen/zeitraum[i]/@jahr'

i = 0 - (anzahl zeiträume-1)
ich glaub so müsstest du durchiterieren können (fast genauso wie beim array)

[ste_ett]

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  XMLDocument: TXMLDocument;
  XMLNode: IXMLNode;
begin
  XMLDocument := TXMLDocument.Create(Form1);
  XMLDocument.LoadFromFile('Pfad\zur\Datei\Datei.xml');
  XMLNode := XMLDocument.DocumentElement.ChildNodes.First; // erster "Zeitraum"-Knoten
  if (XMLNode <> nil) then
  begin
    while (XMLNode <> nil) do
    begin
      if (XMLNode.HasAttribute('jahr')) then
        ShowMessage(XMLNode.Attributes['jahr']);

      XMLNode := XMLNode.NextSibling; // zum nächsten Knoten auf der Ebene / nil, wenn es keine Knoten mehr gibt
    end;
  end;

  XMLDocument.Free;
end;

[Luckie]

Danke. Das sieht gut aus. Nur kennt er bei mir nicht ChildNodes.First und HasAttributes. Und das Attribut ansprechen mit XMLNode.Attributes['jahr'] geht auch nicht, da meint er:

Zitat:

[Pascal Error] ConfigCls.pas(68): E2010 Incompatible types: 'Integer' and 'string'

Das klappt also auch nicht.

Verdammt, es kann doch nicht so schwer sein die Attribute von Knoten auszulesen. :wall:

[Luckie]

Zitat:

Zitat von martin-sun

Bin mir jetzt nicht ganz sicher, aber versuch mal folgendes:

Code:

'/importkennungen/zeitraum[i]/@jahr'

i = 0 - (anzahl zeiträume-1)
ich glaub so müsstest du durchiterieren können (fast genauso wie beim array)

Das kann nicht gehen. Woher soll er wissen, dass [i] den Index bezeichnet. Für den Compiler ist das nur eine Zeichenkette, sonst nichts.

[martin-sun]

Sorry. Mein Fehler. Du musst natürlich den Suchausdruck erst noch zusammensetzen.
suchString := '/importkennungen/Zeitraum['+IntToStr(i) +']/@jahr'

ach ja, das erste element hat auch den index 1 (und nicht 0)

[Luckie]

Nein, das kann auch keine Lösung sein. Aber so geht es:

Delphi-Quellcode:

function TConfigFile.GetIsYearConfigured: Boolean;
var
  ChildNodes: IXMLDOMNodeList;
  SubNode: IXMLDOMNode;
  i: Integer;
  s: String;
begin
  result := False;
  if FYear <> '' then
  begin
    ChildNodes := FXmlDoc.documentElement.selectNodes('zeitraum');
    for i := 0 to ChildNodes.length - 1 do
    begin
      SubNode := ChildNodes.item[i];
      s := SubNode.selectSingleNode('@jahr').nodeValue;
      ShowMessage(s);
    end;
  end
  else
    raise Exception.Create(rsNoYear);
end;

;)

[ste_ett]

Zitat:

Zitat von Luckie

Danke. Das sieht gut aus. Nur kennt er bei mir nicht ChildNodes.First und HasAttributes. Und das Attribut ansprechen mit XMLNode.Attributes['jahr'] geht auch nicht, da meint er:

Zitat:

[Pascal Error] ConfigCls.pas(68): E2010 Incompatible types: 'Integer' and 'string'

Das klappt also auch nicht.

Was für ein Klasse ist das FXMLDoc-Objekt?

[Luckie]

Delphi-Quellcode:

FXmlDoc: msDomDocument;

Importierte Typbibliothek ist die Version 3.0, um mit dem IE 5.0 kompatibel zu sein. Muss leider so sein, da unbedibngt sichergestekllt sein muss, dass sie auf dem Zielrechner existiert.

[MathiasSimmack]

Zitat:

Zitat von Luckie

Nein, das kann auch keine Lösung sein. Aber so geht es:

Oder so:

Delphi-Quellcode:

function TConfigFile.GetIsYearConfigured(year: string): boolean;
var
  node   : IXMLNode;
begin
  node   := FXmlDoc.selectSingleNode(
    Format('/importkennungen/Zeitraum[@jahr="%s"]', [year]));
  Result := node <> nil;
end;

:stupid:

[Luckie]

Hmpf. Ich wusste das du mit so einer Streberlösung daher kommen würdest. Bekommst du das auch für die Kennung hin? ;)

[MathiasSimmack]

Ist doch im Prinzip das gleiche. :zwinker: Du musst es nur kombinieren. Der XPath-Ausdruck:

Code:

/importkennungen/Zeitraum[@jahr="2007"]/Ziel[@kennung="11A15"]

würde als Ergebnis den Knoten

XML-Code:

<Ziel kennung="11A15">(#BUNG07)\Rechnung</Ziel>

aus deiner Datei liefern. Anstelle der festen Angaben setzt du eben nur die Platzhalter rein.

[Luckie]

Zitat:

Zitat von MathiasSimmack

Ist doch im Prinzip das gleiche. :zwinker: Du musst es nur kombinieren.

Jupp, ich habe es ja auch schon, wollte dich nur etwas ärgern. ;)

[MathiasSimmack]

Ich sage doch, so schwer ist XML gar nicht. Das kapierst du, auch ohne zum Klo zu rennen. :mrgreen:

[Luckie]

Zitat:

Zitat von MathiasSimmack

Das kapierst du, auch ohne zum Klo zu rennen. :mrgreen:

Du erinnerst mich gerade an etwas, ich muss mal wohin.

[Luckie]

Ich verstehe es nicht. Ich muss irgendwo etwas falsch machen, aber ich sehe nicht wo.

Ich habe folgende XML-Datei:

XML-Code:

<importkennungen>
  
  <DateMap default="Belegdatum">
    <Form name="WEAR">Lieferschein_Datum</Form>
    <Form name="KOAU">Belegdatum</Form>
  </DateMap>
</importkennungen>

Jetzt will ich den Wert von Form auslesen in Abhängigkeit vom Attribut name, wenn dasnicht klapp, weil kein passendes Attribut gefunden wurde wurde, soll das Attribut von [u]DateMap[i] ausgelesen werden.

Der Code dazu sieht so aus:

Delphi-Quellcode:

  s := Format('/importkennungen/DateMap/Form[@name="%s"]', [FormName]);  // FormName = WEAR
  XMLNode := XMLDoc.selectSingleNode(s);
   // Formname gefunden, konfigurierten Wert nehmen
  if Assigned(XMLNode) then
  begin
    result := XMLNode.text;
  end
   // FormName nicht gefunden Default-Wert nehmen
  else
  begin
    XMLNode := XMLDoc.selectSingleNode('/importkennungen/DateMap/@default');
    if Assigned(XMLNode) then
      result := XMLNode.text;
  end;

Aber XMLNode ist immer nil. Der XPath müsste aber stimmen oder habe ich da noch einen Fehler drinne? Ich verstehe es einfach nicht.

Der plöde Parser ist mit einem Umlaut in einem Kommentar nicht klar gekommen. Fiorefox hat es richtig angezeigt, aber der IE nicht. :wall:

Jetzt geht es.