Filemanager Fehler - Lösung gefunden?

[DarkItachi]

Hallöchen?

Ich benutze folgende Function um Dateien aufzulisten: (Siehe ScreenShot)

Delphi-Quellcode:

  if FindFirst(Path + '*.*', faAnyFile, SR) = 0 then
  begin
    repeat
      if (SR.Attr <> faDirectory) then
      begin
        dview:= Form2.DirFileView.Items.Add;
        dview.ImageIndex:= 1;
        dview.Caption:= SR.Name;
      end;
    until FindNext(SR) <> 0;
    FindClose(SR);
  end;

ImageIndex (1) ist dieses Txt-Symbol.

Meine Frage:
Wie kann ich prüfen, ob SR.Attr faDirectory nicht enthält?
Wie ich vermute, sind diese falsch dargestellten Items(Ordner) mehrere Attribute enthalten.
Also faSysFile und faDirectory..

"SR.Attr <> faDirectory" ist ja schön und gut, aber was ist wenn "SR.Attr = faSysFile + faDirectory" ist?
Hoffentlich ist das verständlich! ^^

Ich bitte um Hilfe, thx

MfG

und gegebenenfalls "Gute Nacht"

[Sir Rufo]

Delphi-Quellcode:

if FindFirst(Path + '*.*', faAnyFile, SR) = 0 then 
  begin 
    repeat 
      if (SR.Attr AND faDirectory <> faDirectory) then 
      begin 
        dview:= Form2.DirFileView.Items.Add; 
        dview.ImageIndex:= 1; 
        dview.Caption:= SR.Name; 
      end; 
    until FindNext(SR) <> 0; 
    FindClose(SR); 
  end;

[DarkItachi]

Krass, funktioniert!
Verstanden und angewendet!^^

Da wäre ich niemals drauf gekommen!

EDIT:

Gut danke, dank diesen Code konnte ich auch noch den Ordner Code variieren!
Doch was jetzt?

Delphi-Quellcode:

procedure ListFileDir(Path: string);
var
  SR: TSearchRec;
  dview: TListItem;
begin

      if FindFirst(Path + '*.*', faAnyFile, SR) = 0 then begin
   if SR.Name <> '.' then begin // Benutze ich, um die zwei Ordner wegzukriegen! (Screenshot)
    repeat
      if (sr.Attr and faDirectory = faDirectory) then
      begin
        dview:= Form2.DirFileView.Items.Add;
        dview.ImageIndex:= 0;
        dview.Caption:= SR.Name;
      end;

    until FindNext(SR) <> 0;
    FindClose(SR);
  end;  
 end;
end;

Jetzt listet er nur noch Ordner in einem Laufwerk Root aber in einem anderen Ordner wird kein Ordner erstellt!
Wenn ich if SR.Name <> '.' then begin wegnehme, funktionierts!

Ich versuche doch aber nur diese zwei Ordner wegzukriegen!

Was mache ich falsch? Thx again!

[nat]

ich habe jetzt nicht ganz kapiert was du für ein problem hast, aber
wenn du "." und ".." weg haben willst, dann sollte dein code so aussehen:

Delphi-Quellcode:

procedure ListFileDir(Path: string);
var
  SR: TSearchRec;
  dview: TListItem;
begin

      if FindFirst(Path + '*.*', faAnyFile, SR) = 0 then begin
   //if SR.Name <> '.' then begin // Benutze ich, um die zwei Ordner wegzukriegen! (Screenshot)  <--- falscher platz für die abfrage
    repeat
      if (SR.Name <> '.') and (SR.Name <> '..') then
        if (sr.Attr and faDirectory = faDirectory) then
        begin
          dview:= Form2.DirFileView.Items.Add;
          dview.ImageIndex:= 0;
          dview.Caption:= SR.Name;
        end;

    until FindNext(SR) <> 0;
    FindClose(SR);
  end; 
end;
end;

vielleicht ist das dann ja das, was du wolltest!

[Sir Rufo]

Der Vergleich geht sogar noch kürzer:
if ( SR.Name[ 1 ] <> '.' ) then

[nat]

Zitat von Sir Rufo:

Der Vergleich geht sogar noch kürzer:
if ( SR.Name[ 1 ] <> '.' ) then

genau diese variante benutze ich extra nicht.
was machst du denn, wenn ein ordner ".hallo" heißt?
ist ein gültiger name. deine routine überspringt ihn dann!

[Sir Rufo]

Zitat von nat:

Zitat von Sir Rufo:

Der Vergleich geht sogar noch kürzer:
if ( SR.Name[ 1 ] <> '.' ) then

genau diese variante benutze ich extra nicht.
was machst du denn, wenn ein ordner ".hallo" heißt?
ist ein gültiger name. deine routine überspringt ihn dann!

umbenennen und denjenigen, der den so benannt hat, steinigen

[himitsu]

if (SR.Name <> '.') and (SR.Name <> '.') then begin Es gibt zwar noch Wege dieses zu "optimieren", allerdings ist FindFirst/FindNext sowas von langsam, daß sich sowas nicht wirklich lohnt.

.htaccess

[DeddyH]

Dann will ich auch noch meinen Senf dazugeben

Delphi-Quellcode:

procedure ListFileDir(const Path: string; const DirFileView: TListView);
var
  SR: TSearchRec;
  dview: TListItem;
begin
  if FindFirst(IncludeTrailingPathDelimiter(Path) + '*.*', faAnyFile, SR) = 0 then 
  begin
    repeat
      if (SR.Name <> '.') and (SR.Name <> '..') then
        if (sr.Attr and faDirectory = faDirectory) then
        begin
          dview:= DirFileView.Items.Add;
          dview.ImageIndex:= 0;
          dview.Caption:= SR.Name;
        end;
    until FindNext(SR) <> 0;
    FindClose(SR);
  end;
end;

[himitsu]

Zitat von DeddyH:

Dann will ich auch noch meinen Senf dazugeben

Delphi-Quellcode:

procedure ListFileDir(const Path: String; DirFileView: TCustomListView);
var
  SR: TSearchRec;
begin
  DirFileView.Items.BeginUpdate;
  try
    if FindFirst(IncludeTrailingPathDelimiter(Path) + '*.*', faAnyFile, SR) = 0 then 
    begin
      repeat
        if (SR.Name <> '.') and (SR.Name <> '..') 
            and (sr.Attr and faDirectory <> 0) then 
          with TListView(DirFileView).Items.Add do
          begin
            ImageIndex := 0;
            Caption := SR.Name;
          end;
      until FindNext(SR) <> 0;
      FindClose(SR);
    end;
  finally
    DirFileView.Items.EndUpdate;
  end;
end;

Wobei '.' und '..' doch Ordner sind und da er doch wohl nur die Dateien haben möchte (oder hab ich das falscht verstanden?), kann man diese Ordner ignorieren und muß natürlich auf "Nicht-Verzeichnis" prüfen:

Delphi-Quellcode:

procedure ListFileDir(const Path: String; DirFileView: TCustomListView);
var
  SR: TSearchRec;
begin
  DirFileView.Items.BeginUpdate;
  try
    if FindFirst(IncludeTrailingPathDelimiter(Path) + '*.*', faAnyFile, SR) = 0 then 
    begin
      repeat
        if sr.Attr and faDirectory = 0 then 
          with TListView(DirFileView).Items.Add do
          begin
            ImageIndex := 0;
            Caption := SR.Name;
          end;
      until FindNext(SR) <> 0;
      FindClose(SR);
    end;
  finally
    DirFileView.Items.EndUpdate;
  end;
end;