[Pascal Warnung] Warum wird die Warnung W1036 angezeigt?

[Chemiker]

Hallo,

ich stelle einige Routinen auf OOP um. Unter anderem habe ich mir eine Klasse erstellt die mir einige Information über die Application liefert.

Delphi-Quellcode:

type
  TAppInfos = Class(TObject)
  private
    function GetSpecialPath(nFolder: Integer): string;
    function GetApplicationsName: String;
    function GetAnwendungsPath: TFileName;
    function GetEigeneDateien: TFileName;
    function GetAppAnwendungsOrdner: TFileName;
  public
    property ApplicationsName : String Read GetApplicationsName;
    property AnwendungsPath : TFileName Read GetAnwendungsPath;
    property EigeneDateien : TFileName Read GetEigeneDateien;
    property AppAnwendungsOrdner: TFileName Read GetAppAnwendungsOrdner;
  End;

implementation

{ TAppInfos }

function TAppInfos.GetAnwendungsPath: TFileName;
begin
  Result:= IncludeTrailingPathDelimiter(GetSpecialPath(CSIDL_APPDATA));
end;

function TAppInfos.GetAppAnwendungsOrdner: TFileName;
begin
  Result:= AnwendungsPath+ApplicationsName;
end;

function TAppInfos.GetApplicationsName: String;
var
  aPath: TFileName;
begin
  Result:= ChangeFileExt(ExtractFileName(Application.ExeName),'');
end;

usw.

Verwendet wird die Klasse von mir zum Beispiel um eine INI-Datei im Anwendungsverzeichnis abzuspeichern.

Delphi-Quellcode:

procedure TfrmSPSDAPHauptMenue.FormCreate(Sender: TObject);
var
  aIniDateiPath: TFileName;
  aInitDateiName: TFileName;
  aInfos: TAppInfos;
begin
  // An dieser Stelle sollen einige Ordner erstellt werden im Anwendungs-
  // Verzeichnis.
  OrdnerAnlegenAnwendungsVerzeichnis;
  // Als weiteres wird eine INI-Datei erstellt um das Form wie bei der letzten
  // Speicherung wieder herzustellen.
  aIniDateiPath:= IncludeTrailingPathDelimiter(aInfos.AppAnwendungsOrdner)+
                  IncludeTrailingPathDelimiter(aInfos.ApplicationsName+INIT);
  aInitDateiName:= aIniDateiPath+Caption+'.INI';

  IniLesenAnlegen (self,aInitDateiName);
end;

Beim Ausführen des Programms meckert der Compiler mit folgender Warnmeldung:

[Pascal Warnung] frmSPSDAPHauptmenue2009.pas(58): W1036 Variable 'aInfos' ist möglicherweise nicht initialisiert worden

Meine Frage ist, wie muss ich den Quell-Code anpassen, dass ich diese [Pascal Warnung] nicht mehr bekomme.

Bis bald Chemiker

[fkerber]

Hi!

Ja, ich denke, das solltest du!
Du greifst ja hier auf die Variable zu "aInfos.AppAnwendungsOrdner"

Schlägt das jetzt nicht fehl?



Ciao, Frederic

[jbg]

Zitat von fkerber:

Schlägt das jetzt nicht fehl?

Da er innerhalb der TAppInfos Methoden nicht auf "Self" zugreift hat er glück, ist aber eine tickende Zeitbombe wenn man denn doch irgendwann auf Daten zugreift, die nicht global sind.

Im Übrigen würde ich hier überhaupt keine Instanzvariable (aInfos) benutzen, sondern die properties und Methoden von TAppInfos zu Klassenmethoden und Klassen-Properties machen. Wenn man schon Delphi 2009 hat, kann man auch die Sprachfeatures nutzen.

Delphi-Quellcode:

TAppInfos = Class(TObject)
  private
    class function GetSpecialPath(nFolder: Integer): string; static;
    class function GetApplicationsName: String; static;
    class function GetAnwendungsPath: TFileName; static;
    class function GetEigeneDateien: TFileName; static;
    class function GetAppAnwendungsOrdner: TFileName; static;
  public
    class property ApplicationsName : String Read GetApplicationsName;
    class property AnwendungsPath : TFileName Read GetAnwendungsPath;
    class property EigeneDateien : TFileName Read GetEigeneDateien;
    class property AppAnwendungsOrdner: TFileName Read GetAppAnwendungsOrdner;
  end;

{ TAppInfos }

class function TAppInfos.GetAnwendungsPath: TFileName;
begin
  Result:= IncludeTrailingPathDelimiter(GetSpecialPath(CSIDL_APPDATA));
end;

...

procedure TfrmSPSDAPHauptMenue.FormCreate(Sender: TObject);
var
  aIniDateiPath: TFileName;
  aInitDateiName: TFileName;
//  aInfos: TAppInfos;  nicht mehr nötig
begin
  // An dieser Stelle sollen einige Ordner erstellt werden im Anwendungs-
  // Verzeichnis.
  OrdnerAnlegenAnwendungsVerzeichnis;
  // Als weiteres wird eine INI-Datei erstellt um das Form wie bei der letzten
  // Speicherung wieder herzustellen.
  aIniDateiPath:= IncludeTrailingPathDelimiter(TAppInfos.AppAnwendungsOrdner)+
                  IncludeTrailingPathDelimiter(TAppInfos.ApplicationsName+INIT);
...

[Chemiker]

Hallo fkerber,

nein, funktioniert alles wie es soll.

Bis bald Chemiker

[Chemiker]

Hallo jbg,

habe ich nach Deine Tipp, umgestellt und funktioniert. Warnmeldungen kommen nicht mehr.

Zitat von jbg:

Wenn man schon Delphi 2009 hat, kann man auch die Sprachfeatures nutzen

Das habe ich zwar auch, aber in der Hauptsache arbeite ich noch mit BDS 2006 und damit geht’s auch.

Also noch mal Danke.

Bis bald Chemiker