AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi SetConsoleCtrlHandler Verständnisfrage(n)

SetConsoleCtrlHandler Verständnisfrage(n)

Ein Thema von turboPASCAL · begonnen am 23. Aug 2009 · letzter Beitrag vom 23. Aug 2009
Antwort Antwort
Benutzerbild von turboPASCAL
turboPASCAL

Registriert seit: 8. Mai 2005
Ort: Sondershausen
4.274 Beiträge
 
Delphi 6 Personal
 
#1

SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 12:06
Hi,

ich habe da mal 'n Problem. Ich versuche gerade bei einer Konsolenanwendung das
Schliessen per X-Button der Titelleiste abzufangen.

Der Quelltext schaut do aus:
Delphi-Quellcode:
program Test;

{$APPTYPE CONSOLE}

uses
  Windows;

var
  AppTerminated: Boolean;

function ConCtrlHandler(dwCtrlType: DWORD): Bool; stdcall;
begin
  Result := True;

  {case dwCtrlType of
    // CTRL+C signal was received, either from keyboard input
    CTRL_C_EVENT:;    

    // CTRL+BREAK signal was received, either from keyboard input
    CTRL_BREAK_EVENT:;    

    // --> system sends to all processes attached to a console when the user closes the console
    CTRL_CLOSE_EVENT:;

    // system sends to all console processes when a user is logging off.
    CTRL_LOGOFF_EVENT:;    

    // system sends to all console processes when the system is shutting down
    CTRL_SHUTDOWN_EVENT:; 
   end }


  AppTerminated := True;
end;

begin
  AppTerminated := False;
  SetConsoleCtrlHandler(@ConCtrlHandler, True);

  while not AppTerminated do
  begin
    Write('Working...'#32);
    sleep(100);
  end;

  writeln(#10#13);
  writeln('...und Tschuess!');
  sleep(500);
end.
Per CTRL+C und CTRL+BREAK funktioniert das so wie es soll.
Schliesse ich die App, bei der Entwicklung in der IDE (D6 PE),
per X-Button hängt sich die IDE (bzw. der Debugger ?) auf.

Wenn ich die App ohne IDE starte und mit dem X-Button beende,
kommt es nicht bei "...und Tschuess!" an.

Irgend welche Ideen ?
Matti
Meine Software-Projekte - Homepage - Grüße vom Rüsselmops -Mops Mopser
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.583 Beiträge
 
Delphi 10.4 Sydney
 
#2

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 13:28
Zitat:
Schliesse ich die App, bei der Entwicklung in der IDE (D6 PE),
per X-Button hängt sich die IDE (bzw. der Debugger ?) auf.
also wärend des Debuggens (im Pause-/Einzelschrittmodus)

das liegt nicht an dem Handler, sondern an dem Debugger, welcher da Probleme hat.

ist mir auch schon ein paar Mal passiert


PS: wenn du wenigstens noch speichern willst, dann fahr einfach Windows runter, dann fängt sich der Compiler wieder und du kannst speichern.

nur mit einem zu schnellem "schnellen Herunterfahren" vom Windows könnte es Probleme geben, also wenn dieses die Anwendungen (also auch Delphi) abschießt, bevor du das Speichern vornehmen konntest.


Zitat:
Wenn ich die App ohne IDE starte und mit dem X-Button beende,
kommt es nicht bei "...und Tschuess!" an.
das könnte wohl daran liegen, daß die Konsole geschlossen wurde.

hast du mal versucht in dem Callback eine Logdatei zu führen?
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von turboPASCAL
turboPASCAL

Registriert seit: 8. Mai 2005
Ort: Sondershausen
4.274 Beiträge
 
Delphi 6 Personal
 
#3

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 13:38
Zitat von himitsu:
das liegt nicht an dem Handler, sondern an dem Debugger, welcher da Probleme hat.
Ok, gut zu wissen. Ich war schon am verzweifeln.


Zitat von himitsu:
Zitat:
Wenn ich die App ohne IDE starte und mit dem X-Button beende,
kommt es nicht bei "...und Tschuess!" an.
das könnte wohl daran liegen, daß die Konsole geschlossen wurde.

hast du mal versucht in dem Callback eine Logdatei zu führen?
Noch nicht. Werde ich mal machen.

Ich dachte zu mindest das die App bis zu Ende ausgeführt wird damit ich Objecte ferigeben kann.

// Edit:

Zitat:
Werde ich mal machen.
Gemacht.

Also es passt alles. Da werde ich wohl die Freigaben in den "ConCtrlHandler" packen.
Matti
Meine Software-Projekte - Homepage - Grüße vom Rüsselmops -Mops Mopser
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.583 Beiträge
 
Delphi 10.4 Sydney
 
#4

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 14:44
Zitat:
Ich dachte zu mindest das die App bis zu Ende ausgeführt wird damit ich Objecte ferigeben kann.
da könnte man mit der Log doch auch mal schauen ... eventuell wird dieses ja gemacht, aber du siehst es einfach nur nicht mehr?
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von turboPASCAL
turboPASCAL

Registriert seit: 8. Mai 2005
Ort: Sondershausen
4.274 Beiträge
 
Delphi 6 Personal
 
#5

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 16:59
Ach, ich musste mich erst einmal mit CreateFile rumschlagen
damit das Loggen nicht gepuffert wird.

Delphi-Quellcode:
program Test;

{$APPTYPE CONSOLE}

uses
  Windows;

var
  AppTerminated: Boolean;
  f: cardinal;

procedure Log(txt: string);
var
  b: cardinal;
  a: array [0..255] of char;
begin
  if not(f<>0) then exit; // no file no write
  zeromemory(@a, sizeof(a));
  lstrcpy(a, PCHAR(txt + #13#10));
  writefile(f, a, lstrlen(a), b, nil);
end;

function ConCtrlHandler(dwCtrlType: DWORD): Bool; stdcall;
begin
  Result := True;

  case dwCtrlType of
    // CTRL+C signal was received, either from keyboard input
    CTRL_C_EVENT: log('App-Event: CTRL_C_EVENT');

    // CTRL+BREAK signal was received, either from keyboard input
    CTRL_BREAK_EVENT: log('App-Event: CTRL_BREAK_EVENT');

    // --> system sends to all processes attached to a console when the user closes the console
    CTRL_CLOSE_EVENT: log('App-Event: CTRL_CLOSE_EVENT');

    // system sends to all console processes when a user is logging off.
    CTRL_LOGOFF_EVENT: log('App-Event: CTRL_LOGOFF_EVENT');

    // system sends to all console processes when the system is shutting down
    CTRL_SHUTDOWN_EVENT: log('App-Event: CTRL_SHUTDOWN_EVENT');
  end;
  AppTerminated := True;
end;

begin

  //////////////////// VERY BAD CODE ////////////////////

  f := CreateFile('log.txt', GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ,
       nil, TRUNCATE_EXISTING, FILE_FLAG_WRITE_THROUGH, 0);

  if f = ERROR_FILE_NOT_FOUND then
  f := CreateFile('log.txt', GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ,
       nil, CREATE_NEW, FILE_FLAG_WRITE_THROUGH, 0);

  //////////////////// ------------- ////////////////////


  log('--------------------------'#13#10'App: Start');

  AppTerminated := False;

  if SetConsoleCtrlHandler(@ConCtrlHandler, True) then log('App: Set CtrlHandler true')
    else log('App: Set CtrlHandler false');


  log('App: Working...');
  while not AppTerminated do
  begin
    Write('Working...'#32);
    sleep(100);
  end;

  writeln(#10#13);
  writeln('...und Tschuess!');
  sleep(500);

  log('App: End');
  closehandle(f);
end.
Die Loggdatei:
Code:
--------------------------
App: Start
App: Set CtrlHandler true
App: Working...
App-Event: CTRL_CLOSE_EVENT
Also wird das Ding mit dem X-Button regelrecht "abgeschossen".
Matti
Meine Software-Projekte - Homepage - Grüße vom Rüsselmops -Mops Mopser
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.583 Beiträge
 
Delphi 10.4 Sydney
 
#6

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 17:16
nja, im Prinzip isses bei dem [X] ja fast so, als wenn du den PC abschaltest .. nur daß du hier deinem Programm die Console (dessen Welt/Lebensraum) unterm Arsch wegziehst.


und bezüglich FILE_FLAG_WRITE_THROUGH brauchst du hier keine Angst zu haben, der Puffer ist ohne doch nur in der WindowsFileCache, also außerhalb der Anwendung .. also solange Windows bzw. der PC nicht verreckt, sind die Daten also so gut wie auf der Festplatte, auch ohne dieses Flag .
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von turboPASCAL
turboPASCAL

Registriert seit: 8. Mai 2005
Ort: Sondershausen
4.274 Beiträge
 
Delphi 6 Personal
 
#7

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 17:25
Mit AssignFile(), Writeln(f, ...) und Co klappte es nicht.
Matti
Meine Software-Projekte - Homepage - Grüße vom Rüsselmops -Mops Mopser
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.583 Beiträge
 
Delphi 10.4 Sydney
 
#8

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 17:29
mit Delphi 7 compiliert seh ich übrigens noch kurz das "und tschüß", egal ob im Debugger oder nicht
Delphi-Quellcode:
program Project1;

{$APPTYPE CONSOLE}

uses
  Windows,
  SysUtils;

var
  AppTerminated: Boolean;
  f: THandle;

procedure Log(txt: AnsiString);
var
  b: cardinal;
begin
  if f = INVALID_HANDLE_VALUE then exit; // no file no write
  txt := txt + #13#10;
  WriteFile(f, txt[1], Length(txt), b, nil);
end;

function ConCtrlHandler(dwCtrlType: DWORD): Bool; stdcall;
begin
  Result := True;

  case dwCtrlType of
    // CTRL+C signal was received, either from keyboard input
    CTRL_C_EVENT: log('App-Event: CTRL_C_EVENT');

    // CTRL+BREAK signal was received, either from keyboard input
    CTRL_BREAK_EVENT: log('App-Event: CTRL_BREAK_EVENT');

    // --> system sends to all processes attached to a console when the user closes the console
    CTRL_CLOSE_EVENT: log('App-Event: CTRL_CLOSE_EVENT');

    // system sends to all console processes when a user is logging off.
    CTRL_LOGOFF_EVENT: log('App-Event: CTRL_LOGOFF_EVENT');

    // system sends to all console processes when the system is shutting down
    CTRL_SHUTDOWN_EVENT: log('App-Event: CTRL_SHUTDOWN_EVENT');
  end;
  AppTerminated := True;
end;

begin
  f := CreateFile('log.txt', GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ,
       nil, CREATE_ALWAYS, 0, 0);
  try
    log('--------------------------'#13#10'App: Start');

    AppTerminated := False;

    if SetConsoleCtrlHandler(@ConCtrlHandler, True) then log('App: Set CtrlHandler true')
      else log('App: Set CtrlHandler false');


    log('App: Working...');
    while not AppTerminated do
    begin
      Write('Working...'#32);
      sleep(100);
    end;

    writeln(#10#13);
    writeln('...und Tschuess!');
    sleep(500);

    log('App: End');
  finally
    closehandle(f);
  end;
end.
Code:
--------------------------
App: Start
App: Set CtrlHandler true
App: Working...
App-Event: CTRL_CLOSE_EVENT
App: End
WinXP SP3

VERY BAD CODE?
von der Funktion her, würde es so auf's Gleiche rauskommen

und dein Log würde unter Delphi2009 nur die Hälfte speichern


[add]
Zitat:
AssignFile(), Writeln(
das ist was Anderes, diese Funktionen haben zusätzlich zur WFC noch eine eigene 128 Byte-Cache via Delphi drin
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von turboPASCAL
turboPASCAL

Registriert seit: 8. Mai 2005
Ort: Sondershausen
4.274 Beiträge
 
Delphi 6 Personal
 
#9

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 17:48
Zitat von himitsu:
mit Delphi 7 compiliert seh ich übrigens noch kurz das "und tschüß", egal ob im Debugger oder nicht
Das ist ja interessant.
Also klappt es dann wohl doch.
Matti
Meine Software-Projekte - Homepage - Grüße vom Rüsselmops -Mops Mopser
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.583 Beiträge
 
Delphi 10.4 Sydney
 
#10

Re: SetConsoleCtrlHandler Verständnisfrage(n)

  Alt 23. Aug 2009, 17:54
jupp, auch im TDE und 2009er

wobei ich TDE grad abschießen durfte, da es sich nicht mehr beenden ließ und es mehr als doppelt soviel RAM belegte, als ein aufgemotzes und seit Stunden laufendes D2009
aber das lag nicht an dem Code hier
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 03:08 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf