StringGrid mit Text und Objects in der Zelle

[Helmi]

Hallo,

anbei ein Test-Programm, mit dem in einer StringGrid eine ComboBox in einer Zeile dargestellt wird.
Wird in der ComboBox etwas ausgewählt, wird dies in der StringGrid-Zelle angezeigt.

Soweit so gut.

Nur das ausgewählte ist ein Object und ein Text.

Mit diesem Code zeig ich den Text und das Object in der Zelle an (mit etwas Positions-Berechnung):

Delphi-Quellcode:

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
var
  Diff_Top_Object : Integer;
  Diff_Top_Text   : Integer;
  Left_Text       : Integer;
  Hoehe_Zelle     : Integer;
  Anfang_links    : Integer;
  Text_Zelle      : String;
  Object_Bitmap   : TBitmap;

begin
  //Variable initialisieren
  Diff_Top_Text     := 0;
  Left_Text         := 0;

  with StringGrid1 do
    begin
      //Bitmap aus Zelle lesen
      Object_Bitmap := TBitmap(Objects[aCol, ARow]);

      //Text aus Zelle lesen
      Text_Zelle    := Cells[aCol, ARow];

      //Höhe der Zelle ausrechnen
      Hoehe_Zelle   := Rect.Bottom - Rect.Top;

      If Assigned(Object_Bitmap) then
        begin
          //Differenz aurechnen um Bitmap mittig anzuzeigen
          Diff_Top_Object := (Hoehe_Zelle - Object_Bitmap.Height) div 2;

          //Abstand von links ausrechen (Diff_Top_Object um immer den gleichen
          //Abstand um das Bitmap zu erhalten)
          Anfang_links    := Rect.Left + Diff_Top_Object;

          //linke Position des Textes ausrechnen (Diff_Top_Object um immer den
          //gleichen Abstand um das Bitmap zu erhalten)
          Left_Text       := Anfang_links + Object_Bitmap.Width + Diff_Top_Object;

          //Differenz ausrechnen um Text mittig anzuzeigen
          Diff_Top_Text   := (Hoehe_Zelle - Canvas.TextHeight(Text_Zelle)) div 2;

          //Bitmap zeichnen
          Canvas.Draw(Anfang_links, Rect.Top + Diff_Top_Object, Object_Bitmap);
        end;

      //Text ausgeben
      Canvas.TextOut(Left_Text, Rect.Top + Diff_Top_Text, Text_Zelle);
    end;
end;

Das funktioniert auch - nur hinter dem Object wird noch der eigentliche Text der Zelle dargestellt (siehe angehängtes Bild).
Eigentlich ganz klar, denn ich schreib ja den Text in die Zelle.

Jetzt kann es passieren, wenn der Text länger ist, dass der Text rechts über das Object rausschaut.

Kann mir jemand einen Tip geben, wie ich das verhindern kann?

Meine Überlegung war, die Zelle nach dem Auslesen des Zellen-Textes komplett zu übermalen und dann erst das Object und den Text zu zeichnen, aber irgendwie hab ich das was falsch gemacht.

[Lannes]

Hallo,

nach ComboBox.Visible := False wird ein Neuzeichnen der entsprechenden Zelle ausgelöst.
Dabei wird der dann in Cells enthaltene String automatisch gezeichnet.
Diesen automatisch ausgegebenen String erst übermalen:

Delphi-Quellcode:

  with StringGrid1 do
    begin
      Canvas.FillRect(Rect);//<------ !
      //Bitmap aus Zelle lesen
      Object_Bitmap := TBitmap(Objects[aCol, ARow]);
      //...

Alternativ könnte man auch das komplette Zeichnen des Grids übernehmen indem man DefaultDrawing auf False setzt.

[Helmi]

Hallo,

danke für den Hinweis.

Hat funktioniert!