Komponente CheckBox: Haken übermalen mit WMPaint

[MacGuyver]

Moin Leute! :hi:

Ich habe mir eine neue Komponente gebastelt. Das Teil ist von TCheckBox abgeleitet. Jetzt möchte ich das Standardteil von Windows übermalen. So wie ich das im Schnipsel getan habe, funktioniert es nicht. Voll seltsam. Wenn das Programm startet, hört man den Ton. Verdecke ich das Fenster und mache es dann wieder frei, tönt es erneut. Schön und gut. Wenn ich den Haken (Kreuz) setzte oder entferne, ist nichts zu hören. Das sieht schon so aus, als ob der Haken von sonstwoher neu gezeichnet wird. Wie muß ich nun den Haken entsprechend übermalen? Kann mir da jemand Helfen? Ich habe schon ein paar Stunden im Forum gesucht aber nichts gefunden. Das Tutorial zur Komponentenentwicklung wurde leider nicht zu ende geführt, das habe ich auch schon gelesen.

Delphi-Quellcode:

procedure TDeCheckBoxControlPanel.WMPaint(var Message: TWMPaint);

var
 DC     : HDC;
 oldpen : HPen;
 loc    : TRect;

begin
  inherited;
  if (Style = csTriangle) then
  begin
    MessageBeep(MB_ICONHAND);
    DC := GetDC(Handle);

    oldpen := SelectObject(dc,CreatePen( PS_SOLID,1,ColorToRGB(clBlack)));
    SendMessage(Handle, EM_GETRECT, 0, LongInt(@Loc));
    MovetoEx(dc,loc.left,loc.Top,nil);
    LineTo(dc,loc.right,loc.Top + height);
    DeleteObject(selectobject(dc,oldpen));

    ReleaseDC(Handle,DC);
  end;
end;

[bitsetter]

Hi,

anstatt WM_PAINT könntest du auch CN_DRAWITEM nehmen.
Noch ein bisschen unfertiger Code, aber zur Demonstration reicht es:

Delphi-Quellcode:

type
  TChBox = class(TCheckBox)
  protected
    procedure CNDrawItem(var Message: TWMDrawItem); message CN_DRAWITEM;
    procedure CreateWnd; override;
  end;

procedure TChBox.CNDrawItem(var Message: TWMDrawItem);
var
  Canv: TCanvas;
  CheckRect: TRect;
begin
  CheckRect := Message.DrawItemStruct.rcItem;
  CheckRect.Right := CheckRect.Bottom;
  Canv := TCanvas.Create;
  try
    Canv.Handle := Message.DrawItemStruct.hDC;
    //if  Message.DrawItemStruct.ItemState and ODS_SELECTED <> 0 then
    if Self.Checked then
      Canv.Brush.Color := clRed
    else
      Canv.Brush.Color := clWhite;
    Canv.Rectangle(CheckRect);
    Canv.Brush.Style := bsClear;
    Canv.TextOut(CheckRect.Right + 2,(CheckRect.Bottom - Canv.TextHeight(Caption)) div 2, Caption);
  finally
    Canv.Free;
  end;
end;

procedure TChBox.CreateWnd;
begin
  inherited CreateWnd;
  if HandleAllocated then
    SendMessage(Handle, BM_SETSTYLE, BS_CHECKBOX or BS_OWNERDRAW, 1);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Cb: TChBox;
begin
  Cb:= TChBox.Create(self);
  Cb.Parent:= self;
  Cb.Caption:= 'Test';
  Cb.Left:= 20;
  Cb.Top:= 50;
end;