Semi-Transparenz auf TCanvas

[Zwoetzen]

Hi DP'ler


ich möchte mir eine kleine graphische Komponente erstellen. Vom Grundgedanken her ist sie an TImage angelehnt, enthält aber ein paar zusätzliche Features, die ich später brauchen werde.

Meine Klasse ist von TGraphicControl abgeleitet, und besitzt ein TPicture, in das ein Bild geladen werden kann, unter anderem auch ein (teilweise transparentes) PNG.

Das TPicture per Paint() zu zeichnen, ist nicht das Problem (Canvas.Draw() ^^). Nun möchte ich aber, dass dieses Bild mit einer Halb-transparenten, sagen wir mal grünen Fläche mit Deckkraft 50%, unterlegt wird. Und hier weiß ich momentan nicht mehr weiter.

Da TCanvas direkt keine Transparenz zu unterstützen scheint (hab zumindest nix entsprechendes gefunden), habe ich mir folgende Varianten überlegt:

Variante 1: Schleife über TCanvas.Pixel[X,Y], Berechnung der Farbe aus Hintergrund + Bild + Fläche:
Ich durchlaufe jedes Pixel der zu zeichnenden Fläche, und rechne die Farbe des TPicture und meine Flächenfarbe prozentual mit ein, um so die Transparenz zu bekommen.
Doch wie bekomm ich die Farbe, die das dahinter liegende Objekt hat? Bekomm ich so überhaupt eine Transparenz hin?
Wenn ja, wie rechne ich am günstigsten mit dem TColor-Wert: Mit ColorToRGB() erst konvertieren, und dann alles ausrechnen? Oder geht das direkter?

Variante 2: Zusätzliches Bild-Objekt (TBitmap?):
Ich erstelle ein temporäres Bild, welches genau 1 Pixel in der entsprechenden Farbe und Transparenz (50%) enthält. Dieses zeichne ich dann per TCanvas.StretchDraw(), und anschließend zeichne ich das TPicture einfach drüber.
Wie bekomm ich das Pixel 50% transparent? Geht das mit einem TBitmap (pf32Bit = RGBA, ABGR, whatever?), wenn ja, wie genau?

Wie würdet ihr das Problem am besten lösen? Sind meine Ansätze überhaupt richtig? Muss ja irgendwie gehen, dass am Ende ne halbttransparente Fläche unter meinem PNG liegt ^^

(Habe versucht, aus den Delphi-Objekten wie TPicture, TImage, TCanvas etc. und der OH schlau zu werden, aber da blick ich irgendwie nicht so recht durch... (bzw OH war keine große Hilfe))


Viele Fragen, ich hoffe, jemand kann mir weiterhelfen

MfG Zwoetzen

[turboPASCAL]

- Scanline nutzen anstelle von Pixels[]; oder wenn Einfarbig nur Farbwert nutzen
- in einer schleife dann den mtiiel btz die Transparenz odeer genauer gesagt das ergebnis berechnen.

Wenn ich mich nicht irre habe ich hir in der DP schon ein paar gute Beispiele gesehen.

(Muss jetzt wech ...)

[Hawkeye219]

Hallo,

mit der folgenden Routine kannst du auf einem Canvas ein Rechteck mit Alphablending zeichnen:

Delphi-Quellcode:

// Zeichnet ein gefülltes Rechteck auf einem Canvas mit Alphablending
procedure AlphaBlendRect (
            const aCanvas    : TCanvas;  // Ziel-Canvas
            const aRect      : TRect;    // zu füllendes Rechteck
            const aColor     : TColor;   // Füllfarbe
            const aIntensity : Byte      // Intensität (0=durchsichtig, 255=deckend)
          );
var
  Width, Height : Integer;
  Bitmap        : {Graphics.}TBitmap;
  BlendParams   : TBlendFunction;
begin
  Width := Succ(aRect.Right - aRect.Left);
  Height := Succ(aRect.Bottom - aRect.Top);

  Bitmap := TBitmap.Create;
  try
    Bitmap.SetSize (Width, Height);
    Bitmap.Canvas.Brush.Color := aColor;
    Bitmap.Canvas.FillRect(Rect(0, 0, Width, Height));

    BlendParams.BlendOp := AC_SRC_OVER;
    BlendParams.BlendFlags := 0;
    BlendParams.SourceConstantAlpha := aIntensity;
    BlendParams.AlphaFormat := 0;

    Windows.AlphaBlend(aCanvas.Handle, aRect.Left, aRect.Top, Bitmap.Width, Bitmap.Height,
                       Bitmap.Canvas.Handle, 0, 0, Bitmap.Width, Bitmap.Height,
                       BlendParams);
  finally
    Bitmap.Free;
  end;
end;

// Beispiel-Aufruf
AlphaBlendRect (Form1.Canvas, Rect(50, 50, 250, 150), clBlue, 64);

Gruß Hawkeye

[Zwoetzen]

Danke für eure Antworten

@Hawkeye: Danke für den Codeschnipsel, konnte ihn nun auch ausprobieren, und bringt genau das gewünschte Resultat