Dynamisch erzeugte Shapes ansteuern WIE ?

[Kytrix]

Hi ich erzeuge zur Laufzeit Shapes in einem Array diese werden auch ohne probleme erzeugt ... so wenn ich aber versuche über den Index auf die einzelnen Shapes zuzugreifen und deren Eigenschaften zu ändern geht das jedoch nicht ich habe auch schon alles im Forum durchgelsen und habe es schon mit FindComponent versucht jedch bekomme ich immer eine AV als fehlermeldung.

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Time: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormDblClick(Sender: TObject);
    procedure TimeTimer(Sender: TObject);
  private
    { Private-Deklarationen }
    SpeziesR, SpeziesB: Array of TShape;
    procedure Move;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
Var i: Integer;
begin
  Randomize;
  for i := 1 to 10 do
  begin
    SetLength(SpeziesR,i);
    SpeziesR[i]:= TShape.Create(Self);
    SpeziesR[i].Parent:=Form1;
    SpeziesR[i].Shape:=stCircle;
    SpeziesR[i].Width:=30;
    SpeziesR[i].Height:=30;
    SpeziesR[i].Brush.Color:=clRed;
    SpeziesR[i].Left:=Random(470);
    SpeziesR[i].Top:=Random(470);
    SetLength(SpeziesB,i);
    SpeziesB[i]:= TShape.Create(Self);
    SpeziesB[i].Parent:=Form1;
    SpeziesB[i].Shape:=stCircle;
    SpeziesB[i].Width:=30;
    SpeziesB[i].Height:=30;
    SpeziesB[i].Brush.Color:=clBlue;
    SpeziesB[i].Left:=Random(470);
    SpeziesB[i].Top:=Random(470);
  end;
end;

procedure TForm1.FormDblClick(Sender: TObject);
begin
  if Time.Enabled=false then
  Time.Enabled:=true
  else
  Time.Enabled:=false;
end;

procedure TForm1.Move;
Var i, Direction: Integer;
begin
  for i := 1 to 10 do
  begin
    Direction:=Random(4);                        
    case Direction of
    1 : SpeziesR[i].Left := SpeziesR[i].Left -1;  // Sobald ich ab hier versuche auf die Shapes zuzugreifen bekomme ich nur noch AV 
    2 : SpeziesR[i].Top:= SpeziesR[i].Top -1;     // Fehlermeldungen
    3 : SpeziesR[i].Left := SpeziesR[i].Left +1;
    4 : SpeziesR[i].Top := SpeziesR[i].Top +1;
    end;
    Direction:=Random(4);
    case Direction of
    1 : SpeziesB[i].Left := SpeziesB[i].Left -1;
    2 : SpeziesB[i].Top:= SpeziesB[i].Top -1;
    3 : SpeziesB[i].Left := SpeziesB[i].Left +1;
    4 : SpeziesB[i].Top := SpeziesB[i].Top +1;
    end;
  end;
end;

procedure TForm1.TimeTimer(Sender: TObject);
begin
  Move;
end;

end.

[omata]

Dynamische Arrays beginnen immer bei 0 und der höchste Index ist immer length-1. Schau dir auch mal High() an.

Bitte nicht so programmieren...

Zitat von Kytrix:

Delphi-Quellcode:

procedure TForm1.FormDblClick(Sender: TObject);
begin
  if Time.Enabled=false then
  Time.Enabled:=true
  else
  Time.Enabled:=false;
end;

das geht schöner...

Delphi-Quellcode:

procedure TForm1.FormDblClick(Sender: TObject);
begin
  Time.Enabled:=not Time.Enabled;
end;

[Kytrix]

wenn ich da statt 1-10 0-9 eintrage klappt da erst recht garnichts mehr ..... aber egal das löst ja das eigentliche problem sowieso nicht


OK ich hatte alles richtig nur das ich statt SetLength(SpeziesB,i) und SetLength(SpeziesR,i) eine feste angabe für die arraygröße genommen habe SetLength(SpeziesB,10) & SetLength(SpeziesR,10)

[turboPASCAL]

Ich habe damit kein Problem :

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormDblClick(Sender: TObject);
    procedure TimeTimer(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
    SpeziesR, SpeziesB: Array of TShape;
    procedure Move;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  Max_Spezies = 10;

procedure TForm1.FormCreate(Sender: TObject);
var
  i: Integer;
begin
  Randomize;

  Timer1.Enabled := FALSE;

  Self.DoubleBuffered := TRUE;

  SetLength(SpeziesR, Max_Spezies);
  SetLength(SpeziesB, Max_Spezies);

  for i := 0 to Max_Spezies - 1 do
  begin

    SpeziesR[i]:= TShape.Create(Self);
    SpeziesR[i].Parent := Self;
    SpeziesR[i].Shape := stCircle;
    SpeziesR[i].Width := 30;
    SpeziesR[i].Height := 30;
    SpeziesR[i].Brush.Color := clRed;
    SpeziesR[i].Left := Random(470);
    SpeziesR[i].Top := Random(470);
    SpeziesR[i].Visible := TRUE;

    SpeziesB[i]:= TShape.Create(Self);
    SpeziesB[i].Parent := Self;
    SpeziesB[i].Shape := stCircle;
    SpeziesB[i].Width := 30;
    SpeziesB[i].Height := 30;
    SpeziesB[i].Brush.Color := clBlue;
    SpeziesB[i].Left:= Random(470);
    SpeziesB[i].Top := Random(470);
    SpeziesB[i].Visible := TRUE;
  end;

  Timer1.Enabled := TRUE;

  Self.Caption := format('Timer: ms = %d, Enabled = %d', [Timer1.Interval, INTEGER(Timer1.Enabled)]);
end;

procedure TForm1.FormDestroy(Sender: TObject);
var
  i: Integer;
begin
  for i := 0 to Max_Spezies - 1 do
  begin
    if Assigned(SpeziesR[i]) then SpeziesR[i].Free;
    if Assigned(SpeziesB[i]) then SpeziesB[i].Free;
  end;
end;

procedure TForm1.FormDblClick(Sender: TObject);
begin
  Timer1.Enabled := not Timer1.Enabled;
  Self.Caption := format('Timer: ms = %d, Enabled = %d', [Timer1.Interval, INTEGER(Timer1.Enabled)]);
end;

procedure TForm1.Move;
var
  i, Direction: Integer;
begin
  for i := 0 to Max_Spezies - 1 do
  begin
    Direction := Random(5); // Random(4) gibt ZufallsZahlen von 0..3
                            // "Random returns a random number within the range
                            // 0 <= X < Range. If Range is not specified, the
                            // result is a real-type random number within the range
                            // 0 <= X < 1."

    case Direction of
      1 : SpeziesR[i].Left := SpeziesR[i].Left -1;
      2 : SpeziesR[i].Top:= SpeziesR[i].Top -1;
      3 : SpeziesR[i].Left := SpeziesR[i].Left +1;
      4 : SpeziesR[i].Top := SpeziesR[i].Top +1;
    end;

    Direction := Random(5);
    case Direction of
      1 : SpeziesB[i].Left := SpeziesB[i].Left -1;
      2 : SpeziesB[i].Top:= SpeziesB[i].Top -1;
      3 : SpeziesB[i].Left := SpeziesB[i].Left +1;
      4 : SpeziesB[i].Top := SpeziesB[i].Top +1;
    end;
  end;
end;

procedure TForm1.TimeTimer(Sender: TObject);
begin
  Move;
end;

end.