AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) "FindFirstChangeNotifikation" neu anstoßen

"FindFirstChangeNotifikation" neu anstoßen

Ein Thema von soulies · begonnen am 9. Jun 2010 · letzter Beitrag vom 10. Jun 2010
Antwort Antwort
soulies

Registriert seit: 9. Dez 2005
234 Beiträge
 
#1

"FindFirstChangeNotifikation" neu anstoßen

  Alt 9. Jun 2010, 15:48
hoi,

ich benutze folgenden Funktion in einem thread.
(die Funktion habe ich von hier)

Delphi-Quellcode:
function RegisterDirectoryWatch(Params:Pointer): Boolean;
var
  hHnd : THandle;
  dwWait : DWORD;
  Parameter : TThreadParameter ;
begin
  Parameter := PThreadParameter(Params)^ ;
  Dispose(PThreadParameter(Params));
  Result := False ;
  
  if (Parameter.Pfad <> EmptyStr) then // bei gueltiger Pfadangabe ...
  begin
    hHnd := FindFirstChangeNotification ( PChar(Parameter.Pfad), // Pfad
                                          False, // keine Unterverz.
                                          FILE_NOTIFY_CHANGE_FILE_NAME); // Flag

    if hHnd = INVALID_HANDLE_VALUE then // bei Fehler -> Abbruch
     begin
       Result := False;
     end
    else
     begin
       while TRUE do // warte
       begin
         dwWait := WaitForSingleObject(hHnd, INFINITE);
         case dwWait of
           WAIT_OBJECT_0: // hab was gefunden
             begin
               if FileExists( Parameter.Pfad + Datei) then // ist die eine datei vorhanden ?
               begin
                 SuspendThread(MyThreadID) ; // thread unterbrechen

                 //...
                 // weitere Verarbeitung
                 //...
                 
                 DeleteFile( Parameter.Pfad + Datei); // datei loeschen
                 
                 if ThreadStoppen then // threadstoppen = boolean ; wird global gesetzt
                    Exit
                 else
                   begin
                     // ...
                     // weiter schauen <---- wie gehts weiter ? die suche soll weiter gehen
                     // ...

                     ResumeThread(MyThreadID);
                   end;

               end;
             end;
         end;
       end;
     end;
    FindCloseChangeNotification(hHnd) ;
  end;
end;
Problem: Ich weiß nicht wie ich es umsetzen muss damit die funktion weiterarbeitet nachdem z.B.
einmal die Datei gefunden wurde. Ich will "nur" ein neues anstoßen bewirken.


cya
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
42.982 Beiträge
 
Delphi 12 Athens
 
#2

AW: "FindFirstChangeNotifikation" neu anstoßen

  Alt 9. Jun 2010, 16:01
Delphi-Quellcode:
FindFirstChangeNotification
while
  WaitForSingleObject
  Auswerten
end;
FindCloseChangeNotification
FindFirstChangeNotification richtet die Üerwachung ein,
WaitForSingleObject wartet auf das nächste Ereignis (oder ein Timeout)
und FindCloseChangeNotification hebt den Benachrichtigungsauftrag auf.

Zitat:
wie gehts weiter ? die suche soll weiter gehen
Was soll man dort also nun machen?
Genau ... nichts, außer die Schleife fortzusetzen, bzw. nicht abzubrechen.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
soulies

Registriert seit: 9. Dez 2005
234 Beiträge
 
#3

AW: "FindFirstChangeNotifikation" neu anstoßen

  Alt 9. Jun 2010, 16:19
hallo himitsu,

wenn ich die schleife mit "continue" weiterarbeiten lassen funktionierts aber
es steht ein Kern bei mir konstant auf 50% Last.

Hängt das zufällig mit dem "Infinite" bei "WaitForSingleObject" zusammen oder
habe ich noch was vergessen ?
  Mit Zitat antworten Zitat
Christian Seehase
(Co-Admin)

Registriert seit: 29. Mai 2002
Ort: Hamburg
11.105 Beiträge
 
Delphi 11 Alexandria
 
#4

AW: "FindFirstChangeNotifikation" neu anstoßen

  Alt 9. Jun 2010, 19:45
Moin Soulies,

bei einer Funktion, die was mit First heisst, und mit Close beendet wird, es auch eine mit Next geben, in diesem Falle:

FindNextChangeNotification



Schau Dir mal folgendes Beispiel an.
Dazu benötigst Du einen Formular, und zwei Button, der Rest steht (hoffentlich ) drin.


Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TcsDirWatchThread = class(TThread)
  private
    FsDirToWatch : string;
    procedure MyShowMessage;
  public
    constructor Create(const AsFolder : string);
    procedure Execute; override;
  end;

type
  TfrmMain = class(TForm)
    btnResume: TButton;
    btnSuspend: TButton;
    procedure btnResumeClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure btnSuspendClick(Sender: TObject);
  private
    { Private declarations }
    FDWT : TcsDirWatchThread;
  public
    { Public declarations }
  end;

var
  frmMain: TfrmMain;

implementation

{$R *.dfm}

{ TcsDirWatchThread }

constructor TcsDirWatchThread.Create(const AsFolder: string);
begin
  inherited Create(true);
  if not DirectoryExists(AsFolder) then raise Exception.CreateFmt('Datei %s nicht gefunden.',[AsFolder]);
  FsDirToWatch := AsFolder;
end;

procedure TcsDirWatchThread.Execute;

var
  dwFCN : DWORD;

begin
  dwFCN := FindFirstChangeNotification(PChar(FsDirToWatch),false,FILE_NOTIFY_CHANGE_FILE_NAME);
  if dwFCN = INVALID_HANDLE_VALUE then raise Exception.CreateFmt('FindFirstChangeNotification fehlgeschlagen.'#13#10'FM: %s',[SysErrorMessage(GetLastError)]);
  try
    while not Terminated do begin
      case WaitForSingleObject(dwFCN,1000) of
        WAIT_OBJECT_0 : begin
          // Mach was mit der Meldung
          Synchronize(MyShowMessage);
        end;
      end;
      FindNextChangeNotification(dwFCN);
    end;
  finally
    FindCloseChangeNotification(dwFCN);
  end;
end;

procedure TcsDirWatchThread.MyShowMessage;
begin
  ShowMessage('Ausgelöst');
end;

procedure TfrmMain.btnResumeClick(Sender: TObject);
begin
  FDWT.Resume;
end;

procedure TfrmMain.FormCreate(Sender: TObject);
begin
  FDWT := TcsDirWatchThread.Create('C:\temp');
end;

procedure TfrmMain.FormDestroy(Sender: TObject);
begin
  FDWT.Terminate;
  FDWT.Free;
end;

procedure TfrmMain.btnSuspendClick(Sender: TObject);
begin
  FDWT.Suspend;
end;

end.
Tschüss Chris
Die drei Feinde des Programmierers: Sonne, Frischluft und dieses unerträgliche Gebrüll der Vögel.
Der Klügere gibt solange nach bis er der Dumme ist
  Mit Zitat antworten Zitat
soulies

Registriert seit: 9. Dez 2005
234 Beiträge
 
#5

AW: "FindFirstChangeNotifikation" neu anstoßen

  Alt 10. Jun 2010, 08:07
hallo christian,

Zitat:
Schau Dir mal folgendes Beispiel an.
Hab ich gemacht!

Das Problem was ich dann aber habe ist nachdem ich "Execute" aufgerufen habe,
der Thread zwar läuft aber das Programm an sich "eingefroren" ist.
Auf Änderungen im Verzeichnis wird korrekt reagiert.

PS. Ich habe "Execute" nach dem "Create" aufgerufen

cya
  Mit Zitat antworten Zitat
Benutzerbild von thkerkmann
thkerkmann

Registriert seit: 7. Jan 2006
Ort: Pulheim Brauweiler
464 Beiträge
 
Delphi 2010 Professional
 
#6

AW: "FindFirstChangeNotifikation" neu anstoßen

  Alt 10. Jun 2010, 08:25
Du darfst Execute gar nicht aufrufen.

Das ist ein Thread, der läuft alleine

Gruss
Thomas Kerkmann
Ich hab noch einen Koffer in Borland.
http://thomaskerkmann.wordpress.com/
  Mit Zitat antworten Zitat
soulies

Registriert seit: 9. Dez 2005
234 Beiträge
 
#7

AW: "FindFirstChangeNotifikation" neu anstoßen

  Alt 10. Jun 2010, 08:26
hallo,

Zitat:
Du darfst Execute gar nicht aufrufen
Richtig! Mein Fehler ...

cya
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:48 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz