AGB  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Tutorials Delphi Tutorial: Sortier-Algorithmen I+II

Tutorial: Sortier-Algorithmen I+II

Ein Tutorial von Daniel · begonnen am 28. Jun 2002 · letzter Beitrag vom 12. Okt 2015
Antwort Antwort
Seite 1 von 4  1 23     Letzte » 
Daniel
Registriert seit: 30. Mai 2002
Bitte beachten: Dieses Tutorial muss überarbeitet werden, dazu fehlt im Moment aber einfach die Zeit.sorry


Sortier-Algorithmen

Eines der grundlegenden Probleme der Informatik: Das Sortieren einer Menge an Daten. Es gibt viele verschiedene Verfahren, die sich mehr oder weniger gut für den Einsatz in einem Programm eignen.

Man kann Sortierverfahren grob in zwei Klassen unterteilen: In die sogenannten internen Sortierverfahren und in die externen Sortierverfahren. Ein internes Sortierverfahren zeichnet sich dadurch aus, dass die zu sortierenden Daten im Speicher (z.B. in einem Array) untergebracht werden. Der Zugriff auf jeden einzelnen Datensatz ist hier leicht und vor allem schnell realisiert. Das genaue Gegenteil haben wir bei den externen Sortierverfahren, bei denen die zu sortierenden Daten auf einem (externen) Speichermedium vorliegen und der Zugriff sequentiell oder blockweise erfolgen muss.

Ich werde im Rahmen dieses Tutorials lediglich auf interne Verfahren eingehen. Es sind im Wesentlichen diejenigen Verfahren, die als die Standard-Verfahren bekannt sind:
  • Selection-Sort
  • Insertion-Sort
  • Bubble-Sort
  • Shell-Sort
  • QuickSort
  • Heap-Sort
  • Merge-Sort
Alle diese Sortier-Verfahren machen im Endeffekt genau das Gleiche: Sie sortieren ein Array von Zahlen. Allerdings unterscheiden sie sich in drei Faktoren:
  • benötigte Dauer
  • benötigter Speicherplatz
  • benötigte Anzahl an Vergleichen
Die Bedeutung dieser Faktoren, welche die Leistungsfähigkeit eines Verfahrens bestimmen, steigt mit der Menge der zu sortierenden Daten. Hat man nur wenige Datensätze oder sortiert nur selten, so kann es sinnvoller sein, einen einfachen Algorithmus zu Nutzen, der zwar ein wenig länger braucht, dafür aber schnell und fehlerfrei programmiert ist.
Bei weniger als zweitausend Datensätzen im Speicher macht es oftmals keinen Sinn, sich große Gedanken über einen schnellen Sortier-Algorithmus zu machen. Die Unterschiede liegen im Bereich von unter einer Sekunde.

Um die oben genannten Algorithmen in Bezug auf die drei wesentlichen Kenngrößen analysieren zu können, werde ich sie jetzt hier der Reihe nach vorstellen. Zuvor noch eine kurze Bemerkung zur den Beispiel-Codes:
Die Anzahl der zu sortierenden Elemente bezeichne ich mit dem Buchstaben N. (Dies ist die in der Fachliteratur gängige Methode). Zudem unterstelle ich als Datenfeld ein Array, welches von 1..N indiziert ist.

Selection-Sort
"Sortieren durch direktes Auswählen"
Der Selection-Sort ist einer der einfachsten Sortier-Algorithmen und läuft nach folgendem Schema ab:
Finde zuerst das kleinste Element und tausche es gegen das an erster Stelle befindliche Element aus, finde danach das zweitkleinste Element und tausche es gegen das an zweiter Stelle befindliche Element aus und setze dies so lange fort, bis das gesamte Feld sortiert ist.
Code:
Procedure SelectionSort;
var i, j, min : Integer;
Begin
  For i:= 1 to N-1 Do
  Begin
    min:= i;
    For j:= i+1 To N Do
      If (Data[j] < Data[min]) Then min:= j;

    SwapValues( i, min);
  End;
End;
Ich werde später noch darauf eingehen, dass dieser Algorithmus nicht einer der schnellsten ist. Dennoch hat er eine Eigenschaft, die sich unter Umständen als sehr positiv erweisen kann: Jeder Datensatz wird höchstens einmal verschoben. Gerade bei sehr großen Datensätzen kann dies ein Vorteil sein.


Insertion-Sort
"Sortieren durch direktes Einfügen"
Dieser Algorithmus ist fast so einfach wie der Selection-Sort, jedoch ein wenig flexibler. Dies ist eine Methode, die Menschen oft beim Kartenspiel anwenden, um die auf ihrer Hand befindlichen Karten zu sortieren:
Betrachte die Elemente eines nach dem anderen und fügen jedes an seinen richtigen Platz zwischen den bereits betrachteten Elementen ein.
Hierzu wird erst eine Lücke geschaffen (die größeren Elemente werden nach rechts gerückt) und dann kann man auf den frei gewordenen Platz das aktuelle Element einfügen.
Code:
Procedure InsertionSort;
var i,j,v : Integer;
Begin
  For i:= 2 To N Do
  Begin
    v:= Data[i];
    j:= i;
    While (j > 1) and (Data[j-1] > v) Do
    Begin
      Data[j]:= Data[j-1];
      dec( j );
    End;
    Data[j]:= v;
  End;
End;

Bubble-Sort
"Sortieren durch direktes Austauschen"
Dieser Algorithmus ist bestimmt in jedem Informatik-Grundkurs und jeder Informatik-Vorlesung gelehrt worden. Er gehört eindeutig zu den gemütlichen Sortier-Algorithmen. Schon bei 100.000 Elementen kann sich erst mal einen Kaffee holen, bevor dieser Algorithmus mit seiner Arbeit fertig ist. Trotzdem ist er leicht zu begreifen:
Durchlaufe immer wieder das Feld und tausche wenn nötig zwei benachbarte Elemente miteinander aus.
Code:
Procedure BubbleSort;
var i,j : Integer;
Begin
  For i:= N downto 1 Do
    For j:= 1 To i Do
      If (Data[j-1] > Data[j]) Then SwapValues( j-1, j );
End;

Shell-Sort
Der Shell-Sort ist eine Erweiterung des Insertion-Sort und setzt genau dort an, wo dieser seine Schwäche hat. Insertion-Sort ist langsam, weil stets nur benachbarte Elemente ausgetauscht werden. Steht zufälligerweise das kleinste Element ganz hinten, so werden N Vertauschungen benötigt, um es an seine richtige Position zu bringen.
Der Shell-Sort vertauscht also auch weit voneinander entferne Elemente miteinander. Diese Distanz wird als "h" bezeichnet. Der Grundgedanke besteht nun darin, dass man die Daten so umordnet, dass man eine sortierte Reihenfolge erhält, wenn man jedes h-te Element entnimmt. Lässt man dieses "h" nun gegen 1 laufen, wird nach und nach die gesamte Datenmenge sortiert.
Code:
Procedure ShellSort;
var i, j, h, v : Integer;
Begin
  h:= 1;
  Repeat
    h:= (3 * h) +1;
  Until (h > N);

  Repeat
    h:= (h div 3);
    For i:= (h+1) To N Do
    Begin
      v:= Data[i];
      j:= i;

      While ((j > h) and (Data[j-h] > v)) Do
      Begin
        Data[j]:= Data[j-h];
        dec( j, h );
      End;
      Data[j]:= v;
    End;
  Until (h = 1);
End;

Quick-Sort
Der Quick-Sort wurde 1960 entwickelt und dürfte einer der am häufigsten angewandten Sortier-Algorithmen sein. Seinen Namen verdient er der Tatsache, dass er für das Sortieren von N Elementen im Durchschnitt nur N * log (N) Operationen benötigt. (Ob das viel oder wenig ist, werden wir noch sehen) Der Quick-Sort kann sowohl rekursiv als auch iterativ programmiert werden. In rekursiver Variante belastet er den Stack-Speicher - dies kann bei großen Datenmengen zu einem Stack-Überlauf führen. In iterativer Variante läuft er zwar ein wenig langsamer, belastet dafür aber nur den Heap, welcher üblicherweise weniger beschränkt ist als der Stack.
Einen gravierenden Nachteil hat der Quick-Sort allerdings auch: Im ungünstigsten Fall benötigt er N*N Operationen, um die sortierte Reihenfolgen herzustellen. In diesem Fall zeigt er ein ähnlich schlechtes Verhalten wie der Bubble-Sort.
Das Prinzip des Quick-Sort beruht auf dem Prinzip, die Daten in Teilmengen aufzuspalten und diese unabhängig voneinander zu sortieren. Die rekursive Variante des Quick-Sort hat folgenden Rumpf:
Code:
Procedure QuickSort( l,r : Integer );
var i : Integer;
Begin
  If (r > l) Then
  Begin
    i:= Partition( l, r);
    QuickSortRekursiv( l, i-1 );
    QuickSortRekursiv( i+1, r );
  End;
End;
Von entscheidender Bedeutung ist hierbei die Prozedur "Partition". Diese muss das Datenfeld so umsortieren, dass drei Bedingungen erfüllt sind:
  • das Element Daten[ i ] befindet sich an seinem endgültigen Platz
  • alle Elemente, die links von i liegen, sind kleiner oder gleich dem Element Daten[ i ]
  • alle Elemente, die rechts von i liegen, sind größer oder gleich dem Element Daten[ i ]
Die Methodik, nach der vorgegangen wird, um diese Ziele zu erreichen, ist von entscheidender Bedeutung für die Leistungsfähigkeit des Algorithmus. (Mehr zu diesem Aspekt später)
Diese Prozedur setzt i = r und wählt somit willkürlich das Element ganz rechts (also ist Data[ i ] = Data[ r ]) und sucht jetzt von links beginnend ein Element, welches größer als Data[ i ] ist. Nun wird von rechts beginnend ein Element gesucht, welches kleiner als Data[ i ] ist. Beide gefundenen Elemente werden vertauscht. Fährt man so fort, ist sicher gestellt, dass die Teildatenmenge sortiert ist und dass das anfangs ausgewählte Element an seiner endgültigen Position liegt. Je näher i in der Mitte des Feldes liegt, desto erfolgreicher war die Partitionierung. (An dieser Stelle werden wir später noch optimieren)
Code:
Function Partition( l,r : Integer ) : Integer;
var v,t,i,j : Integer;
Begin
  v:= Data[r];
  i:= l-1;
  j:= r;
  Repeat
    Repeat inc( i ); Until (Data[i] >= v);
    Repeat dec( j ); Until (Data[j] <= v);
    t:= Data[i]; Data[i]:= Data[j]; Data[j]:= t;
  Until (j<=i);

  Data[j]:= Data[i]; Data[i]:= Data[r]; Data[r]:= t;
  Result:= i;
End;
Man kann wie bereits erwähnt die Rekursion entfernen. Man muss jedoch noch eine Hilfs-Struktur schaffen, in welcher man sich die Indizes der Teilmengen merkt. Hier bietet sich die Datenstruktur "Stack" an. (Ich setzte diese als bekannt voraus, kann aber auf Wunsch gerne einmal tiefer auf "Stacks" eingehen)
Die rekursiven Aufrufe werden also durch Stack-Operationen ersetzt und es wird eine innere Schleife hinzugefügt, welche solange läuft, bis der Stack vollständig abgearbeitet ist.
Code:
Procedure QuickSortIterativ;
var i, l, r : Integer;    
Begin
  l:= 1; r:= N;
  Stack.Push( l ); Stack.Push( r );

  Repeat
    If (r > l) Then
    Begin
      i:= Partition( l, r );
      If (i-l) > (r-i) Then
      Begin
        Stack.Push( l );
        Stack.Push( i-1 );
        l:= i+1;
      End
      Else
      Begin
        Stack.Push( i+1 );
        Stack.Push( r );
        r:= i-1;
      End;
    End
    Else
    Begin
      r:= Stack.Pop;
      l:= Stack.Pop;
    End;
  Until StackisEmpty;
End;
Wichtig hier bei ist, dass die Indizes der Teilmengen nicht in beliebiger Reihenfolge abgelegt werden, sondern dass die Indizes der größeren Teilmenge immer zuerst auf den Stack geschrieben werden. Dies bewirkt, dass der Stack im Durchschnitt lediglich für log(N) Einträge Platz bieten muss. Im ungünstigsten Fall könnte die Belastung des Stacks N erreichen.


Heap-Sort
(Es sind jetzt Vorkenntnisse in Bezug auf Bäume und deren Repräsentation als Feld (Array) nötig. Auf Wunsch kann ich gerne einmal näher darauf eingehen)
Der Heap-Sort basiert auf der Datenstruktur "Heap". Darunter versteht man einen Binärbaum, der die sog. Heap-Bedingung erfüllt. Unter dieser Heap-Bedingung versteht man die Eigenschaft, dass der größte (oder der kleinste) Wert stets an der Wurzel steht und dass alle folgenden Knoten die Bedingung erfüllen, dass der Wert jedes Knotens größer (oder kleiner) gleich dem seiner Nachfolger ist.
Das Prinzip des Heap-Sort basiert darauf, aus den zu sortierenden Daten einen Heap zu konstruieren, dann die Elemente nacheinander vom Heap zu entfernen und nach jedem Entfernen die Heap-Bedingung wieder herzustellen.
Code:
Procedure HeapSort;
var i, k, m : Integer;
Begin
  m:= N;
  k:= m div 2;

  For i:= k downto 1 Do downHeap( i, m );

  While (m > 1) Do
  Begin
    SwapValues( 1, m );
    dec( m );
    downHeap( 1, m );
  End;
End;
Von zentraler Bedeutung ist die Methode "downHeap", welche die Heap-Bedingung wider herstellt:
Code:
Procedure downHeap( index, heapSize : Integer );
var j, k, m, v : Integer;
Begin
  k:= index;
  v:= Data[k];
  m:= heapSize;
  While (k <= (m div 2)) Do
  Begin
    j:= 2*k;
    If (j < n) Then
      If (Data[j] < Data[j+1]) Then inc( j );
    If (v > Data[j]) Then
    Begin
      Data[k]:= v;
      Exit;
    End;
    SwapValues( k, j );
    k:= j;
  End;
End;
Der Heapsort hat den eindeutigen Vorteil, dass er ohne zusätzlichen Speicher auskommt und zudem selbst im ungünstigsten Fall noch eine nahezu konstante Laufzeit von N * log(N) garantiert. (Ich gehe später darauf ein, wie dieser Umstand zu bewerten ist)

Merge-Sort
Der Merge-Sort sortiert eine Datenmenge, indem er sie in Hälften teilt, diese dann (rekursiv) sortiert und anschließend zusammenfügt. Der Mergesort hat eine Eigenschaft, die als wesentlicher Vorteil gesehen werden kann: Man kann ihn so implementieren, dass der Zugriff auf die Daten hauptsächlich sequentiell erfolgt. Zum Beispiel ist der Mergesort ein gern genutztes Sortier-Verfahren für verkettete Listen, bei denen ein sequentieller Zugriff die einzig mögliche Zugriffsart ist. Leider hat er aber auch einen Nachteil: Er benötigt proportional zu N weiteren Speicher. (Im Code-Beispiel durch 'HilfsArray' dargestellt)
Code:
Procedure MergeSort( l, r : Integer );
var i, j, k, m : Integer;
Begin
  If (l < r) Then
  Begin
    m:= (r+l) div 2;

    MergeSort( l, m );
    MergeSort( m+1, r );

    For i:= l To m Do HilfsArray[i]:= Data[i];
    i:= l;

    For j:= m+1 To r Do HilfsArray[r+m+1-j]:= Data[j];
    j:= r;

    For k:= l To r Do
    Begin
      If (HilfsArray[i] < HilfsArray[j]) Then
      Begin
        Data[k]:= HilfsArray[i];
        inc( i );
      End
      Else
      Begin
        Data[k]:= HilfsArray[j];
        dec( j );
      End;
    End;
  End;
End;
Das war also ein erster Überblick über die Standard-Sortierverfahren. Ich hoffe, dass ich mich einigermaßen verständlich ausgedrückt habe. Für Fragen und Anmerkungen bin ich natürlich jederzeit offen.

Im nächsten Teil werde ich die vorstellten Algorithmen hinsichtlich der Laufzeit analysieren und vergleichen. In diesem Zusammenhang werde ich auch Varianten des Quick- und Heap-Sorts vorstellen, welche Laufzeit drastisch verbessern. Dann wird es auch das vollständige Programm-Listing zum Download geben.

Grüße,
Daniel
 
Daniel

 
Delphi 10.2 Tokyo Enterprise
 
#2
  Alt 10. Jul 2002, 21:38
Nachdem ich im letzten Teil die Standard-Algorithmen in gängigen Implementationen vorgestellt habe, will ich jetzt dazu kommen, diese zu vergleichen.
Als Basis habe ich ein Array mit 100.000 Elementen, welches einmalig mit Zufallszahlen gefüllt wird. Dieses Array wurde gesichert und für jeden Sortier-Algorithmus in genau der selben Form wieder hergestellt, so dass alle hier behandelten Algorithmen die gleiche Ausgangs-Situation vorfanden.
Verglichen werden jeweils die Laufzeit sowie die benötigte Anzahl an Vergleichen:

Bubble-Sort
Dauer: 74.157 ms
Anzahl Vergleiche: 5 * 10^9

Selection-Sort
Dauer: 42.341 ms
Anzahl Vergleiche: 5 * 10^9

Insertion-Sort
Dauer: 20.359 ms
Anzahl Vergleiche: 2,5 * 10^9

Shell-Sort
Dauer: 80 ms
Anzahl Vergleiche: 7.146.727

Quick-Sort (Rekursiv)
Dauer: 30 ms
Anzahl Vergleiche: 2.224.657

Quick-Sort (Iterativ)
Dauer: 71 ms
Anzahl Vergleiche: 2.224.657

Heap-Sort
Dauer: 65 ms
Anzahl Vergleiche: 2.984.590

Merge-Sort
Dauer: 40 ms
Anzahl Vergleiche: 1.668.946

Wie man unschwer erkennen kann, bilden der Bubble-, der Selection- und der Insertion-Sort die Schlusslichter.
Für diese Anzahl an Elementen spielt es ansonsten kaum eine Rolle, für welchen Algorithmus man sich entscheidet. Das könnte man zumindest meinen... Interessant wird es jetzt, wenn man sich die Anzahl an benötigten Vergleichen ansieht. Dieser Wert wird genau dann wichtig, wenn der Zugriff auf die benötigten Elemente Zeit kostet. In solch einem Szenario wäre es wichtig, die Vergleiche zu minimieren, um so die gesamte Laufzeit zu drücken. Folgende Variationen des Heap- und des Quicksort bringen diesbezüglich weitere Vorteile:

Heap-Sort (Optimiert)
Dauer: 50 ms
Anzahl Vergleiche: 1.560.387

Quick-Sort (Rekursiv / Optimiert)
Dauer: 20 ms
Anzahl Vergleiche: 1.628.846

Was verbirgt sich hinter diesen Varianten? Nun - der Heapsort hält sich lange damit auf, die Heapbedingung wieder herzustellen. Zu diesem Zweck schreibt er die Werte immer ganz nach unten an den Heap und bringt die von dort aus in die richtige Position. Es hat sich aber gezeigt, dass es im Mittel reicht, nur die halbe Strecke zurück zu legen und die Werte von der Mitte aus an die richtige Position zu bringen - sei es nun nach oben oder unten.

Code:
Procedure downHeapRisky( index, heapSize : Integer );
var ix, son1, son2, ixson : Integer;
Begin
  ix:= index;
  While (ix <= (heapSize div 2)) Do
  Begin
    son1:= 2 * ix;
    son2:= son1 + 1;

    If (son2 > heapSize) or (Data[son1] > Data[son2]) Then
      ixson:= son1
    Else
      ixson:= son2;

    SwapValues( ix, ixSon );
    ix:= ixSon;
  End;
  upHeap( index, ix );
End;

Procedure upHeap( index, heapSize : Integer );
var temp, upix, upix2 : Integer;
Begin
  temp:= Data[heapSize];
  upix:= heapSize;
  upix2:= upix div 2;

  While ((upix2 >= index) and (Data[upix2] < temp)) Do
  Begin
    SwapValues( upix, upix div 2 );
    upix:= upix div 2;
    upix2:= upix div 2;
  End;
  Data[upix]:= temp;
End;

Procedure HeapSortFast;
var size, i : Integer;
Begin
  size:= AnzahlElemente;

  For i:= (size div 2) downTo 1 Do downHeapRisky( i, size );

  For i:= 1 To size Do
  Begin
    SwapValues( 1, size-i+1 );
    downHeapRisky( 1, size-i );
  End;

End;
Und was wurde beim Quicksort geändert? Der wesentliche Vorteil des Quicksorts liegt darin, dass er die Daten über große Entfernungen hin austauschen kann. (Aus genau dem konträren Verhalten heraus ist der Bubble-Sort so langsam; er tauscht lediglich benachbarte Elemente aus). Je näher der Quicksort dem Ende kommt, desto häufiger hat er die Daten geteilt und desto kleiner werden die Teilmengen. Hier wird der Quicksort mehr und mehr ineffizient, da der Verwaltungsaufwand für die Rekursion oder den eigenen Stack deutlicher ins Gewicht fallen. Also hört man einfach auf, wenn die Größe der Mengen eine Größe von beispielsweise 25 erreicht haben. Dann setzt man einen Insertion-Sort ein, der bei kleinen vor-sortierten Teilmengen unschlagbar schnell ist. In dieser Kombination erreicht man den o.g. Vorteil.

Code:
Procedure InsertionSortForQuickSort;
var i,j,v : Integer;
Begin

  For i:= ErstesElement+1 To LetztesElement Do
  Begin
    v:= Data[i];
    j:= i;
    While (j > 1) and (Data[j-1] > v) Do
    Begin
      Data[j]:= Data[j-1];
      dec( j );
    End;
    Data[j]:= v;
  End;
End;

Procedure QuickSortOptimal( l, r : Integer );
var i, j, p, q, v, k : Integer;
Begin
  i:= l-1;
  p:= l-1;
  j:= r;
  q:= r;
  v:= Data[r];

  If (r - l) > 20 Then
  Begin

    Repeat
      inc( i );
      While (Data[i] < v) Do
      Begin
        inc( i );
      End;

      dec( j );
      While (v < Data[j]) Do
      Begin
        dec( j );
        If (j < l) Then Break;
      End;

      If (i >= j) Then Break;
      SwapValues(i, j);

      If (Data[i] = v) Then
      Begin
        inc( p );
        SwapValues( p, i );
      End;

      If (Data[j] = v) Then
      Begin
        dec( q );
        SwapValues( j, q );
      End;
    until (j < i);

    SwapValues( i, r );
    j:= i-1;
    inc( i );

    k:= l;
    While (k < p) Do
    Begin
      inc( k );
      dec( j );
      SwapValues( k, j );
    End;

    k:= r-1;
    While (k > q) Do
    Begin
      dec( k );
      inc( i );
      SwapValues( i, k );
    End;

    QuickSortOptimal( l, j);
    QuickSortOptimal( i, r);
  End;
End;
Ich hoffe, dass der eine oder andere ein paar für ihn brauchbare Infos herausziehen konnte (wenngleich es natürlich ein etwas spezielleres Thema ist... )

Grüße,
Daniel
Daniel R. Wolf
  Mit Zitat antworten Zitat
Daniel B
 
#3
  Alt 10. Jul 2002, 22:26
Hi,

hoffentlich ist dir die Tinte in der Tastatur nicht ausgegegangen.
Könntest du das vielleicht zippen und auch zum Download anbieten? Vielleicht sigar pdf, falls du es hast.
  Mit Zitat antworten Zitat
Tpercon

 
Delphi 5 Professional
 
#4
  Alt 11. Jul 2002, 19:21
Hi

Ich wollte den ShellSort mal aus Spaß zum Sortieren einer ListView nehmen. Warum funktioniert der Code nicht?
Code:
var i,j,h:integer;
    v:TListItem;
    begin
     h:=1;
     Repeat
      h:=(3*h)+1;
     Until (h>ListView1.Items.Count-1);
     Repeat
      h:=(h div 3);
      For i:=(h+1) To ListView1.Items.Count-1 Do
       Begin
        v:=ListView1.Items.Item[i];
        j:=i;
        While ((j>h) and (ListView1.Items.Item[j-h].Caption>v.Caption)) Do
         Begin
          ListView1.Items.Item[j]:=ListView1.Items.Item[j-h];
          dec(j,h);
         End;
        ListView1.Items.Item[j]:=v;
       End;
     Until (h=1);
    end;
  Mit Zitat antworten Zitat
Daniel

 
Delphi 10.2 Tokyo Enterprise
 
#5
  Alt 11. Jul 2002, 20:09
Es hat offenbar Probleme mit den Objekt-Referenzen gegeben. Wenn man sich lediglich auf die Captions beschränkt, dann geht es. Zudem arbeitet die von mir vorgestellte Version auf einem Datenbestand, der mit dem Index 1 anfängt. Also musst Du die Indices aller Zugriffe auf die ListItems um 1 erniedrigen.
Code:
var i,j,h:integer;
    v:TListItem;
    begin
     v:= TListItem.Create( ListView1.Items ); // den habe ich mal erzeugt
     h:=1;
     Repeat
      h:=(3*h)+1;
     Until (h>ListView1.Items.Count-1);
     Repeat
      h:=(h div 3);
      For i:=(h+1) To ListView1.Items.Count-1 Do
       Begin
        v.Caption:=ListView1.Items.Item[i-1].Caption;
        j:=i;
        While ((j>h) and (ListView1.Items.Item[j-h-1].Caption>v.Caption)) Do
         Begin
          ListView1.Items.Item[j-1].Caption:=ListView1.Items.Item[j-h-1].Caption;
          dec(j,h);
         End;
        ListView1.Items.Item[j-1].Caption:=v.Caption;
       End;
     Until (h=1);
     v.Free;
    end;
In dieser Fassung funktioniert der Algorithmus - jetzt muss man sich nur noch um eine saubere Behandlung der Objekte kümmern.

Grüße,
Daniel
Daniel R. Wolf
  Mit Zitat antworten Zitat
Udontknow
 
#6
  Alt 27. Aug 2002, 21:16
Hallo, Daniel!

Ich habe mir mal den Quicksort zu Gemüte geführt und treffe da auf ein paar Probleme, vielleicht kannst du mir weiterhelfen:


Ich bekomme beim Ausführen den Hinweis "Listenindex überschreitet das Maximum" (habe anstelle eines Arrays ein TList-Objekt, habe also deine Routinen dementsprechend angepasst).

Du hast ja die Routinen Quicksort und Partition gepostet.
Bei der Funktion Partition glaube ich einen Fehler entdeckt zu haben.

Du initialisierst folgende Werte :
Code:
 
i:= l-1;
j:= r;
i entspricht dem ersten Element in der Menge -1; Da du sofort in einer repeat-until-Schleife um 1 erhöhst, erhälst du dann als erstes den Index des ersten Elementes.
Wieso tust du das aber nicht mit j? Du willst ja anscheinend zunächst das letzte Element erhalten, da aber erstmal wieder in einer Repeat-Until-Schleife Dec(j) erfolgt, setzt du doch hier (fälschlicherweise?) beim vorletzten Element an, oder?

Nachdem ich also die Zeile "j:=r" durch "j:=r+1" ersetzt hatte, traten keine Fehler mehr auf, die Liste ist dann aber immer noch nicht komplett sortiert. Hast du auf Anhieb ne Idee, woran das liegen könnte?

Ich poste mal meine Partition-Routine, vielleicht hilft´s ja:

Code:
function TStempIDComponentList.Partition(l, r: Integer): Integer;
var v,i,j : Integer;
var t:Pointer;
Begin
  v:= Items[r].ID;
  i:= l-1;
  j:= r+1;
  Repeat

    Repeat
      inc( i );
    Until (Items[i].ID >= v);

    Repeat
      dec( j );
    Until (Items[j].ID <= v);

    t:= Items[i];
    Items[i]:=Items[j];
    Items[j]:= t;

  Until (j<=i);

  Items[j]:= Items[i];
  Items[i]:= Items[r];
  Items[r]:= t;

  Result:= i;
End;
Cu & thx im voraus,
Udontknow
  Mit Zitat antworten Zitat
Udontknow
 
#7
  Alt 27. Aug 2002, 22:59
Hallo, ich bins nochmal!

Irgendwo war da noch der Wurm in der Partition-Routine.
Warum setzt du das vergleichende Element eigentlich auf das rechte Ende der Folge? In meiner Algorithmus-Beschreibung steht, das das mittlere Element für den Vergleich ausgewählt werden muss...

Naja, ich habe es noch einmal neu aufgesetzt, allerdings mit while-Schleifen anstelle von Repeat-Until-Konstrukten. So klappts.

In diesem Fall sortiere ich Objekte, die sich in einer Liste befinden und von meiner Klasse TStempIDComponentList verwaltet werden. ich sortiere nach dem Attribut ID der einzelnen Objekte.

Code:
procedure TStempIDComponentList.SwapValues(Index1, Index2: Integer);
var P:Pointer;
begin
  P:=Items[Index1];
  Items[Index1]:=Items[Index2];
  Items[Index2]:=P;
end;

function TStempIDComponentList.Partition(l, r: Integer): Integer;
var x,i,j : Integer;
begin
  //Mittleres Element x bestimmen
  x:=r+l div 2;

  //Elemente von aussen nach innen durchgehen & evt. vertauschen
  i:=l;
  j:=r;

  //Solange vorgehen, bis Grenzen angenähert
  while (i<j) do
  begin
    //Äußerstes Element der linken Seite bestimmen, das verschoben werden muss
    //(Vergleich des Feldes ID der Objekte)
    while (Items[i].ID<Items[x].ID) do
      Inc(i);
    //Äußerstes Element der rechten Seite bestimmen, das verschoben werden muss
    //(Vergleich des Feldes ID der Objekte)
    while (Items[j].ID<Items[x].ID) do
      Dec(j);

    //Werte vertauschen
    SwapValues(i,j);
  end;

  Result:=i;
end;
Cu,
Udontknow
  Mit Zitat antworten Zitat
Daniel

 
Delphi 10.2 Tokyo Enterprise
 
#8
  Alt 27. Aug 2002, 23:19
Zitat von Udontknow:
Warum setzt du das vergleichende Element eigentlich auf das rechte Ende der Folge? In meiner Algorithmus-Beschreibung steht, das das mittlere Element für den Vergleich ausgewählt werden muss...
.. das haben mich meine Berater die letzten zwei Tage vor dem Schreiben des Tutorials auswendig lernen lassen.
Nein - mal im Ernst: Ich greife das Thema morgen nochmal auf; heute habe ich mein Hirn offenbar schon überlastet.

Grüße,
Daniel
Daniel R. Wolf
  Mit Zitat antworten Zitat
Daniel

 
Delphi 10.2 Tokyo Enterprise
 
#9
  Alt 29. Aug 2002, 13:24
Hallo,

bei der Partitionierung geht es ja darum, sich ein Element aus der Datenmenge zu greifen und anschliessend die Datenmenge so zu sortieren, dass alle Elemente, die kleiner als das gewählte Element sind, links davon liegen und alle Elemente, die grösser als das gewählte Element sind, rechts davon liegen.

Der Quicksort arbeitet um so effizienter, je näher das gewählte Elemente an der Mitte der Datenmenge liegt.

Wenn Du nur ein einzelnes Element herausgreifst und wir mal davon ausgehen, dass Du eine unsortierte Datenmenge vorliegen hast, so ist es völlig unerheblich, welches Element Du herausgreifst. Die Wahrscheinlichkeit ein geeignetes Element zu finden, ist für das erste, letzte und mittlere Element gleich gross.

Eine Technik, den Vorgang zu optimieren, wäre der "Median von Dreien", nach der Du Dir drei Elemente herausgreifst und deren mittleres Element auswählst.


Grüße,
Daniel
Daniel R. Wolf
  Mit Zitat antworten Zitat
Udontknow
 
#10
  Alt 30. Aug 2002, 01:38
Wir müssen uns nochmal mit dem Fehler in der Routine "Partition" beschäftigen.

Was ist mit der Initialisierung "j:=r"?

Deine Funktion "Partition" schlägt fehl, wenn das letzte Element Data[r] die kleinste Wertigkeit hat.

Nimm mal folgende Zahlenfolge an :

Data[1]:=1200;
Data[2]:=1100;
Data[3]:=1000;

Führe nun Partition[1,3] durch.
Die Initialisierung belegt dann

v=Data[r]=1000,
i=l-1=0
und j=r=3.

Nachdem i einmal inkrementiert und dann die Abbruchbedingung Data[i]>=v) erfüllt wurde, gerätst du in eine Endlosschleife, die j immer weiter senkt:
Du senkst zunächst j um 1. Ab diesem Zeitpunkt ist (zumindest innerhalb der Arraygrenzen) deine Abbruchbedingung Data[j]<=v gar nicht mehr erfüllbar, da eben der niedrigste Wert der Zahlenfolge das letzte Element (r) ist, du aber eine Prüfung immer erst beim vorletzten Element ansetzt!
Bei einem TList-Objekt wie bei mir ist sowas halb so schlimm, ich bekomme dann eine Exception, bei einem Array aber "sortierst" du plötzlich Speicherbereiche, die gar nicht zum Array gehören (wenn z.B. zufälligerweise Data[-5043]=900 ist, tauscht du dann an dieser Stelle die Werte aus ).

Bei einer Initialisierung mit "j:=r+1" wäre das natürlich dann korrekt.

Was meinst du?

Cu,
Udontknow
  Mit Zitat antworten Zitat
Themen-Optionen Tutorial durchsuchen
Tutorial durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 23:07 Uhr.
Powered by vBulletin® Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2017 by Daniel R. Wolf