Auf den Typ der aufrufenden Instanz reagieren

[Kinimod8]

Hallo,

folgendes Beispiel:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;

type
  TForm1 = class(TForm)
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

  TBigClass = class(TObject)
    function ReallyDoIt: boolean; virtual;
    procedure DoSomething;
  end;

  TSmallClass = class(TBigClass)
    function ReallyDoIt: boolean; override;
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

function TBigClass.ReallyDoIt: boolean;
begin
  result := false;
end;

procedure TBigClass.DoSomething;
var NewBigClass: TBigClass;
begin
  if ReallyDoIt then
  begin
    ShowMessage('Los gehts!');
    NewBigClass := TBigClass.Create;
    NewBigClass.DoSomething;
    NewBigClass.Free;
  end;
end;

function TSmallClass.ReallyDoIt: boolean;
begin
  result := false;
  if random(2) = 1 then
    result := true;
end;

end.

Wenn ich nun TSmallClass.DoSomething aufrufe, bekomme ich mit einer Wahrscheinlichkeit von ca. 50% die Meldung 'Los gehts!' gezeigt. Danach wird eine Instanz von TBigClass konstuiert und deren DoSomething aufgerufen, die wiederum TBigClass.ReallyDoIt abfragt, die ihrerseits immer false zurückgibt. Kurz: Ich werde nie zweimal 'Los gehts!' angezeigt bekommen.

Um das zu erreichen, müsste TBigClass.DoSomething eine TSmallClass konstruieren, wenn sie als "TSmallClass.DoSomething" aufgerufen wird. Kann man das irgendwie implementieren?

Vielen Dank schon mal! Hoffentlich war das verständlich.. :P

[Christian Seehase]

Moin Dominik,

warum nimmst Du hier

Delphi-Quellcode:

NewBigClass := TBigClass.Create;

nicht TSmallClass?
Dann hätte es doch den gewünschten Effekt.

BTW:

Delphi-Quellcode:

function TSmallClass.ReallyDoIt: boolean;
begin
  result := false;
  if random(2) = 1 then
    result := true;
end;

// geht auch kürzer

function TSmallClass.ReallyDoIt: boolean;
begin
  result := random(2) = 1;
end;

[Kinimod8]

Hallo,

Zitat:

Zitat von Christian Seehase

warum nimmst Du hier nicht TSmallClass?

Weil ich auch TBigClass.DoSomething aufrufen können und neben TSmallClass noch eine TEvenSmallerClass mit einer anderen ReallyDoIt-Funktion haben möchte.

Zitat:

Zitat von Christian Seehase

BTW:

Delphi-Quellcode:

function TSmallClass.ReallyDoIt: boolean;
begin
  result := false;
  if random(2) = 1 then
    result := true;
end;

// geht auch kürzer

function TSmallClass.ReallyDoIt: boolean;
begin
  result := random(2) = 1;
end;

Hast natürlich recht. Das ganze ist ja auch nur Beispiel, die richtigen Methoden sind noch etwas komplizierter :wink:

Danke.

[Hawkeye219]

Hallo Dominik,

die benötigte Klassenreferenz zum Erzeugen einer neuen Instanz erhältst du über TObject.ClassType:

Delphi-Quellcode:

procedure TBigClass.DoSomething;
var NewBigClass: TBigClass;
begin
  if ReallyDoIt then
  begin
    [..]
    NewBigClass := ClassType.Create AS TBigClass;
    [..]
  end;
end;

Wenn den den Constructor später überschreiben möchtest, so daß er Parameter übernimmt, dann solltest du die Klassenreferenz als Typ vereinbaren:

Delphi-Quellcode:

type
  TBigClassType = class of TBigClass;

[..]
NewBigClass := TBigClassType(ClassType).Create(...);
[..]

Gruß Hawkeye

[Kinimod8]

Funktioniert! Dankeschön!

[Alloc]

Zitat:

Zitat von Hawkeye219

TObject.ClassType

Hi,

hab mir grad mal in der OH den Eintrag dazu angeschaut:

Zitat:

Zitat von OH

Avoid using ClassType in application code.

Hat das einen Grund oder sollte man das einfach ignorieren?

Grüße,
Chris

[Hawkeye219]

Hallo Chris,

man sollte auf ClassType verzichten, wenn es möglich und sinnvoll ist, z.B. bei einer Typabfrage durch den Operator is. In Dominiks Code könnte man ClassType prinzipiell auch durch eine IF-Konstruktion ersetzen:

Delphi-Quellcode:

if Self is TSmallClass then
  NewBigClass := TSmallClass.Create
else
  if Self is TBigClass then
    NewBigClass := TBigClass.Create
  else
    raise Exception.Create('nicht vorgesehen');

Man sieht aber sehr deutlich, wie fehleranfällig eine solche Vorgehensweise ist. Die Reihenfolge der Abfragen ist wichtig (jede TSmallClass ist auch eine TBigClass) - ein Vertauschen der beiden Abfragen mit 'is' liefert nicht mehr das gewünschte Resultat. Zudem muß die Anweisung für jede hinzugenommene Klasse erweitert werden. Die (nicht verbotene) Verwendung von ClassType löst das Problem sehr elegant mit einer Zeile Code.

Gruß Hawkeye