Array of String - Zugriffsverletzung

[Real-TTX]

Hallo Gemeinde

Ich habe ein Problem mit einem Dynamischen Array. Ich denke ich habe irgendwo ein Denkfehler drinne. Ich finde ihn einfach nicht. Ich mach es eigentlich wie immer. Und es geht einfach nicht :/ Ich hoffe jemand findet was:

Delphi-Quellcode:

type
  ArrOfStr = array of string;

....


function ReadComPorts : ArrOfStr;
var
  reg: TRegistry;
  st: Tstrings;
  i: Integer;
begin
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    reg.OpenKey('hardware\devicemap\serialcomm', False);
    st := TstringList.Create;
    try
      reg.GetValueNames(st);
      //setlength(result,0);
      for i := 0 to st.Count do // st.Count = 2 Laut Überwachung
      begin
        setlength(result,i);
        result[i] := reg.Readstring(st.strings[i]);

      end;
    finally
      st.Free;
    end;
    reg.CloseKey;
  finally
    reg.Free;
  end;

end;

Gruß, Real-TTX

[Apollonius]

Das letzte Array-Element hat den Index Length-1, sodass dein Index in der Schleife zu hoch ist. Selbiges für die Stringliste, die Schleife muss von 0 bis Count-1 laufen.
Das SetLength solltest du außerdem vor die Schleife verlagern, da dies sehr viel Zeit spart.

[marabu]

Hi,

ein paar augenfällige Korrekturen:

Delphi-Quellcode:

uses
  Types;

....

function ReadComPorts : TStringDynArray;
var
  reg: TRegistry;
  st: Tstrings;
  i: Integer;
begin
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    reg.OpenKey('hardware\devicemap\serialcomm', False);
    st := TStringList.Create;
    try
      reg.GetValueNames(st);
      setlength(result, st.Count);
      for i := 0 to Pred(st.Count) do 
        result[i] := reg.Readstring(st[i]);
    finally
      st.Free;
    end;
    reg.CloseKey;
  finally
    reg.Free;
  end;
end;

Grüße vom marabu

[Real-TTX]

Ich merk schon, ohne euch bin ich aufgeschmissen
Danke euch!

Gruß, Real-TTX