AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Code-Bibliothek Neuen Beitrag zur Code-Library hinzufügen Delphi Zufällig Zahlen ziehen, aber ohne Wiederholung

Zufällig Zahlen ziehen, aber ohne Wiederholung

Ein Thema von alzaimar · begonnen am 29. Apr 2010 · letzter Beitrag vom 30. Apr 2010
Antwort Antwort
alzaimar
(Moderator)

Registriert seit: 6. Mai 2005
Ort: Berlin
4.956 Beiträge
 
Delphi 2007 Enterprise
 
#1

Zufällig Zahlen ziehen, aber ohne Wiederholung

  Alt 29. Apr 2010, 20:24
Hier eine Klasse, die zufällig Zahlen aus einem Zahlenbereich zieht, bis keine mehr übrig sind. Jede Zahl wird nur 1x gezogen. Die Klasse erstellt eine Liste der Zahlen, mischt sie nach Fisher-Yates und liefert dann eine nach dem anderen zurück.

Verwendung (Lotto, 6 aus 49 + Zusatzzahl);
Delphi-Quellcode:
With TUniqueRandomSequenceGenerator.Create (1,49) do begin
  Write('Und hier die Lottozahlen: ');
  For i := 1 to 6 do
    Write(GetNextNumber:2,' ');
  Writeln(' Zusatzzahl ',GetNextNumber);
  Free
End;
Und hier die Klasse:
Delphi-Quellcode:
type
  ENoMoreNumbers = Exception;
  TUniqueRandomSequenceGenerator = class
  private
    FCounter: Integer;
    FNumberList: array of Integer;
    procedure BuildSequence(aStart, aEnde: Integer);
  public
    constructor Create(aStart, aEnde: Integer);
    function GetNextNumber: Integer;
    function TotalCount: Integer;
    function RemainingCount: Integer;
  end;
implementation

{ TUniqueRandomGenerator }

constructor TUniqueRandomSequenceGenerator.Create(aStart, aEnde: Integer);
begin
  BuildSequence(aStart, aEnde);
end;

procedure TUniqueRandomSequenceGenerator.BuildSequence(aStart, aEnde: Integer);
var
  i, j, tmp: Integer;

begin
  SetLength(FNumberList, aEnde - aStart + 1);
// Zahlenliste erzeugen
  for i := 0 to TotalCount - 1 do
    FNumberList[i] := aStart + i;

// Mischen nach Fisher-Yates
  for i := Low(FNumberList) to High(FNumberList) do begin
    j := i + Random(TotalCount - i);
    tmp := FNumberList[j];
    FNumberList[j] := FNumberList[i];
    FNumberList[i] := tmp;
  end;
  FCounter := 0;
end;

function TUniqueRandomSequenceGenerator.GetNextNumber: Integer;
begin
  if FCounter < TotslCount then begin
    Result := FNumberList[FCounter];
    Inc(FCounter);
  end
  else
    raise ENoMoreNumbers.Create('No more numbers');
end;

function TUniqueRandomSequenceGenerator.RemainingCount: Integer;
begin
  Result := TotalCount - FCounter;
end;

function TUniqueRandomSequenceGenerator.TotalCount: Integer;
begin
  Result := Length(FNumberList);
end;
[edit]Schlampenfehler dank gsammatester korrigiert[/edit]
"Wenn ist das Nunstruck git und Slotermeyer? Ja! Beiherhund das Oder die Flipperwaldt gersput!"
(Monty Python "Joke Warefare")
  Mit Zitat antworten Zitat
gammatester

Registriert seit: 6. Dez 2005
999 Beiträge
 
#2

Re: Zufällig Zahlen ziehen, aber ohne Wiederholung

  Alt 29. Apr 2010, 21:02
Also mit Delphi 2 und/oder 3 kann man's nicht übersetzen, da zB keine dynamischen Arrays bekannt sind.

Dann ein Bug: '<' muss durch '<=" ersetzt werden, sonst erhält man nicht die gesamte Liste (das berüchtigte 1-mehr/weniger-Problem):
Delphi-Quellcode:
function TUniqueRandomSequenceGenerator.GetNextNumber: Integer;
begin
  if FCounter <= High(FNumberList) then begin // hier <= statt <
    Result := FNumberList[FCounter];
    Inc(FCounter);
  end
  else
    raise ENoMoreNumbers.Create('No more numbers');
end;
Aus Konsistenzgünden sollte statt Length(FNumberList) hier j := i + Random(Length(FNumberList) - i); auch TotalCount benutzt werden,


Gruß Gammatester
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#3

Re: Zufällig Zahlen ziehen, aber ohne Wiederholung

  Alt 29. Apr 2010, 21:06
Zitat von gammatester:
Also mit Delphi 2 und/oder 3 kann man's nicht übersetzen, da zB keine dynamischen Arrays bekannt sind.
Nun ja. Das würde mich aber nicht sonderlich stören. Delphi 3 ist immer hin 13 Jahre alt und Delphi 2 sogar 12.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.582 Beiträge
 
Delphi 10.4 Sydney
 
#4

Re: Zufällig Zahlen ziehen, aber ohne Wiederholung

  Alt 29. Apr 2010, 21:22
Zitat von Luckie:
Delphi 3 ist immer hin 13 Jahre alt und Delphi 2 sogar 12.
Sorry could not resist

Klaus
Klaus
  Mit Zitat antworten Zitat
alzaimar
(Moderator)

Registriert seit: 6. Mai 2005
Ort: Berlin
4.956 Beiträge
 
Delphi 2007 Enterprise
 
#5

Re: Zufällig Zahlen ziehen, aber ohne Wiederholung

  Alt 30. Apr 2010, 06:53
Hi gammatester,

wenn Du nicht wärst....
"Wenn ist das Nunstruck git und Slotermeyer? Ja! Beiherhund das Oder die Flipperwaldt gersput!"
(Monty Python "Joke Warefare")
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 22:49 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf