AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Step wie noch mal ?

Ein Thema von EWeiss · begonnen am 23. Apr 2009 · letzter Beitrag vom 23. Apr 2009
Antwort Antwort
Seite 2 von 2     12
Benutzerbild von himitsu
himitsu
Online

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.382 Beiträge
 
Delphi 10.4 Sydney
 
#11

Re: Step wie noch mal ?

  Alt 23. Apr 2009, 15:16
Delphi-Quellcode:
for i := 0 to 100 {step 3} do
begin
  // mach was mit i

  i := i + 2; // es gibt einen Hack, womit man die Variable sezten kann,
  // aber da muß man aufpassen, denn daß hier wird eine "Endlosschleife",
  // da die Abbruchbedingung i=100 nicht erreicht wird > 93 96 99 102 ...
end;
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Hawkeye219

Registriert seit: 18. Feb 2006
Ort: Stolberg
2.227 Beiträge
 
Delphi 2010 Professional
 
#12

Re: Step wie noch mal ?

  Alt 23. Apr 2009, 16:43
Hallo,

es ist eine technische Spielerei, aber ich konnte einfach nicht widerstehen:

Delphi-Quellcode:
type
  TLoop = class
  private
    FFrom : Integer;
    FTo : Integer;
    FStep : Integer;
    FCurrent : Integer;
  public
    constructor Create (const aFrom, aTo: Integer);
    function MoveNext: Boolean;
    function Step (const aStep: Integer): TLoop;
    function GetEnumerator: TLoop;
    property Current: Integer read FCurrent;
  end;

constructor TLoop.Create (const aFrom, aTo: Integer);
begin
  FFrom := aFrom;
  FTo := aTo;
  Step(1);
end;

function TLoop.Step (const aStep: Integer): TLoop;
begin
  FStep := aStep;
  FCurrent := FFrom - FStep;

  Result := Self;
end;

function TLoop.GetEnumerator: TLoop;
begin
  Result := Self;
end;

function TLoop.MoveNext: Boolean;
begin
  Inc (FCurrent, FStep);

  if (FStep < 0) then
    Result := (FCurrent >= FTo)
  else
    Result := (FCurrent <= FTo);
end;


function Range (const aFrom, aTo: Integer): TLoop;
begin
  Result := TLoop.Create(aFrom, aTo);
end;

// Anwendung:

procedure TForm1.btnEnumeratorClick (Sender: TObject);
var
  i : Integer;
begin
  Memo.Clear;

  for i in Range(12, 51).Step(7) do
    Memo.Lines.Add (IntToStr(i));

  Memo.Lines.Add('');

  for i in Range(20, 0).Step(-3) do
    Memo.Lines.Add (IntToStr(i));
end;
Die Klasse und die Hilfsfunktion Range würde man natürlich in eine eigene Unit verfrachten.

Gruß Hawkeye
  Mit Zitat antworten Zitat
Benutzerbild von Sunlight7
Sunlight7

Registriert seit: 17. Sep 2006
Ort: Sonnensystem, Zentral
1.522 Beiträge
 
Delphi 5 Standard
 
#13

Re: Step wie noch mal ?

  Alt 23. Apr 2009, 20:49
Zitat von himitsu:
Delphi-Quellcode:
for i := 0 to 100 {step 3} do
begin
  // mach was mit i

  i := i + 2; // es gibt einen Hack, womit man die Variable sezten kann,
  // aber da muß man aufpassen, denn daß hier wird eine "Endlosschleife",
  // da die Abbruchbedingung i=100 nicht erreicht wird > 93 96 99 102 ...
end;
Du meinst (falls man nen Integer als i hat)

  Inc(PInteger(@i)^, 2); Edit: Da ich per PN geschimpft wurde, sowas zu zeigen...
Ne so schlimm war die PN nich, aber hier halt ein Hinweis zum beachten:
Manipuliert man Delphis Schleifenvariable, kann dies zu unerwünschten Ergebnissen,
wie zB. Endlosschleifen und AVs führen.
Man sollte dies nur machen, wenn man genau weiß was man macht, oder gleich die Finger davon lassen.


Noch eine saubere Methode:

Delphi-Quellcode:
   for i := 0 to 100 {step 3} do begin
   If i mod 3<>0 then continue;

   // Mach was mit i
end;
Ist 0 nicht gewünscht mit 1 beginnen
Windows: Ja - Microsoft: Nein -> www.ReactOS.org
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 21:48 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf