Drag / Drop Tutorial

[haentschman]

... ein erfolgreiches neues Jahr euch allen...


... mit der SuFu komme ich zu keinem vernünftigem Ergebnis...

- wo finde ich ein Tutorial zu Drag / Drop.
- wie funktioniert das prinzipiell (kein Code).

...ich möchte erst einmal verstehen wie das funktioniert... den Rest kriege ich schon.

Danke...

[DeddyH]

Vielleicht hilft Dir diese Seite erstmal weiter (englisch): http://www.blong.com/Conferences/Bor...dDrop/4114.htm

P.S.: Auch Dir ein frohes neues Jahr (dieser Smiley ist echt witzig)

[MrKnogge]

Was möchtest du denn Dragen und Dropen ?

Wenn es um Dateien/Ordner vom Explorer zum Programm geht, so funktioniert es, in dem du auf die entsprechende Message von Windows reagierst und sie auswertest.

[haentschman]

Dank für die schnelle Antwort...

... ist wirklich

... für den Anfang geht es erst einmal um Dateinamen vom Explorer in eine FileListBox.

...mit Englisch komme ich zwar einigermaßen zurecht, wenn es aber ans eingemachte geht...hört es auf..

[MrKnogge]

Dann bekommste jetzt einfach doch den Source :

Delphi-Quellcode:

uses ShellApi;

...
type
 
  private
    { Private-Deklarationen }
    procedure WMDROPFILES (var Msg: TMessage); message WM_DROPFILES;

...

procedure TForm1.WMDROPFILES (var Msg: TMessage);
var
  i, anzahl, size: integer;
  Dateiname: PChar;
begin
  inherited;
  anzahl := DragQueryFile(Msg.WParam, $FFFFFFFF, Dateiname, 255);
  for i := 0 to (anzahl - 1) do
  begin
    size := DragQueryFile(Msg.WParam, i , nil, 0) + 1;
    Dateiname:= StrAlloc(size);
    DragQueryFile(Msg.WParam,i , Dateiname, size);
    ListBox1.items.add(StrPas(Dateiname));
    StrDispose(Dateiname);
  end;
  DragFinish(Msg.WParam);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Form1.Handle, true);
end;

Gruß

[haentschman]

...vielen Dank.

dann mache ich jetzt mal Copy / Paste und schaue mir das mal in Ruhe an...

Danke...

[haentschman]

... ich löcher Euch einfach mal...

... das Beispiel funktioniert ja... aber warum


- nullterminierte Strings

... ich habe die Funktion mal angehalten und mir die verschiedenen Werte mal angeschaut. (auf manche kann ich nicht zugreifen)

anzahl := DragQueryFile(Msg.WParam, $FFFFFFFF, Dateiname, 255); - die Anzahl repräsentiert ja die Menge der Dateinamen...aber wie wird die übergeben / wo versteckt ?


size := DragQueryFile(Msg.WParam, i , nil, 0) + 1; - die Länge des Strings


DragQueryFile(Msg.WParam,i , Dateiname, size); - der Dateiname zurück



...learning by doing ist manchmal ein Krampf...

Sorry...

[Hawkeye219]

Hallo,

die Erklärung zu den benötigten Funktionen findest du bei Microsoft: DragAcceptFiles und DragQueryFile.

Ich habe die Routine von MrKnogge mal in eine handliche Funktion umgewandelt, dann kann man sie relativ einfach in mehreren Applikationen verwenden.

Delphi-Quellcode:

// uses ShellAPI

function GetFilesDropped (aHandle: THandle;  aList: TStrings): Boolean;
var
  FileCount : Integer;
  Index     : Integer;
  Buffer    : array [0..MAX_PATH] of Char;
begin
  FileCount := DragQueryFile(aHandle, Cardinal(-1), nil, 0);
  aList.BeginUpdate;
  try
    for Index := 0 to FileCount - 1 do
      begin
        DragQueryFile(aHandle, Index, @Buffer, SizeOf(Buffer));
        aList.Add(Buffer);
      end;
  finally
    aList.EndUpdate;
  end;
  Result := (FileCount > 0);
end;

// in der Applikation:
type
  TForm1 = class (TForm)
    [...]
    procedure FormCreate (Sender: TObject);
  private
    procedure WMDropFiles (var aMsg: TMessage); message WM_DROPFILES; 
  end;

procedure Form1.FormCreate (Sender: TObject);
begin
  DragAcceptFiles (Handle, True);
end;

procedure Form1.WMDropFiles (var aMsg: TMessage);
begin
  if GetFilesDropped(aMsg.WParam, ListBox.Items) then
    ShowMessage ('files dropped');
end;

Gruß Hawkeye

[haentschman]

Danke...

Zitat:

die Erklärung zu den benötigten Funktionen findest du bei Microsoft: DragAcceptFiles und DragQueryFile.

...die Links waren gut.

...jetzt ist mir einiges mit dem 'Return Value' viel klarer.

- ich spiel dann mal ein bischen rum... kopieren per Drag/Drop etc.

Danke noch mal...

[haentschman]

...aufwärm...

ich habe mal ein bischen rumgespielt...

und...

1. ShellApi eingebunden

2.

Delphi-Quellcode:

private
    { Private-Deklarationen }
    procedure DropFiles (var Msg: TMessage); message WM_DROPFILES;

3.

Delphi-Quellcode:

procedure TFAnlagenkomponenten.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(FAnlagenkomponenten.ListBox1.Handle, true);
end;

4.

Delphi-Quellcode:

procedure TFAnlagenkomponenten.DropFiles(var Msg: TMessage);
var
  i, anzahl, size: integer;
  Dateiname: PChar;
begin
  inherited;
  anzahl := DragQueryFile(Msg.WParam, $FFFFFFFF, Dateiname, 255);
  for i := 0 to (anzahl - 1) do
  begin
    size := DragQueryFile(Msg.WParam, i , nil, 0) + 1;
    Dateiname:= StrAlloc(size);
    DragQueryFile(Msg.WParam,i , Dateiname, size);
    Label2.Caption:= intToStr(size);
    Label3.Caption:= StrPas(Dateiname);
    ListBox1.items.add(StrPas(Dateiname));
    StrDispose(Dateiname);
  end;
  DragFinish(Msg.WParam);
end;

... die Procedure 4. wird nicht angesprungen.

... bis auf ein paar Labels für die Visualisierung und procedure Namensänderung hat sich zum Beispiel nichts verändert

Danke für Eure Geduld...