AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Object-Pascal / Delphi-Language Delphi mehrere funktionsparameter bei beginthread übergeben?

mehrere funktionsparameter bei beginthread übergeben?

Offene Frage von "griever"
Ein Thema von griever · begonnen am 8. Mär 2009 · letzter Beitrag vom 9. Mär 2009
Antwort Antwort
Seite 1 von 2  1 2   
griever

Registriert seit: 27. Apr 2008
19 Beiträge
 
#1

mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 17:31
hi,
ich wollte mal fragen wie man mehrere Parameter einer funktion bei aufruf von Beginthread übergibt
kleines beispiel:
-funktion:
Delphi-Quellcode:
funktion rechne(a,b:integer):integer;
begin
result := a+b;
end;
-aufruf:
Delphi-Quellcode:
a1s := 2;
b1s := 3;
threadhandle:=beginThread(nil,0,TFNThreadStartRoutine(@rechnen),@a1s, 0, threadid);
nun versuch ich schon seit einiger zeit herauszufinden wie man aus 2 parametern einen macht aber was nützliches hab ich noch nicht gefunden.
wie kann ich nun auch b1s mit übergeben?
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#2

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 17:33
Erstell ein Record mit den Parametern und übergib den Record an die Funktion.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
griever

Registriert seit: 27. Apr 2008
19 Beiträge
 
#3

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 17:43
und wie muss das record aussehen?
Delphi-Quellcode:
  myrecord = record
    a: Pinteger;
    b: Pinteger;
so oder muss ich dann die integer weitergeben?
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#4

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 17:53
Ganz normal. Du übergibst dann den Zeiger auf den Record. Siehe auch mein Threading Tutorial: http://delphitutorials.michael-puff.de

Parameter auf dem Heap ablegen:
Delphi-Quellcode:
(******************************************************************************
*                                                                            *
*  Project: Thread Programmierung unter Windows mit Delphi                  *
*          Paramter-Demo                                                    *
*                                                                            *
*  Copyright (c) Michael Puff  [url]http://www.michael-puff.de[/url]                    *
*                                                                            *
******************************************************************************)


program ParameterHeap;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TThreadParams = packed record
    Number: Integer;
    Text: string;
  end;
  PThreadParams = ^TThreadParams;

function IntToStr(Int: integer): string;
begin
  Str(Int, result);
end;

function ThreadFunc(tp: PThreadParams): Integer;
var
  Number : Integer;
  Text : string;
  s : string;
begin
  // Parameter lokalen Variablen zuweisen.
  Number := PThreadParams(tp)^.Number;
  Text := PThreadParams(tp)^.Text;
  s := 'Zahl: ' + IntToStr(Number) + #13#10 + 'Text: ' + Text;
  // ExitCode enthält Rückgabewert der Messagebox.
  Result := MessageBox(0, PChar(s), 'Thread', MB_YESNO or MB_ICONINFORMATION);
  // Reservierten Speicher für Parameter wieder freigeben.
  Dispose(tp);
end;

procedure RunThread;
var
  tp : PThreadParams;
  Thread : THandle;
  ThreadID : Cardinal;
  ExitCode : Cardinal;
begin
  // Speicher für Struktur reservieren.
  New(tp);
  // Daten den feldern der Struktur zuweisen.
  tp.Number := 42;
  tp.Text := 'Die Antwort.';
  // Thread erzeugen.
  Thread := BeginThread(nil, 0, @ThreadFunc, tp, 0, ThreadID);
  // Auf Beendigung des Threads warten.
  WaitForSingleObject(Thread, INFINITE);
  // Rückgabewert ermitteln...
  GetExitCodeThread(Thread, ExitCode);
  // ...und auswerten.
  case ExitCode of
    IDYES: Writeln('Benutzer hat "Ja" angeklickt.');
    IDNO: Writeln('Benutzer hat "Nein" angeklickt.');
  end;
  // Thread-Handle schliessen udn somit das Thread-Objekt zerstören.
  CloseHandle(Thread);
end;

begin
  RunThread;
  Readln;
end.
Parameter auf dem Stack ablegen:
Delphi-Quellcode:
(******************************************************************************
*                                                                            *
*  Project: Thread Programmierung unter Windows mit Delphi                  *
*          Paramter-Demo                                                    *
*                                                                            *
*  Copyright (c) Michael Puff  [url]http://www.michael-puff.de[/url]                    *
*                                                                            *
******************************************************************************)


program ParameterStack;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TThreadParams = packed record
    Number: Integer;
    Text: string;
  end;
  PThreadParams = ^TThreadParams;

function IntToStr(Int: integer): string;
begin
  Str(Int, result);
end;

function ThreadFunc(tp: PThreadParams): Integer;
var
  Number : Integer;
  Text : string;
  s : string;
begin
  Number := PThreadParams(tp)^.Number;
  Text := PThreadParams(tp)^.Text;
  s := 'Zahl: ' + IntToStr(Number) + #13#10 + 'Text: ' + Text;
  Result := MessageBox(0, PChar(s), 'Thread', MB_YESNO or MB_ICONINFORMATION);
end;

procedure RunThread;
var
  tp : TThreadParams;
  Thread : THandle;
  ThreadID : Cardinal;
  ExitCode : Cardinal;
begin
  tp.Number := 42;
  tp.Text := 'Die Antwort.';
  Thread := BeginThread(nil, 0, @ThreadFunc, @tp, 0, ThreadID);
  WaitForSingleObject(Thread, INFINITE);
  GetExitCodeThread(Thread, ExitCode);
  case ExitCode of
    IDYES: Writeln('Benutzer hat "Ja" angeklickt.');
    IDNO: Writeln('Benutzer hat "Nein" angeklickt.');
  end;
  CloseHandle(Thread);
end;

begin
  RunThread;
  Readln;
end.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Apollonius

Registriert seit: 16. Apr 2007
2.325 Beiträge
 
Turbo Delphi für Win32
 
#5

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 18:00
Die zweite Möglichkeit funktioniert aber nur, wenn man tatsächlich in der selben Routine auf die Beendigung des Threads wartet. Das dürfte recht selten vorkommen.
Wer erweist der Welt einen Dienst und findet ein gutes Synonym für "Pointer"?
"An interface pointer is a pointer to a pointer. This pointer points to an array of pointers, each of which points to an interface function."
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#6

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 18:03
Logisch. Da beim Verlassen der Routine die lokalen Variablen ungültig werden. Aber es geht.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Apollonius

Registriert seit: 16. Apr 2007
2.325 Beiträge
 
Turbo Delphi für Win32
 
#7

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 18:04
Dass du das weißt, war mir klar. Das war nur als Hinweis für den unbedarften Leser gedacht.
Wer erweist der Welt einen Dienst und findet ein gutes Synonym für "Pointer"?
"An interface pointer is a pointer to a pointer. This pointer points to an array of pointers, each of which points to an interface function."
  Mit Zitat antworten Zitat
griever

Registriert seit: 27. Apr 2008
19 Beiträge
 
#8

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 19:04
danke das hab ich denke ich mal verstanden
jetzt muss ichs nur noch auf meine:
"pointer auf ein array von records die aus pointern auf array von zahlen bestehen" variante umwandeln^^ und nachdem ich das gesachafft hab muss ich rausfinden warum ich zugriffsverletzungen bekomme wenn ich die zahlen verändern will.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.016 Beiträge
 
Delphi 12 Athens
 
#9

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 20:32
statt einem Record könnte man auch ein Objekt übergeben (also die Objektreferenz) ... wollt ich nur mal so erwähnen,
aber das mit dem Record ist wohl gängiger.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von sirius
sirius

Registriert seit: 3. Jan 2007
Ort: Dresden
3.443 Beiträge
 
Delphi 7 Enterprise
 
#10

Re: mehrere funktionsparameter bei beginthread übergeben?

  Alt 8. Mär 2009, 22:36
Zitat von himitsu:
statt einem Record könnte man auch ein Objekt übergeben (also die Objektreferenz) ... wollt ich nur mal so erwähnen,
aber das mit dem Record ist wohl gängiger.
Und man kan die Threadfunction aucvh gleich asl Methode der zugehörigen Klasse nehmen:
Delphi-Quellcode:
type TmyThread=class
      private
       a,b:Integer;
      public
       function ThreadFunc:Integer;
       property ...
     end;

...

//und im Aufruf:
myThread:=TmyThread.create;
myThread.property:=xyz;
BeginThread(nil,0,@TmyThreadClass.ThreadFunc,myThread,0,id);
Dieser Beitrag ist für Jugendliche unter 18 Jahren nicht geeignet.
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 20:52 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz